close databases all

local lcConnString, lnConnection, ;
	loMyCAD as CursorAdapter, ;
	laErrors[ 1 ]

text to lcConnString noshow pretext  15 
	Driver=SQL Native Client;
	SERVER=....;
	DATABASE=test;
	uid=sa;
	pwd=as;
endtext	

lnConnection = sqlstringconnect(lcConnString)
if lnConnection<= 0 
   messagebox('не подцепился')
   return 
endif

text to lcSqlCmd noshow pretext  7 
	if object_id('dbo.plato') is not null drop table plato
	begin
		CREATE TABLE [dbo].[plato] ([kod]    [numeric]( 8 ,  0 )                                NOT NULL ,
									[nplt]   [numeric]( 6 ,  0 )                                NULL ,
									[priz]   [char] ( 6 )      COLLATE Cyrillic_General_CI_AS NULL ,
									[data]   [datetime]                                     NULL ,
									[summa]  [numeric]( 11 ,  2 )                               NULL ,
									[naim]   [char] ( 45 ) COLLATE Cyrillic_General_CI_AS     NULL ,
									[raion]  [tinyint]                                      NULL ,
									[user1]  [char] ( 10 ) COLLATE Cyrillic_General_CI_AS     NULL ,
									[myguid] [uniqueidentifier]                             NOT NULL ,
									[mes]    [numeric]( 2 ,  0 )                                NULL ,
									[god]    [numeric]( 4 ,  0 )                                NULL ,
									[nazn]   [char] ( 250 ) COLLATE Cyrillic_General_CI_AS    NULL 
									) ON [PRIMARY]

		ALTER TABLE [dbo].[plato] WITH NOCHECK ADD 
		CONSTRAINT [DF_plato_myguid] DEFAULT (newid()) FOR [myguid]

		CREATE UNIQUE INDEX [IX_plato] ON [dbo].[plato]([kod], [nplt], [data], [priz]) ON [PRIMARY]
	end
endtext
if sqlexec(lnConnection, lcSqlCmd)< 0 
	messagebox('не создал табличку')
    return 
endif 

loMyCAD = createobject('CursorAdapter')
with loMyCAD
	.Alias              = 'MyAlias'
	.DataSourceType     = 'ODBC'
	.DataSource         = lnConnection
	.SelectCmd          = "select * from plato"
	.Tables             = 'plato'
	.BufferModeOverride =  5 
	.cursorschema       = ""
	.keyFieldList		= 'myguid'
	text to .UpdatableFieldList noshow pretext  15 
		kod,nplt,data,summa,naim,priz,user1,raion,mes,god
	endtext 
	text to	.updateNameList noshow pretext  15 
	    myguid plato.myguid, kod plato.kod, nplt plato.nplt,
		Data plato.Data, summa plato.summa, naim plato.naim,
		priz plato.priz, user1 plato.user1, raion plato.raion,
		mes plato.mes, god plato.god
	endtext 
	if .CursorFill(!empty(.cursorschema),.f.)
		insert into (.Alias) (kod) values ( 1 )
		insert into (.Alias) (kod) values ( 2 )
		if !tableupdate(.t., .f.,.Alias)
			aerror(laErrors)
		    messagebox(laErrors[ 2 ])
		endif
	else
		aerror(laErrors)
		messagebox(laErrors[ 2 ])
	endif .CursorFill(.t.)
endwith