Классический вариант:
Создать на форме Property в которое гриды будут в событии When записывать ссылку на себя/свое имя или еще чего, в событии VALID "Выписываться"
Затем в Toolbar считывать и делать вызов нужной формы.

Если гриды пусты, то и желания надавить на кнопку тулбара возникать не должно.

Либо же создайте пустой курсор и подменяйте источник грида на него.
Тогда можно будет кликнуть на "пустом" гриде.
Всякие там прозрачные шапы на гриде это извращения.

Вот Вам пример, попроще.

***********************************
create cursor test1 (UID I)
For lnI = 1 to 10
Insert into test1 (UID) values (lnI)
EndFor
go 1 in "test1"


SElect Uid+10 as UID from test1 into cursor Test2

Public oTollBar

oTollBar = CreateObject('MySuperToolBar')
oForm1 = CreateObject('TestForm')
oForm1.Top = 50
oForm1.Left = 100

oForm2 = CreateObject('TestForm')
oForm2.Top = 100
oForm2.Left = 200

oTollBar.show()
oForm1.Show()
oForm2.Show()
Read Event

clear memory
close all
quit

*------------------------------------------------------
define class TestForm as Form
height = 150
Width = 350
add object grid1 as LinkGrid with top = 5, Left =5,RecordSource = "Test1"
add object grid2 as LinkGrid with top = 5, Left =130, RecordSource = "Test2"
add object Txt1 as TextBox with top = 110, Left =5

Procedure QueryUnload
thisform.Release()
EndPRoc
EndDefine

*------------------------------------------------------
Define Class MySuperToolBar as ToolBar
oGrid = .Null.
Add object cmdVizov as commandButton with top = 1, Left =1, Width = 100,Caption = "Вызофф..."

Procedure oGrid_assign
Lparameters vNewVal
This.cmdVizov.Enabled = (VarType(m.vNewVal) = 'O')
This.oGrid = m.vNewVal
EndProc

Procedure cmdVizov.Click
This.Parent.oGrid.BackColor = rgb(250,200,200)
EndProc

Procedure destroy
clear events
EndProc
EndDefine

*------------------------------------------------------
Define Class LinkGrid as grid
Width = 120
Height = 100

Procedure When
IF VARTYPE(oTollBar)='O' .And. .Not. Isnull(oTollBar)
oTollBar.oGrid = this
ENDIF
EndProc

Procedure Valid
IF VARTYPE(oTollBar)='O' .And. .Not. Isnull(oTollBar)
oTollBar.oGrid = .Null.
This.ResetToDefault('BackColor')

ENDIF
EndProc
EndDefine

Пустой курсор создать для этого примера можно так:
Select UID from test1 where .F. into cursor Test2