SET SAFETY OFF
SET MULTILOCKS ON
SET DELETED ON
CLOSE DATABASE
CLOSE TABLES all
* настройки мускула
gcDRIVER = "MySQL ODBC 3.51 Driver"
gcUID = "root"
gcSTMT = ""
gcOPTION = "3"
gcSOCKET = ""
gcPORT = "3306"
gcPASSWORD = "123456"
gcSERVER = "localhost"
gcDB = "ote" && имя базы данных на сервере в которую будем заливать таблички
gcDESC = ""

gcODBC = '"'+'DRIVER='+gcDRIVER+';UID='+gcUID+';STMT='+gcSTMT+';OPTION='+gcOPTION+';SOCKET='+gcSOCKET+';PORT='+gcPORT+';PASSWORD='+gcPASSWORD+';SERVER='+gcSERVER+';DB='+gcDB+';DESC='+gcDESC+'"'
gnSoed = SQLSTRINGCONNECT(&gcODBC)

IF gnSoed <  0 
	=MESSAGEBOX("Нет соединения с сервером")
	RETURN
endif

* Открываешь свою базу данных, таблички из которой будешь конвертить
OPEN DATABASE d:\ote\ote.DBC SHARED

* перебор табличек
FOR mm =  1  to ADBOBJECTS(laTables, "Table") 
	WAIT WINDOW (laTables[mm]) NOWAIT 
	lcTableName=laTables[mm]

	* удаляем таблички на сервере (если они есть, например после неправильной конвертации)
	sqlExec(gnSoed, LOWER("drop table " + lcTableName) )
	strSQL='create table '+ lcTableName + ' ('
	strFieldList=''
	strNameList=''
	strSelect='select '
	
	USE (laTables[mm]) 
	* анализируем структуру таблички для формирования sql строки создания таблицы
	gnFieldcount = AFIELDS(gaMyArray)  
	FOR nCount =  1  TO gnFieldcount 

		lcFName=gaMyArray(nCount, 1 )
		lcType=gaMyArray(nCount, 2 )
		lnWidth=gaMyArray(nCount, 3 )
		lnDec=gaMyArray(nCount, 4 )
		
		DO case
			CASE lcType=='C'
				strSQL=	strSQL +  lcFName +  " varchar(" + ALLTRIM(STR(lnWidth)) + ') not null default ""'
			CASE lcType=='I'
				strSQL=	strSQL +  lcFName +  ' int(11) not null default 0'
			CASE lcType=='N'
				strSQL=	strSQL +  lcFName +  ' double not null default 0'
			CASE lcType=='T'
				strSQL=	strSQL +  lcFName +  ' datetime not null default "0000-00-00 00:00"'
			CASE lcType=='L'
				strSQL=	strSQL +  lcFName +  ' smallint(4) not null default 0'
			CASE lcType=='D'
				strSQL=	strSQL +  lcFName +  ' date not null default "0000-00-00"'
		ENDCASE  		
			strSQL=	strSQL + IIF(nCount<>gnFieldcount,',', ')') && Запятые
			strFieldList=strFieldList + lcFName + IIF(nCount<>gnFieldcount,', ', '')
			strNameList=strNameList + lcFName + ' ' + lcTableName + '.' + lcFName + IIF(nCount<>gnFieldcount,', ', '')
			strSelect=strSelect + IIF(lcType=='Logical', 'IIF('+ lcFName+'=.t.,1,0)' ,lcFName) + IIF(nCount<>gnFieldcount,', ', ' from ' + laTables[mm])
	ENDFOR   

	* создаем таблички на сервере	
	sqlExec(gnSoed, LOWER(strSQL))
	
lo_CA=CREATEOBJECT("CursorAdapter")
lo_CA.Alias="Curfrommysql"
lo_CA.DataSourceType="ODBC"
lo_CA.DataSource=gnSoed
lo_CA.SelectCmd=LOWER("select * from " + lcTableName)
lo_CA.Tables=LOWER(lcTableName)
lo_CA.KeyFieldList= LOWER(field( 1 ,laTables[mm]))
lo_CA.UpdateNameList=LOWER(strNameList)
lo_CA.UpdatableFieldList=LOWER(strFieldList)
lo_CA.UpdateType= 2 

* заливаем КА
llCursorFilled=lo_CA.CursorFill()

* переносим данные на сервер 
strSQL1=LOWER('INSERT INTO Curfrommysql ' + strSelect)
&strSQL1
	
	USE IN (laTables[mm])
	USE IN Curfrommysql
	RELEASE lo_CA
ENDFOR