ReSQL.ru
     
powered by simpleCommunicator - 2.0.61     © 2026 Programmizd 02
Мобильная версия    Контакт    Правила    FAQ    Помощь
Целевая тема:
Создать новую тему:
Автор:
Закрыть
Цитировать
Доб. в избранное | Игнор. тему | Прикреп. тему | Пометить прочит. / непрочит. | Фильтр
Форумы / FoxPro, Visual FoxPro [игнор отключен] [закрыт для гостей] / Поможите select написать
6 сообщений из 6, страница 1 из 1
Поможите select написать
    #35246004
Tigroff
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Tigroff
Участник
Сидю, мучаюсь:
есть курсор А:
Код: plaintext
1.
2.
3.
4.
5.
6.
7.
8.
  номер  |   кол   | назв  |
   1     |    1    |    a  |
   1     |    4    |    b  |
   1     |    5    |    v  |
   2     |    2    |    a  |
   2     |    1    |    d  |
   2     |    2    |    b  |
   5     |    1    |    c  |
   5     |    1    |    l  |
....
и табличка В:
Код: plaintext
1.
2.
3.
  номер | кол_сум |    назв     |
  1     |    10   |    a, b, v  |
  2     |    5    |    a, d, b  |
  5     |    2    |    c,b      |
....
Как заполнить 2 первых поля в таблице В, понятно: select номер, sum(кол) as кол_сум group by номер
А вот как заполнить третье поле, никак не могу придумать. Записей в курсоре порядка 20000.
Мож есть какой-нибудь хитрый select?
Код: plaintext
...
Рейтинг: 0 / 0
09.04.2008, 16:34
| Ответить | Цитировать | Написать  
Поможите select написать
    #35246119
12345вышелзайчикпогулять
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
12345вышелзайчикпогулять
Гость
http://www.sql.ru/forum/actualthread.aspx?tid=539952
...
Рейтинг: 0 / 0
09.04.2008, 17:07
| Ответить | Цитировать | Написать  
Поможите select написать
    #35246208
Tigroff
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Tigroff
Участник
to 12345вышелзайчикпогулять

А как-нить попросче? Медленно...
Форма, вкоторой все это нужно выполнить и так долго обрабатывается.
А вообще, СПАСИБО. Если быстрее нельзя, то я так оставлю.
...
Рейтинг: 0 / 0
09.04.2008, 17:28
| Ответить | Цитировать | Написать  
Поможите select написать
    #35246336
12345вышелзайчикпогулять
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
12345вышелзайчикпогулять
Гость
авторМедленно...

что оптимизатор говорит

включена оптимизация??

индексы есть по полям в конструкции where
+ бинарный на делетед

Код: plaintext
1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
11.
12.
13.
14.
15.
16.
17.
18.
19.
20.
21.
22.
23.
24.
25.
26.
27.
28.
29.
30.
31.
32.
33.
34.
35.
36.
37.
38.
_screen.Cls()
SYS( 3054 , 1 )

create cursor tt (tt_id i, pp_id i)
insert into tt values ( 1 ,  1 )
insert into tt values ( 1 ,  2 )
insert into tt values ( 1 ,  3 )
insert into tt values ( 2 ,  4 )
insert into tt values ( 2 ,  5 )
index on pp_id tag pp_id 
index on deleted() tag del binary

create cursor pp (pp_id i, value c( 10 ))
insert into pp values ( 1 , 'раз')
insert into pp values ( 2 , 'два')
insert into pp values ( 3 , 'три')
insert into pp values ( 4 , 'четыре')
insert into pp values ( 5 , 'пять')
index on pp_id tag pp_id
index on deleted() tag del binary

select t1.tt_id, ff(t1.tt_id)   ;
	from tt t1 					;
	group by t1.tt_id
	
	
function ff
lparameters tnId
local lcResult, lcValue
select value ;
	from pp t1 ;
		inner join tt t2 on t1.pp_id=t2.pp_id and t2.tt_id = tnId ;
	into array laArr
lcResult = ""
for each lcValue in laArr
	lcResult = lcResult + iif(!empty(lcResult),",","") + alltrim(lcValue)
endfor
return 	lcResult

сравни рез-ты
...
Рейтинг: 0 / 0
09.04.2008, 18:03
| Ответить | Цитировать | Написать  
Поможите select написать
    #35246373
12345вышелзайчикпогулять
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
12345вышелзайчикпогулять
Гость
вот так все будет полностью оптимизировано

при установке делетед в офф
необходимо дописывать
условие !dele()

Код: plaintext
1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
11.
12.
13.
14.
15.
16.
17.
18.
19.
20.
21.
22.
23.
24.
25.
26.
27.
28.
29.
30.
31.
32.
33.
34.
35.
36.
37.
38.
39.
_screen.Cls()
set deleted on
SYS( 3054 , 1 )

create cursor tt (tt_id i, pp_id i)
insert into tt values ( 1 ,  1 )
insert into tt values ( 1 ,  2 )
insert into tt values ( 1 ,  3 )
insert into tt values ( 2 ,  4 )
insert into tt values ( 2 ,  5 )
index on pp_id tag pp_id 
index on tt_id tag tt_id 
index on deleted() tag del binary

