И без рекурсии, одним циклом решается эта задачка

сори, двумя конечно

set talk off
adirc("files")
select files
brow norm

*-----------------------------------------------------------------------------
* lib.file.adirc(cAlias, [cMask], [cParam])
*
* cAlias Курсор:
* file M(4)
* size N(16)
* date D(8)
* time C(8)
* attributes C(5)
* [cMask] [Путь и] маска искомых файлов (по-умолчанию - все файлы)
* [cParam] 'S' - без файлов текущей директории (только поддиректории)
* 'D' - отбирать как файлы, так и директории (по-умолчанию только файлы)
* Возвращает кол-во отобранных файлов [и директорий]
*
* + обрабатывает все поддиректории, не содержит рекурсии;
* + не имеет ограничения 64K на предельное количество файлов (возвращает курсор);
* + позволяет накачивать файлы в один курсор последовательными вызовами;
* + в имени файлов возвращается полный путь и имя файла;
* + возвращает корректные размеры для файлов больше 4GB;
* + не имеет ограничения на длину пути файлов;
* - ограничение на 64535 директорий (может быть устранено заменой массива
* adirs на курсор, но оставлено для быстродействия);
* - ограничение на размер файла 2GB (dbf или fpt), не критично
*-----------------------------------------------------------------------------
#define LONGINT 4294967296

Function adirc
lparameters cAlias, cMask, cParam
local cPath, lDirs, iFilesPtr, iDirsPtr1, iDirsPtr2, lBegin, cCurr, j, i, aCurr[1], cName, lAdd
ok = .t.
if !used(cAlias)
create cursor (cAlias) (;
file M(4) ,;
size N(14) ,;
date D(8) ,;
time C(8) ,;
attributes C(5) )
endif
if vartype(cMask)<>'C'
cMask = "*.*"
endif
if vartype(cParam)<>'C'
cParam = ""
endif

declare integer GetCompressedFileSize IN win32api string cFileName, Integer @lpFileSizeHigh

if ok
local iFileSize, iHigh, iLow, lNoCurrDir
cMask = strtran(alltrim(cMask),"\\","\")
cPath = addbs(justpath(cMask))
cMask = justfname(cMask)
if empty(cMask)
cMask = "*.*"
else
cMask = upper(cMask)
endif
lDirs = 'D'$cParam
lNoCurrDir = 'S'$cParam

local aDirs[1] && стек директорий
aDirs[1] = cPath
iDirsPtr1 = 1 && .. позиция сканирования
iDirsPtr2 = 1 && .. вершина стека

lBegin = .t.
do while ok and iDirsPtr1<=iDirsPtr2
cCurr = aDirs[iDirsPtr1]
j = adir(aCurr, cCurr+"*.*", "DHS", 1)
for i=1 to j
cName = aCurr[i,1]
lAdd = .f.

do case
case !ok
exit
case inlist(cName,".","..")
case 'D'$aCurr[i,5]
iDirsPtr2 = iDirsPtr2 + 1
local aDirs[iDirsPtr2]
aDirs[iDirsPtr2] = cCurr + cName + "\"
if lDirs
lAdd = .t.
endif
case lBegin and lNoCurrDir
case like(cMask,upper(cName))
lAdd = .t.
endcase

if lAdd
iHigh = 0
iLow = GetCompressedFileSize(cCurr+cName,@iHigh)
iFileSize = iif(iLow>=0, iLow, (iHigh+1)*LONGINT + iLow)

insert into (cAlias) values (;
cCurr+cName ,;
iFileSize ,;
aCurr[i,3] ,;
aCurr[i,4] ,;
aCurr[i,5] )
endif
endfor

iDirsPtr1 = iDirsPtr1 + 1
lBegin = .f.
enddo
endif

return ok

Сорри, забыл про тег SRC ;)
Во вложении то же самое