*****************************************************************************************
*-* (IGEL)
*-* Данная хрень является демонстрашкой одного из методов построения деревянных структур.
*-* Запускайте, нажимайте периодически AnyKey
lnTimeOut =  10 
*-* (IGEL)  0 . Первоначальное заполнение курсора
USE IN SELECT ("TstCursor")
CREATE CURSOR TstCursor (Kod I, KodPar I NULL, Punkt C( 20 ), nLft I, nRgt I, nLev I)
INSERT INTO TstCursor (Kod, KodPar) VALUES ( 1 , .NULL.)
INSERT INTO TstCursor (Kod, KodPar) VALUES ( 2 , .NULL.)
INSERT INTO TstCursor (Kod, KodPar) VALUES ( 3 ,  1 )
INSERT INTO TstCursor (Kod, KodPar) VALUES ( 4 ,  1 )
INSERT INTO TstCursor (Kod, KodPar) VALUES ( 5 ,  3 )
INSERT INTO TstCursor (Kod, KodPar) VALUES ( 6 ,  5 )
INSERT INTO TstCursor (Kod, KodPar) VALUES ( 7 ,  5 )
INSERT INTO TstCursor (Kod, KodPar) VALUES ( 8 ,  5 )
INSERT INTO TstCursor (Kod, KodPar) VALUES ( 9 ,  2 )
INSERT INTO TstCursor (Kod, KodPar) VALUES ( 10 ,  2 )
INSERT INTO TstCursor (Kod, KodPar) VALUES ( 11 ,  10 )
INSERT INTO TstCursor (Kod, KodPar) VALUES ( 12 ,  10 )
INSERT INTO TstCursor (Kod, KodPar) VALUES ( 13 ,  2 )
INSERT INTO TstCursor (Kod, KodPar) VALUES ( 14 ,  11 )
INSERT INTO TstCursor (Kod, KodPar) VALUES ( 15 ,  11 )
INSERT INTO TstCursor (Kod, KodPar) VALUES ( 16 ,  15 )
GO TOP
BROWSE LAST NOWAIT
WAIT WINDOW "Изначальный грид" TIMEOUT lnTimeOut

*-* (IGEL)  1 . 1  Строим иерархию...
IF BuildHierarhy(.NULL.,  0 ,  0 , "Kod", "KodPar") != RECCOUNT()* 2 
	=MESSAGEBOX("ERROR1",  0 + 16 , "ERROR")
	RETURN .F.
ENDIF
INDEX ON nLft TO SYS( 2015 )
GO TOP

*-* (IGEL)  1 . 2  Обход дерева (для построения дерева стек уже не нужен).
LOCAL lcKey, lnLev
lcKey = ""
lnLev =  0 
SCAN	
	DO CASE
		CASE lnLev < nLev AND !ISNULL(KodPar)
			lcKey = lcKey + TRANSFORM(KodPar) + "."
		CASE lnLev > nLev AND !EMPTY(lcKey) 
			IF nLev >  1 
				lcKey = LEFT(lcKey, AT(".", lcKey, nLev -  1 ))
			ELSE
				lcKey = ""
			ENDIF				
	ENDCASE
	lnLev = nLev
	REPLACE Punkt WITH lcKey + TRANSFORM(Kod)
ENDSCAN

GO TOP
BROWSE LAST NOWAIT
WAIT WINDOW "Построена иерархия" TIMEOUT lnTimeOut
*-* (IGEL)  2 . 1  Выборки хочу всех детей первого элемента
SELECT TstCursor
SET FILTER TO 
LOCATE FOR Kod =  1 
IF FOUND()
	lcFilterClause = TEXTMERGE([BETWEEN(nLft, <<nLft>>, <<nRgt>>)])
	SET FILTER TO &lcFilterClause
	GO TOP
	BROWSE LAST NOWAIT
	WAIT WINDOW "Тест 1. Хочу всех детей от родителя с кодом 1" TIMEOUT lnTimeOut
ENDIF
*-* (IGEL)  2 . 2  Выборки хочу всех родителей восьмого элемента
SELECT TstCursor
SET FILTER TO 
LOCATE FOR Kod =  8 
IF FOUND()
	lcFilterClause = TEXTMERGE([nLft <= <<nLft>> AND nRgt >= <<nRgt>>])
	SET FILTER TO &lcFilterClause
	GO TOP
	BROWSE LAST NOWAIT
	WAIT WINDOW "Тест 2. Хочу всех родителей элемента с кодом 8" TIMEOUT lnTimeOut
ENDIF
*-* (IGEL)  2 . 3  Для кода  11  хочу выбрать и родителей и детей, +/-  1  уровень
SELECT TstCursor
SET FILTER TO 
LOCATE FOR Kod =  11 
IF FOUND()
	lcFilterClause = TEXTMERGE([nRgt >= <<nLft>> AND nLft <= <<nRgt>> AND ABS(nLev - <<nLev>>) =  1 ])
	SET FILTER TO &lcFilterClause
	GO TOP
	BROWSE LAST NOWAIT
	WAIT WINDOW "Тест 3. Хочу всех родителей и детей элемента с кодом 11" TIMEOUT lnTimeOut
ENDIF



******************************************************************
* Один из не самых быстрых методов построения иерархии в курсоре.
FUNCTION BuildHierarhy
LPARAMETERS tuNode, tnCounter, tnLevel, tcKeyField, tcParField

IF tnLevel >  100 
	=MESSAGEBOX("Уровней иерархии более 100!!!",  0 + 16 , "Error")
	RETURN tnCounter
ENDIF
IF VARTYPE(tcParField)#"C" OR EMPTY(tcParField)
	tcParField = "KodPar"
ENDIF

LOCAL lcUslovie, lnRecno

IF ISNULL(tuNode)
	lcUslovie = TEXTMERGE("ISNULL(<<tcParField>>)")
ELSE
	lcUslovie = TEXTMERGE("<<tcParField>> == <<tuNode>>")
ENDIF

tnLevel = tnLevel +  1 

GO TOP
SCAN FOR &lcUslovie
	tnCounter = tnCounter +  1 
	REPLACE nLft WITH tnCounter, ;
			nLev WITH tnLevel
			
	lnRecno = RECNO()
	
	tnCounter = BuildHierarhy(&tcKeyField, tnCounter, tnLevel, tcKeyField, tcParField)
	
	IF lnRecno <= RECCOUNT()
		GOTO lnRecno
	ENDIF	
	tnCounter = tnCounter +  1 
	REPLACE nRgt WITH tnCounter
ENDSCAN


RETURN tnCounter
ENDFUNC