*-- Определение функций в Win32API для управления атрибутами файлов
DECLARE INTEGER SetFileAttributes IN Win32API STRING FileName, INTEGER Attributes
DECLARE INTEGER GetFileAttributes IN Win32API STRING FileName
#DEFINE FILE_ATTRIBUTE_NORMAL	 128 

LOCAL m.oFile AS Object, m.lnFileAttributeDBF AS Integer, m.RetVal AS Integer, m.lcFileName
#DEFINE FILE_ATTRIBUTE_NORMAL	 128 
#DEFINE CRLF					CHR( 13 ) + CHR( 10 )

LOCAL lnFileAttributeFRX AS Integer, lnFileAttributeFRT AS Integer, RetVal AS Integer, m.lnLineORIENT AS Integer, ;
	m.lnLinePAPERSIZE AS Integer, m.lnLineCOLOR AS Integer, m.lcNewStr AS Character

WITH THIS
	IF TYPE("Application.ActiveProject") == "O"
		FOR EACH m.oFile IN Application.ActiveProject.Files
			IF m.oFile.Type == "R"
				WAIT WINDOW "Обработка отчета: " + m.oFile.Name NOWAIT
				*-- у отчета удаляем окружение
				m.lnFileAttributeFRX = GetFileAttributes(m.oFile.Name)
				m.lnFileAttributeFRT = GetFileAttributes(FORCEEXT(m.oFile.Name, "FRT"))
				*-- Устанавливаем атрибуты в "нормальный" у файла FRX
				m.RetVal = SetFileAttributes(m.oFile.Name, FILE_ATTRIBUTE_NORMAL)
				*-- Устанавливаем атрибуты в "нормальный" у файла FRT
				m.RetVal = SetFileAttributes(FORCEEXT(m.oFile.Name, "FRT"), FILE_ATTRIBUTE_NORMAL)
				*-- Открываем отчет, как DBF - файл
				USE (m.oFile.Name) IN  0  ALIAS temp_report
				SELECT temp_report
				LOCATE FOR Objtype =  1  AND Objcode =  53 
				IF FOUND()
					REPLACE Tag  WITH ""
					REPLACE Tag2 WITH ""
					m.lnLineORIENT = ATCLINE("ORIENTATION", Expr)
					m.lnLinePAPERSIZE = ATCLINE("PAPERSIZE", Expr)
					m.lnLineCOLOR = ATCLINE("COLOR", Expr)
					m.lcNewStr = MLINE(Expr, m.lnLineORIENT) + CRLF + MLINE(Expr, m.lnLinePAPERSIZE) + CRLF + MLINE(Expr, m.lnLineCOLOR)
					REPLACE Expr WITH m.lcNewStr
				ENDIF
				*-- Закрываем отчет, как DBF - файл
				USE
				*-- Восстанавливаем атрибуты у файлов
				m.RetVal = SetFileAttributes(m.oFile.Name, m.lnFileAttributeFRX)
				m.RetVal = SetFileAttributes(FORCEEXT(m.oFile.Name, "FRT"), m.lnFileAttributeFRT)
			ENDIF
		ENDFOR
		WAIT CLEAR
	ENDIF
ENDWITH