LPARAMETERS loTextBox
LOCAL loForm, m.lData, m.lnDayMax

loForm = THISFORM
m.lnDayMax = DAY(GOMONTH(DATE(ListDocum.Plan_Year, ListDocum.Plan_Month,  1 ),  1 ) -  1 )

DEFINE POPUP ldoc_menu SHORTCUT RELATIVE FROM MROW(),MCOL()
DEFINE BAR  1  OF ldoc_menu PROMPT 'Открыть спецификацию для данной продукции' ;
	SKIP FOR EOF('Schedule') ;
	PICTURE 'bitmaps\mcr.bmp'
DEFINE BAR  2  OF ldoc_menu PROMPT 'Редактировать месячный план производства данного продукта (F4)' ;
	SKIP FOR !loForm.ToolBar.cmdEdit.Enabled ;
	PICTURE loForm.ToolBar.cmdEdit.Picture
ON SELECTION BAR  1  OF ldoc_menu loForm.ViewSpecification(Schedule.UO_ID,  Schedule.GUO_T_ID)
ON SELECTION BAR  2  OF ldoc_menu loForm.ToolBar.cmdEdit.Click()

IF BETWEEN(m.loForm.CurrentDay,  1 , m.lnDayMax)
	m.lData = DATE(ListDocum.Plan_Year, ListDocum.Plan_Month, m.loForm.CurrentDay)
	DEFINE BAR  3  OF ldoc_menu PROMPT '\-'
	DEFINE BAR  4  OF ldoc_menu PROMPT 'Редактировать план производства на дату: ' + DTOC(m.lData)  + ' (F3)';
		SKIP FOR !loForm.ToolBar.cmdEdit.Enabled ;
		PICTURE loForm.ToolBar.cmdEdit.Picture
	ON SELECTION BAR  4  OF ldoc_menu loForm.Edit( 1 )
	DEFINE BAR  5  OF ldoc_menu PROMPT '\-'
	DEFINE BAR  6  OF ldoc_menu PROMPT 'Показать потребности в сырье и материалах' ;
		SKIP FOR EOF('Schedule') ;
		PICTURE 'bitmaps\treeview2.bmp'
	ON SELECTION BAR  6  OF ldoc_menu loForm.ViewBalance()
ENDIF
*-- Печать
DEFINE BAR  10  OF ldoc_menu PROMPT '\-'
DEFINE BAR  11  OF ldoc_menu PROMPT 'Печать...' ;
	SKIP FOR EOF('Schedule') ;
	PICTURE 'bitmaps\print.bmp'
DEFINE BAR  12  OF ldoc_menu PROMPT 'Печать плана в диапазоне дат...' ;
	SKIP FOR EOF('Schedule') ;
	PICTURE 'bitmaps\print.bmp'
ON SELECTION BAR  11  OF ldoc_menu loForm.Preport( 0 )
ON SELECTION BAR  12  OF ldoc_menu loForm.Preport( 1 )

ACTIVATE POPUP ldoc_menu
RELEASE POPUPS ldoc_menu