close databases all

local lcConnString, lnConnection, ;
	loMyCAD as CursorAdapter, ;
	laErrors[ 1 ]

text to lcConnString noshow pretext  15 
	Driver=SQL Native Client;
	SERVER=.\SQLSERVER2005;
	DATABASE=test;
	uid=sa;
	pwd=as;
endtext	

lnConnection = sqlstringconnect(lcConnString)
if lnConnection<= 0 
   messagebox('не подцепился')
   return 
endif

text to lcSqlCmd noshow pretext  7 
	if object_id('tempdb..#t') is not null drop table #t
	create table #t ( [Id] [int] IDENTITY( 1 , 1 ) NOT NULL, bigDate datetime )
endtext
if sqlexec(lnConnection, lcSqlCmd)< 0 
	messagebox('не создал табличку')
    return 
endif 

loMyCAD = createobject('CursorAdapter')
with loMyCAD
	.Alias              = 'MyAlias'
	.DataSourceType     = 'ODBC'
	.DataSource         = lnConnection
	.SelectCmd          = "select * from #t"
	.Tables             = '#t'
	.BufferModeOverride =  5 
	.cursorschema       = "id i, bigDate d(8)"
	.keyFieldList		= 'Id'
	.UpdatableFieldList = 'bigDate'
	.updateNameList     = 'Id #t.Id, bigDate #t.bigDate'
	.usetransactions    = .f.
	if .CursorFill(.t.)
		for i= 1  to  10 
		   insert into MyAlias (bigDate) values (date())
		endfor
		select MyAlias
		brow
		if !tableupdate(.t.,.t.,.Alias)
			aerror(laErrors)
		    messagebox(laErrors[ 2 ])
		endif
		.cursorrefresh()
		browse title "Данные с сервера после апдейта"
	else
		aerror(laErrors)
		messagebox(laErrors[ 2 ])
	endif .CursorFill(.t.)
endwith