* скрипт для создания тестовой таблички
#if .f.
	CREATE TABLE [dbo].[testImage](
		[id] [int] IDENTITY( 1 , 1 ) NOT NULL,
		[Image] [image] NULL
	) ON [PRIMARY] TEXTIMAGE_ON [PRIMARY]
#endif


close databases all
local lcConnString, lnConnection, ;
	loMyCAD as CursorAdapter, ;
	laErrors[ 1 ], ;
	lcFileName
* строка соединения с сервером	
text to lcConnString noshow pretext  15 
	Driver=SQL Native Client;
	SERVER=.\SQLSERVER2005;
	DATABASE=Test;
	uid=sa;
	pwd=as;
endtext	
lnConnection = sqlstringconnect(lcConnString)
if lnConnection<= 0 
   messagebox('не подцепился')
   return 
endif

loMyCAD = createobject('CursorAdapter')
with loMyCAD
	.Alias              = 'MyAlias'
	.DataSourceType     = 'ODBC'
	.DataSource         = lnConnection
	.SelectCmd          = "select [id], [Image] from testImage"
	.Tables             = 'testImage'
	.BufferModeOverride =  5 
	.cursorschema       = "id i, Image m NOCPTRANS"
	.MapBinary          = .t.
	.keyFieldList       = 'id'
	.UpdatableFieldList = 'Image'
	.updateNameList     = 'id testImage.id, Image testImage.Image'
	if .CursorFill(.t.)
		lcFileName = GetFile("bmp","покажите картинку")
		if !Empty(lcFileName)
			* если указали файлик,
			* то запишем его в курсор курсорадаптера
			Insert into MyAlias (Image) ;
			        values (filetostr(lcFileName))
			* сохраняем на сервер        
			if !tableupdate(.t.,.t.,.Alias)
				aerror(laErrors)
			    messagebox(laErrors[ 2 ])
			EndIf
		EndIf
		* смотрим, что лежит на сервере
		If .cursorrefresh()	
			loImage = CreateObject("Image")
			With _screen
				If !PemStatus(_screen, "oBmp",  5 )
					.ADDOBJECT("oBmp","Image")
				EndIf 
				WITH .oBmp
					.zOrder( 1 )
					.visible =.T.
					* пробежим все, что есть 
					* и посмотрим
					select MyAlias						
					Scan
						.Pictureval = MyAlias.Image
						Wait WINDOW "нажми клавишу"
					EndScan
				EndWith
			EndWith 
		EndIf
	else
		aerror(laErrors)
		messagebox(laErrors[ 2 ])
	endif .CursorFill(.t.)
endwith