******************************************************************************
*  Определить, сколько строк займет текст в колонке отчета заданной ширины,  * 
*  если он выводится в поле Stretch		                                     *
******************************************************************************
FUNCTION GetTextKolRows
LPARAMETERS tnFieldWidth, tcText, tcFontName, tnFontSize

* Входные параметры:
*	tnFieldWidth - ширина заполняемого поля в миллиметрах
* 	tcText - текст, выводимый в поле
* 	tcFontName - имя шрифта
* 	tnFontSize - размер шрифта

* Предупреждение  1 . Эта функция - сплошная эвристика в том смысле,
*                   что точно не определен алгоритм разбиения текста 
*                   на строки для полей Stretch при печати отчета.
*
* Предупреждение  2 . Пиксел здесь эмпирически считается  0 . 268  мм.
*
* Функция отлажена и проверена при ширине поля  52 . 9  мм и шрифте Arial, 8 . 
* Результат - удовлетворительный, т.е. функция правильно предсказывала количество строк,  
* на которые фактически разбивался текст в колонке при печати отчета.

LOCAL lnKolStr, lnFieldWidthF
lnFieldWidthF = tnFieldWidth /  0 . 268  / FONTMETRIC( 6 , tcFontName, tnFontSize)		&& Ширина поля в фокселах
					  
LOCAL lcTextRest, lnFieldRest, lcNextWord, lcTextRow, lni, lnj, lnKolWords 
lcTextRest = ALLTRIM(tcText)			&& Остаток текста для текущей строки
lnFieldRest = lnFieldWidthF 			&& Ширина свободного остатка поля в фокселах
lcTextRow = ""							&& Текст в очередной строке поля
lnKolStr =  0 

DO WHILE NOT EMPTY(lcTextRest)						&& Цикл виртуального разбиение текста на строки
	lcTextRow = ""									&& Текст в очередной строке поля
	lnKolWords = GETWORDCOUNT(lcTextRest)			&& Количество слов в остатке текста
	FOR lni= 1  TO lnKolWords 						&& Цикл заполнения строки
		lcNextWord = GETWORDNUM(lcTextRest, lni)	&& Очередное слово из остатка текста
		
		IF TXTWIDTH(lcNextWord, tcFontName, tnFontSize) > lnFieldWidthF 
				*-- Если очередное слово длиннее всего поля, то его надо разбить,
				*-- т.е. в остаток поля поместить то, что влезет,
				*-- а затем перейти к новой строке
				
			lnFieldRest = lnFieldWidthF - TXTWIDTH(lcTextRow, tcFontName, tnFontSize)	&& Ширина свободного остатка поля
			
			lnj =  1    					&& Количество сиволов, помещаемых в остаток поля
			DO WHILE lnj<=LEN(lcNextWord) .AND. TXTWIDTH(SUBSTR(lcNextWord,  1 , lnj), tcFontName, tnFontSize) <= lnFieldRest
				lnj = lnj+ 1  
			ENDDO

			lcTextRow = lcTextRow + SUBSTR(lcNextWord,  1 , lnj- 1 )				&& Текст в очередной строке поля

			lnKolStr = lnKolStr +  1 			&& Закончить строку 
			
			lcTextRest = ALLTRIM(SUBSTR(lcTextRest, IIF(lni= 1 ,  1 , AT(" ", lcTextRest, lni- 1 )+ 1 ) + lnj- 1 ))
			
			EXIT
		ELSE
			IF TXTWIDTH(lcTextRow + lcNextWord, tcFontName, tnFontSize) <= lnFieldWidthF 
					*-- Если очередное слово можно добавить к строке --*
				lcTextRow = lcTextRow + lcNextWord + " " 	&& Текст строки с добавленным словом
				
				IF lni = lnKolWords					&& Если добавляется последнее слово
					lnKolStr = lnKolStr +  1 			&& Закончить строку
					lcTextRest = ""
					EXIT
				ENDIF 
			ELSE		&& Если очередное слово (которое короче поля) нельзя добавить к строке --*
				lnKolStr = lnKolStr +  1 			&&  Закончить строку
				lcTextRest = ALLTRIM(SUBSTR(lcTextRest, IIF(lni= 1 ,  1 , AT(" ", lcTextRest, lni- 1 ))))
				EXIT
			ENDIF
		ENDIF
	ENDFOR
	
*	MESSAGEBOX(lcTextRow) 
ENDDO

RETURN MAX( 1 , lnKolStr)
************************************************************