**************************************************
DEFINE CLASS cus_refresh AS custom


	Height =  17 
	Width =  20 
	*-- Таймер, используется для обновления данных на форме
	orefreshtimer = ""
	*-- ID редактируемого документа
	nlinkdoc =  0 
	nparentobj_codelink =  0 
	naccess =  0 
	*-- Наименование док-та, используемое в сообщениях
	cdocname = ""
	*-- Строка, используемая в запросе
	cselectrecordssqlcmd = ""
	*-- Объект, в которм отображаются записи из курсора в котором они обновляются
	osourcerecordscontrol = .F.
	*-- Имя объекта, в котором отображаются обновляемые записи
	csourcerecordscontrol = .F.
	*-- список имен полей (через запятую), которые нужно заменить на сервере при групповой замене (метод GroupUpdate)
	ccadupdatablefieldlist = ""
	*-- Имя таблицы на SQL сервере, в которую вносятся изменения
	csql_updatetablename = ""
	*-- ключевое поле в таблице, в которую вносим изменения (используется в методе GroupUpdate)
	ccadkeyfieldlist = "LINK"
	ncadconnection =  0 
	ccadcursorschema = ""
	Name = "cus_refresh"

	*-- имя настройки для получения настроенного интервала обновлений
	cpropertynamerefreshtimerinterval = .F.
	cdocrevision = .F.
	clockrevision = .F.

	*-- имя буферной таблицы
	csql_tmptablename = .F.

	*-- Наименование объета, которому принадлежит документ
	cparentobjname = .F.

	*-- обновляемый локальный курсор
	clocalalias = .F.

	*-- Строка, которая используется в методе ChangeRecordInDoc
	cupdaterecordsqlcmd = .F.

	*-- Код документа в объектной структуре
	cobj_name = .F.

	*-- Уникальный идентификатор -код просесса (позволяет удалить затем группу блокировок, имеющих совпадающий код)
	cprocessid = .F.


	*-- Вспомогательный метод. позволяет заблокировать обновление в необходимых случаях, (до полного завершения процессов)
	PROCEDURE lockrefresh
		this.oRefreshTimer.Enabled = .f.
	ENDPROC


	*-- Вспомогательный метод. снимает ранее наложенную блокировку  периодического обновления
	PROCEDURE unlockrefresh
		this.oRefreshTimer.Enabled = .t.
	ENDPROC


	*-- Метод пытается наложить блокировку на документ, в случае успеха возвращает .t.
	PROCEDURE setdoclock
		*!*	Флаг блокировки:
		*!*	Значение
		*!*	Тип блокировки
		*!*	 1  Монопольный доступ
		*!*	 2  Совместный доступ
		*!*	 3  Непосредственная модификация документа при совместном доступе 
		*!*	(устаналвивается только при наличии ранее установленной совместной блокировки  
		*!*	и при ревизии документа не превышающей ревизию ранее установленной блокировки)
		lparameters tnLock
		if empty(tnLock)
			return .f.
		endif
		local lcSqlCmd, lcTempAlias, lcRevision
		text to lcSqlCmd noshow textmerge pretext  15 
			DocumentLock
				@Operation  = 'SET',
				@LinkDoc  = <<ltrim(str(this.nLinkDoc))>>,
				@Object = <<ltrim(str(this.nParentObj_codeLink))>>,
				@Lock  = <<ltrim(str(tnLock))>>,
				<<iif(!empty(this.cProcessId),"@Processes = '"+ this.cProcessId+"',", "")>>
				@OutputCursor =  1 
		endtext
		lcTempAlias = sys( 2015 )
		if l_sqlexec(,lcSqlCmd,lcTempAlias)> 0 
			select (lcTempAlias)
			if nRet= 1 
				this.cDocRevision = RevDoc
				this.cLockRevision = RevLock
			else
				use in select(lcTempAlias)
				return .f.
			endif
			use in select(lcTempAlias)
		else
			return .f.
		endif
		return .t.
	ENDPROC


	PROCEDURE cparentobjname_assign
		LPARAMETERS tcNewVal
		if vartype(tcNewVal)='C' and !empty(tcNewVal)
			THIS.cParentObjName = tcNewVal
			this.nParentObj_codeLink = j_getobject(tcNewVal)
		endif
	ENDPROC


	*-- Метод позволяет получить значение текущей ревизии документа
	PROCEDURE getdocrevision
		local lcSqlCmd, lcTempAlias, lcRevision
		text to lcSqlCmd noshow textmerge pretext  15 
			DocumentRevision
		               @operation = 'GET',
		               @LinkDoc = <<ltrim(str(this.nLinkDoc))>>,
		               @Object = <<ltrim(str(this.nParentObj_codeLink))>>,
		               @OutputCursor =  1 
		endtext
		lcTempAlias = sys( 2015 )
		if l_sqlexec(,lcSqlCmd,lcTempAlias)> 0 
			select (lcTempAlias)
			if nRet= 1 
				lcRevision = revDoc
			    this.nAccess = 	access
			else
				use in select(lcTempAlias)
				return .f.
			endif
			use in select(lcTempAlias)
		else
			return .f.
		endif
		return lcRevision
	ENDPROC


	PROCEDURE naccess_assign
		LPARAMETERS tnNewVal
		THIS.nAccess = tnNewVal
		if bittest(tnNewVal, 1 )
			local lcMessage
			text to lcMessage noshow textmerge pretext  7 
				Редактирование данного документа:"<<this.cDocName>>"
				в многопользовательском режиме невозможно!
			endtext
			messagebox( lcMessage,  16 , PCNAMEAPP + "Внимание")
			* закрываем форму, на которой лежит этот объект
			if type("this.parent")="O" and pemstatus(this.parent, "release",  5 )
				this.parent.Release()
			endif
		endif
	ENDPROC


	*-- переносит изм-я в лок-й курсор, привязанный к гриду или другому объекту
	PROCEDURE updatelocalcursor
		lparameters tcAliasFrom
		if !empt(this.cLocalAlias) and !empty(tcAliasFrom) and used(tcAliasFrom)
			local lnRecno
			lnRecno = recno(this.cLocalAlias)
			this.cmdUpdateLocalCursor(this.cLocalAlias, tcAliasFrom)
			if !empty(lnRecno) and recno(this.cLocalAlias)<>lnRecno
				select (this.cLocalAlias)
				locate record lnRecno
			endif
			use in select(tcAliasFrom)
		endif
	ENDPROC


	*-- Фоксовая команда для  обновления записи в локальном курсоре
	PROCEDURE cmdupdatelocalcursor
		lparameters tcTempAlias_refrTo, tcAliasFrom
		*  пример апдейта (необходимо переписать для каждой формы на свой)
		*!*	update t1 set t1.inreys=t2.inreys, t1.username=t2.username ;
		*!*						from (tcTempAlias_refrTo) t1, (tcAliasFrom) t2 ;
		*!*						where t1.link=t2.link
	ENDPROC


	*-- Метод внесения изменений в конкретную запись (строку детализации) документа
	PROCEDURE changerecordindoc
		lparameters tnLink, tuOldValue, tuNewValue
		this.lockRefresh()
		if this.BeforeChangeRecordInDoc(tnLink, tuOldValue) and this.CreateUpdateCmd(tnLink,tuNewValue)
			local llSuccess
			* изменяем значение
			if l_sqlexec(,this.cUpdateRecordSqlCmd)> 0  and this.AfterUpdateSql()
				llSuccess = .t.
			endif
			this.UnlockRefresh()
			return llSuccess
		else
			this.UnlockRefresh()
			return .f.
		endif
	ENDPROC


	*-- формирователь строки cUpdateRecordSqlCmd, используемой в методе ChangeRecordInDoc
	PROCEDURE createupdatecmd
		* метод формирует строку, используемую в методе 
		lparameters tnLink, tuValue
		* для каждого документа этот апдейт должен быть исправлен
		* пример
		*!*		text to this.cUpdateRecordSqlCmd noshow textmerge pretext  15 
		*!*			update <<this.cSql_updateTableName>> set marker =  1 , inreys = <<ltrim(str(tuValue))>>
		*!*					where link=<<ltrim(str(tnLink))>>
		*!*		endtext
		return .t.
	ENDPROC


	*-- Метод выполняется до выполнения метода ChangeRecordInDoc   если этот метод вернет ложь, то никакого апдейта выполнено не будет
	PROCEDURE beforechangerecordindoc
		lparameters tnLink, tuOldValue
		* необходимо проверять перед изменением
		* редактировалась ли запись кем-то
		return .t.
		*!*	local lcSqlCmd, lcTempAlias
		*!*	local lcTempAlias
		*!*	lcTempAlias = sys( 2015 )
		*!*	* смотрим, не изменил ли еще кто-то значение
		*!*	text to lcSqlCmd noshow textmerge pretext  15 
		*!*		select marker, username
		*!*			from <<this.cSql_tmpTableName>>
		*!*					where link=<<ltrim(str(tnLink))>>
		*!*	endtext
		*!*	if l_sqlexec(,lcSqlCmd,lcTempAlias)> 0 
		*!*		select (lcTempAlias)
		*!*		if marker<>tnOldValue
		*!*			with this
		*!*				.UpdateLocalCursor(lcTempAlias)
		*!*				.aGrid1.refresh()
		*!*			endwith
		*!*			*messagebox('Значение изменено!')
		*!*			return .f.
		*!*	    endif
		*!*	else
		*!*		return .f.
		*!*	endif 
		*!*	return .t.
	ENDPROC


	PROCEDURE refreshdoc
		lparameters tlRefreshAlways
		* tlRefreshAlways = .t.
		* производит обновление без сравнения .cDocRevision > .cLockRevision
		with this
			local lcAllertMessage
			text to lcAllertMessage noshow textmerge pretext  7 
				Другим пользователем закрыт доступ к документу '<<.cDocName>>'.
				Выйти из режима редактирования?
			endtext
			if !.SetDocLock( 2 ) and MESSAGEBOX(lcAllertMessage, 68 ,'Внимание')= 6  ;
				and type("this.parent")="O" and pemstatus(this.Parent, "release",  5 )
					this.parent.Release()
			endif
			if tlRefreshAlways or (.cDocRevision > .cLockRevision)
				* кто-то изменил документ,
				* нужно сделать на клиенте данные актуальными
				.ShowWaitMsg()
				local lcSqlCmd
				lcSqlCmd = .cSelectRecordsSqlCmd
				if !empty(lcSqlCmd)
					local lcTempAlias
					lcTempAlias = sys( 2015 )
					if l_sqlexec(, lcSqlCmd, lcTempAlias)> 0 
						* получили назад курсор
						this.UpdateLocalCursor(lcTempAlias)
						if vartype(.oSourceRecordsControl)='O' and pemstatus(.oSourceRecordsControl,'tt', 5 )
							.oSourceRecordsControl.refresh()
						endif
					endif
				endif
				.CleareWaitMsg()
			endif
		endwith
	ENDPROC


	*-- Метод для отображения процесса обновления
	PROCEDURE showwaitmsg
		* метод может быть переписан под конкретные нужды
		if type("this.parent")="O" and pemstatus(this.Parent, "OleStatusBar",  5 )
			this.Parent.OleStatusBar.Panels( 1 ).Text = "Ждите... Происходит обновление данных ..."
		endif
	ENDPROC


	*-- Метод очистки сообщений, используемых для отображения процесса обновления
	PROCEDURE clearewaitmsg
		* метод может быть переписан под конкретные нужды
		if type("this.parent")="O" and pemstatus(this.Parent, "OleStatusBar",  5 )
			this.Parent.OleStatusBar.Panels( 1 ).Text = ""
		endif
	ENDPROC


	*-- формирователь строкиcSelectRecordsSqlCmd, используемой в методе RefreshDoc
	PROCEDURE createselectcmd
		* метод переписывается под конкретные нужды
		* формирователь строки cSelectRecordsSqlCmd,
		* используемой в методе RefreshDoc
		* этот запрос возвращает назад все актуальные записи в док-те
		* пример:
		*!*	text to this.cSelectRecordsSqlCmd noshow textmerge pretext  15 
		*!*		Exec select_doc_x401002_mu  @nMode =  2 , @nLink = <<ltrim(str(this.nLinkDoc))>>, @cInto = <<this.cSql_tmpTableName>>
		*!*	endtext 
		return .t.
	ENDPROC


	PROCEDURE csourcerecordscontrol_assign
		LPARAMETERS tcNewVal
		if empty(tcNewVal) or vartype(tcNewVal)<>C
			this.cSourceRecordsControl  = tcNewVal
			try
				this.oSourcerecordscontrol = evaluate(tcNewVal)
			catch
				messagebox('Ошибка привязки объекта cus_Refresh к объекту отображ-я данных.', 16 )
			endtry
		endif
	ENDPROC


	*-- Метод снимает блокировку с документа, в случае успеха возвращает .t.
	PROCEDURE unlockdoc
		local lcSqlCmd, lcTempAlias
		text to lcSqlCmd noshow textmerge pretext  15 
			Exec DocumentLock
				@Operation  = 'DEL',
				@LinkDoc  = <<ltrim(str(this.nLinkDoc))>>,
				@Object = <<ltrim(str(this.nParentObj_codeLink))>>,
				@OutputCursor =  1 
		endtext
		* Exec select_doc_x401002_mu  @nMode =  3 , @cInto = <<this.cSql_tmpTableName>>
		lcTempAlias = sys( 2015 )
		if l_sqlexec(,lcSqlCmd,lcTempAlias)> 0 
			select (lcTempAlias)
			if nRet<> 1 
				use in select(lcTempAlias)
				return .f.
			endif
			use in select(lcTempAlias)
		else
			return .f.
		endif
		return .t.
	ENDPROC


	PROCEDURE groupupdate
		* tuValue - передаем и разбираем в методе cmdGroupUpdateLocalCursor
		lparameters tuValue &&одно значение, или объект-пакет со свойствами - значениями
		if empty(this.cCADkeyFieldList) or empty(this.cCADupdatableFieldList)
			messagebox('КАД. Неверно настроены свойства у класса!', 16 )
			return .f.
		endif
		local lnConnection
		if this.nCadConnection> 0 
			lnConnection = this.nCadConnection
		else
			local llSuccess
			for lnConnection= 1  to  1000 
				if sqlexec(lnConnection,"select @@SERVERNAME")> 0 
					llSuccess = .t.
					exit
				endif 
			endfor
			use in select("sqlresult")
			lnConnection = iif(llSuccess, lnConnection,  0 )
		endif
		if lnConnection> 0 
			this.lockRefresh()
			this.ShowWaitMsg() 
			local loCad
			loCad = createobject('cad_updater')
			if vartype(loCad)='O'
				with loCad
					.DataSource     	= cast(lnConnection as integer)
					text to .SelectCmd noshow textmerge pretext  15 
						select <<this.cCADkeyFieldList>>, <<this.cCADupdatableFieldList>>
							from <<this.cSql_updateTableName>>
					endtext
					.Tables             = this.cSql_updateTableName
					.keyFieldList		= this.cCADkeyFieldList
					.cursorsChema 		= this.cCADcursorSchema  &&"Fld c(16)"
					.UpdatableFieldList = this.cCADupdatableFieldList &&'Fld1, Fld2'
					local laFieldsArr( 1 ), lnUpdFields, lnField, lcField, lcLocalFldsUpdCmdADD
					lnUpdFields = alines(laFieldsArr,.UpdatableFieldList,',')
					* формируем строку
					.updateNameList 	=  this.cCADkeyFieldList + ' ' + .Tables+'.'+this.cCADkeyFieldList
					lcLocalFldsUpdCmdADD = ''
					for lnField= 1  to lnUpdFields
						lcField = alltrim(laFieldsArr(lnField))
						if !empty(lcField)
							lcLocalFldsUpdCmdADD = lcLocalFldsUpdCmdADD + iif(!empty(lcLocalFldsUpdCmdADD) ,', ','') + lcField + '=t2.' + lcField
							.updateNameList = .updateNameList +iif(!empty(.updateNameList),', ','') + lcField + ' ' + .Tables+'.'+lcField
						endif
					endfor
					if .CursorFill(!empty(.cursorschema)) && тянем таблицу с сервера
						* вносим изменения в курсор КАДа
						local lnLocalRecno, lnSqlTranOld
						lnLocalRecno = recno(this.cLocalAlias)
						if this.cmdGroupUpdateLocalCursor(loCad,tuValue) 
							if !empty(lnLocalRecno) and recno(this.cLocalAlias)<>lnLocalRecno
								select (this.cLocalAlias)
								locate record lnLocalRecno
							endif
							if !empty(getNextModified( 0 ,.Alias))
								* если шо-то потрогали
								* сохраняем изменения на сервер
								lnSqlTranOld = sqlgetprop(lnConnection,"Transactions")
								if sqlsetprop( lnConnection, "Transactions",  2 )= 1 
									if !tableupdate(.t.,.t.,.Alias)
										* ошибка, не смогли сохранить изменения на сервер
										=sqlrollback(lnConnection)
										local laErrors, lcErrMessage
										=aerror(laErrors)
										text to lcErrMessage noshow textmerge pretext  7 
											КАД. Ошибка сохранения изменений в таблице <<.Tables>>.
											<<iif(alen(laErrors)>= 2 ,laErrors[ 2 ],'Ошибка не идентифицирована.')>>
										endtext
						    			messagebox(lcErrMessage, 16 )
						    			this.CleareWaitMsg()
						    			this.UnLockRefresh()
										return .f.
									else &&!tableupdate(.t.,.t.,.Alias)
										* все хорошо, сохранились
										=sqlcommit(lnConnection)
										if !this.AfterUpdateSql() 
						    				this.CleareWaitMsg()
						    				this.UnLockRefresh()
						    				return .f.
										endif
										this.refreshDoc(.t.)
										this.oRefreshTimer.Reset()
									endif &&!tableupdate(.t.,.t.,.Alias)
								else
									=sqlsetprop(lnConnection, "Transactions", lnSqlTranOld)
									=messagebox('КАД. Ошибка выполнения транзакции на сервере.', 16 )
					    			this.CleareWaitMsg()
					    			this.UnLockRefresh()
									return .f.
								endif
								=sqlsetprop(lnConnection, "Transactions", lnSqlTranOld)
							endif
						else
							if !empty(lnLocalRecno) and recno(this.cLocalAlias)<>lnLocalRecno
								select (this.cLocalAlias)
								locate record lnLocalRecno
							endif
						endif
					else
						messagebox('КАД. Ошибка чтения записей на сервере.', 16 )
		    			this.CleareWaitMsg()
		    			this.UnLockRefresh()
						return .f.
		 			endif
				endwith
			else
				messagebox('КАД. Ошибка при инициализации.', 16 )
				this.CleareWaitMsg()
				return .f.
			endif
		else
			messagebox('КАД. Ошибка соединения.', 16 )
			this.nCadConnection = lnConnection
			this.CleareWaitMsg()
			return .f.
		endif
		if this.nCadConnection<>lnConnection
			this.nCadConnection = lnConnection
		endif
		this.CleareWaitMsg()
		this.UnLockRefresh()
		return .t.  && благополучно ушли взад
	ENDPROC


	*-- Фоксовая команда для обновления записей в КАДе в зависимости от выбранных записей в локальном курсоре вызывается из метода GroupUpdate
	PROCEDURE cmdgroupupdatelocalcursor
		lparameters toCad, tuValue
		*  пример апдейта (необходимо переписать для каждой формы на свой)
		*!*	update t1 set t1.marker= 1 , t1.inreys=tuValue ;
		*!*		from (toCad.Alias) t1, (this.cLocalAlias) t2 ;
		*!*		where t1.link=t2.link and t2.checked= 1 
		return .t.
	ENDPROC


	*-- метод выполняется  в методе GroupUpdate после успешного внесения изменений во врем.таблицы
	PROCEDURE afterupdatesql
		local lcSqlCmd, lcTempAlias, lcRevision
		local lcTempAlias
		lcTempAlias = sys( 2015 )
		lcSqlCmd = this.cSelectRecordsSqlCmd
		if !empty(lcSqlCmd) and l_sqlexec(,lcSqlCmd, lcTempAlias)> 0 
			text to lcSqlCmd noshow textmerge pretext  15 
				Exec DocumentRevision
					@operation = 'SET',
					@LinkDoc = <<ltrim(STR(this.nLinkDoc))>>,
					@Object = <<ltrim(str(this.nParentObj_codeLink))>>,
					@OutputCursor =  1 
			endtext 
			if l_sqlexec(,lcSqlCmd, lcTempAlias)> 0 
				select (lcTempAlias)
				this.cDocRevision = revDoc
				this.nAccess = 	access
			endif
			use in select(lcTempAlias)
		else
			return .f.
		endif
		return .t.
	ENDPROC


	PROCEDURE cselectrecordssqlcmd_access
		with this
			if empty(.cSelectRecordsSqlCmd)
				.CreateSelectCmd()
			endif
			return .cSelectRecordsSqlCmd
		endwith
	ENDPROC


	*-- Устанавливает необходимую блокировку на необходимую запись в док-те, в случае успеха возвращает .t.
	PROCEDURE setrecordlock
		*!*	Флаг блокировки:
		*!*	Значение
		*!*	Тип блокировки
		*!*	 1  Монопольный доступ
		*!*	 2  Совместный доступ
		*!*	 3  Непосредственная модификация документа при совместном доступе 
		*!*	(устаналвивается только при наличии ранее установленной совместной блокировки  
		*!*	и при ревизии документа не превышающей ревизию ранее установленной блокировки)
		lparameters tnLock, ;
					tnRecordLink, ;
					tnRecordObj_codeLink, ;
					tcRecordRevision, ;
					tnRecordLockRevision

		if empty(tnLock)
			return .f.
		endif
		local lcSqlCmd, lcTempAlias, lcRevision
		text to lcSqlCmd noshow textmerge pretext  15 
			DocumentLock
				@Operation  = 'SET',
				@LinkDoc  = <<ltrim(str(tnRecordLink))>>,
				@Object = <<ltrim(str(tnRecordObj_codeLink))>>,
				@Lock  = <<ltrim(str(tnLock))>>,
				<<iif(!empty(this.cProcessId),"@Processes = '"+ this.cProcessId+"',", "")>>
				@OutputCursor =  1 
		endtext
		lcTempAlias = sys( 2015 )
		if l_sqlexec(,lcSqlCmd,lcTempAlias)> 0 
			select (lcTempAlias)
			if nRet= 1 
				tcRecordRevision = RevDoc
				tnRecordLockRevision = RevLock
			else
				use in select(lcTempAlias)
				return .f.
			endif
			use in select(lcTempAlias)
		else
			return .f.
		endif
		return .t.
	ENDPROC


	*-- Метод снимает блокировку с записей документа,(отличен от метода UnlockDoc тем, что имеется возможность указать линк док-та и код документа (списочной части док-та) (детализации), возвращает .t. в случае успеха
	PROCEDURE unlockrecord
		lparameters tnRecordLink, ;
					tnRecordObj_codeLink

		local lcSqlCmd, lcTempAlias
		text to lcSqlCmd noshow textmerge pretext  15 
			Exec DocumentLock
				@Operation  = 'DEL',
				@LinkDoc  = <<ltrim(str(tnRecordLink))>>,
				@Object = <<ltrim(str(tnRecordObj_codeLink))>>,
				@OutputCursor =  1 
		endtext
		lcTempAlias = sys( 2015 )
		if l_sqlexec(,lcSqlCmd,lcTempAlias)> 0 
			select (lcTempAlias)
			if nRet<> 1 
				use in select(lcTempAlias)
				return .f.
			endif
			use in select(lcTempAlias)
		else
			return .f.
		endif
		return .t.
	ENDPROC


	*-- Возвращает имя пользователя, установившего блокировку
	PROCEDURE getlockusername
		lparameters tnLinkDoc, tnObject, tcRevision
		local lcSqlCmd, lcTempAlias, lcUserName
		text to lcSqlCmd noshow textmerge pretext  15 
			select top  1  UserName
				from Documents_Lock
				where LinkDoc = <<ltrim(str(iif(empty(tnLinkDoc),  0 , tnLinkDoc)))>>	and
					  Object = <<ltrim(str(iif(empty(tnObject),  0 , tnObject)))>>
					  <<iif(!empty(tcRevision), " and Revision='"+tcRevision+"'", " order by revision desc")>>
		endtext
		lcTempAlias = sys( 2015 )
		if l_sqlexec(,lcSqlCmd,lcTempAlias)> 0  and used(lcTempAlias)
			select (lcTempAlias)
			lcUserName = alltrim(nvl(UserName,""))
			use in select(lcTempAlias)
		else
			store "" to lcUserName
		endif
		return lcUserName
	ENDPROC


	*-- Снятие блокировки со всего документя, включая его записи (детализацию)  (возможно при заранее установленном свойстве cProcessId)
	PROCEDURE unlockall
		if empty(this.cProcessId)
			return .f.
		else
			local lcSqlCmd, lcTempAlias
			text to lcSqlCmd noshow textmerge pretext  15 
				Exec DocumentLock
					@Operation  = 'DEL',
					@Processes  = '<<this.cProcessId>>',
					@OutputCursor =  1 
			endtext
			lcTempAlias = sys( 2015 )
			if l_sqlexec(,lcSqlCmd,lcTempAlias)> 0 
				select (lcTempAlias)
				if nRet<> 1 
					use in select(lcTempAlias)
					return .f.
				endif
				use in select(lcTempAlias)
			else
				return .f.
			endif
			return .t.
		endif
	ENDPROC


	PROCEDURE generatecprocessid
		if !empty(this.nParentobj_codelink) and !empty(this.nLinkDoc)
			this.cProcessId = d_chr_10to36(this.nParentobj_codelink, 3 ) + ;
							  d_chr_10to36(this.nLinkDoc, 4 ) + ;
							  ltrim(str(arm_user.user_id))
		endif
	ENDPROC


	PROCEDURE Destroy
		this.lockRefresh()
		store .f. to this.oSourceRecordsControl 
		if !empty(this.cLockRevision)
			* снимаем блокировку с документа
			this.unlockDoc()
		endif
		*!*	if !empty(this.nCadConnection)
		*!*		sqldisconnect(this.nCadConnection)
		*!*	endif
	ENDPROC


	PROCEDURE Init
		with this
			.oRefreshTimer = createobject('MuRefreshTimer')
			if vartype(.oRefreshTimer)<>'O'
				=messagebox('Ошибка создания объекта таймера обновлений!', 16 )
				return .f.
			endif
			local lnRefreshInterval
			* если есть настройка, то смотрим интервал
			if !empty(.cPropertyNameRefreshTimerInterval)
				try
					lnRefreshInterval = abs(A_GET_PROP ("", .cObj_name, .cPropertyNameRefreshTimerInterval)* 1000 )
				catch 
				endtry
				if vartype(lnRefreshInterval)<>'N' or empty(lnRefreshInterval)
					local lcErrMsg
					text to lcErrMsg noshow pretext  7 
						Проверьте значение настройки [Интервал отображения изменений (сек.)]
						Интервал установлен в  10  сек. (по умолчанию)
					endtext 
					messagebox(lcErrMsg, 64 ,PCNAMEAPP + "Внимание")
					lnRefreshInterval =  10000 
				endif
			else
				lnRefreshInterval =  10000 
			endif &&!empty(.cPropertyNameRefreshTimerInterval)
			with .oRefreshTimer
				.oParent = this
				.enabled = .f.
				.interval = lnRefreshInterval
			endwith 
			if !empty(.cParentObjName) and empty(.nParentObj_CodeLink)
				.cParentObjName_Assign(.cParentObjName)
			endif
			if !empty(.cSourceRecordsControl) and vartype(.oSourceRecordsControl)<>'O'
			  	.cSourceRecordsControl_Assign(.cSourceRecordsControl)
			endif
		endwith
	ENDPROC


	*-- Метод формирует стандартный идентификатор
	PROCEDURE getrecordaccess
	ENDPROC


ENDDEFINE
*
*-- EndDefine: cus_refresh
**************************************************

local lcObjName, loCus1, loObj 
loCus1 = createobject("custom")
loCus1.addproperty("oCus2", createobject("custom"))
loCus1.oCus2.addproperty("cValue", "123")

lcObjName = "oCus2"

loObj = getpem(loCus1, lcObjName)
? loObj.cValue

local lcObjName, loCus1, loObj 
loCus1 = createobject("custom")
loCus1.addproperty("oCus2", createobject("custom"))
loCus1.oCus2.addproperty("cValue", "123")

? pemstatus(loCus1, "oCus2",  5 )

? pemstatus(loCus1, "tutytu",  5 )