create cursor pp (pp_id i, value c( 10 ))
insert into pp values ( 1 , 'раз')
insert into pp values ( 2 , 'два')
insert into pp values ( 3 , 'три')
insert into pp values ( 4 , 'четыре')
insert into pp values ( 5 , 'пять')
index on pp_id tag pp_id
index on deleted() tag del binary

select t1.tt_id, ff(t1.tt_id)   ;
	from tt t1 					;
	group by t1.tt_id
	
function ff
lparameters tnId
local lcResult, lcValue
select value ;
	from pp t1 ;
		inner join tt t2 on t1.pp_id=t2.pp_id and t2.tt_id = tnId ;
	into array laArr
lcResult = ""
for each lcValue in laArr
	lcResult = lcResult + iif(!empty(lcResult),",","") + alltrim(lcValue)
endfor
return 	lcResult
...
Рейтинг: 0 / 0
09.04.2008, 18:13
| Ответить | Цитировать | Написать  
Поможите select написать
    #35247131
Фотография Aleksey-K
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Aleksey-K
Участник
Не очень понял, зачем в функции join ?
Может так будет быстрее:
Код: plaintext
1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
11.
12.
13.
14.
15.
16.
17.
18.
19.
20.
21.
22.
23.
24.
CREATE CURSOR a1 (nomer I, Kvo I, name C( 10 ))
INSERT INTO a1 VALUES ( 1 , 1 ,'a')
INSERT INTO a1 VALUES ( 1 , 4 ,'b')
INSERT INTO a1 VALUES ( 1 , 5 ,'v')
INSERT INTO a1 VALUES ( 2 , 2 ,'a')
INSERT INTO a1 VALUES ( 2 , 1 ,'d')
INSERT INTO a1 VALUES ( 2 , 2 ,'b')
INSERT INTO a1 VALUES ( 5 , 1 ,'c')
INSERT INTO a1 VALUES ( 5 , 1 ,'l')

SELECT nomer, SUM(Kvo) AS Kvo, ff(a1.nomer) AS name ;
	FROM a1 INTO CURSOR cur1 NOFILTER READWRITE ;
	GROUP BY nomer ;
	ORDER BY nomer

FUNCTION ff
	LPARAMETERS tnId
	LOCAL m.lcResult, m.lnI
	SELECT name FROM a1 INTO ARRAY laArr WHERE nomer = tnId ORDER BY name
	m.lcResult = ""
	FOR m.lnI =  1  TO ALEN(laArr)
		m.lcResult = m.lcResult + [,] + ALLTRIM(laArr[m.lnI])
	ENDFOR
	RETURN (m.lcResult)
ENDFUNC
Но... , не думаю, что использование в SELECT -SQL вместо агрегатной фунции UDF хороший вариант с точки зрения скорости. Это в SQL 2005 я могу написать на C# свою агрегатную функцию и через CLR использовать ее. Тогда агрегат будет считаться в потоке данных и не тормозить за счет многократных сканирований таблицы.
Может имеет смысл сделать запрос без заполнения последнего поля (конкатенации), а затем в цикле выполнять функцию ff:
Код: plaintext
1.
2.
3.
4.
5.
6.
7.
SELECT nomer, SUM(Kvo) AS Kvo, CAST('' AS C( 254 )) AS name ;
	FROM a1 INTO CURSOR cur2 NOFILTER READWRITE ;
	GROUP BY nomer ;
	ORDER BY nomer
SELECT cur2
SCAN
	REPLACE name WITH ff(cur2.nomer)
ENDSCAN
В любом случае, индекс по полю nomer будет полезен.
Кстати, а какая длина строки ожидается после конкатенации? Если более 254 символов, то тогда только второй вариант но ...CAST('' AS M) AS name

С уважением, Алексей
...
Рейтинг: 0 / 0
10.04.2008, 09:44
| Ответить | Цитировать | Написать  
6 сообщений из 6, страница 1 из 1
Форумы / FoxPro, Visual FoxPro [игнор отключен] [закрыт для гостей] / Поможите select написать
Найденые пользователи ...
Разблокировать пользователей ...
Читали тему (0):
Читали форум (0):
Пользователи онлайн (0):
Польз. соглашение   Полит. конфиден.  
NoSQL.ru       Кролег: Проекты, Новости, Чат       РЕД ФОРУМ       Фотоальбом: Участники, Встречи
Закрыть
start [/forum/topic.php?fid=41&msg=35246336&tid=1587908]:
 0ms
get settings:
 10ms
get forum list:
 19ms
check forum access:
 3ms
check topic access:
 3ms
track hit:
 54ms
get topic data:
 10ms
get forum data:
 3ms
get page messages:
 44ms
get tp. blocked users:
 1ms
others: 236ms
total:  383ms
созд. / загр.: 383ms
x
x
Закрыть


Просмотр
0 / 0
Close
Debug Console [Select Text]