#DEFINE cnSumma  0000000000 . 0000 
SET DATE TO GERMAN
SET TALK OFF
CLOSE TABLES ALL
USE Prixod.Dbf IN  0 
USE Rasxod.Dbf IN  0 

*-* (IGEL) Заполняем шаблон дат полным пересечением дат.
CREATE CURSOR CurDates (Datum D)
CALCULATE MIN(Od_Tar), MAX(Od_Tar) TO ldMinDt1, ldMaxDt1 IN Prixod
CALCULATE MIN(Yukl_Tar), MAX(Yukl_Tar) TO ldMinDt2, ldMaxDt2 IN Rasxod
ldMinDt = MIN(ldMinDt1, ldMinDt2)
ldMaxDt = MAX(ldMaxDt1, ldMaxDt2)
ldMinDt = DATE(YEAR(ldMinDt), MONTH(ldMinDt),  1 )
ldMaxDt = GOMONTH(DATE(YEAR(ldMaxDt), MONTH(ldMaxDt),  1 ),  1 )- 1 
IF EMPTY(ldMinDt) OR EMPTY(ldMaxDt)
	=MESSAGEBOX("Не вычислили минимальную/максимальную дату")
	RETURN .T.
ENDIF
ldDate = ldMinDt
DO WHILE ldDate < ldMaxDt +  1 
	INSERT INTO CurDates VALUES (ldDate)
	ldDate = ldDate +  1 
ENDDO
SELECT CurDates
GO TOP && Шобы рашмор TABLEUPDATE сделал.

*-* (IGEL) Получаем полное пересечение дат с контрагентами... Будет шаблон такой.
*-* (IGEL) Чтоб не тормозило можно разбить на  2  выборки. У меня не тормозит.
SELECT DISTINCT ;
	CurDates.Datum, ;
	NVL(Prixod.Muas_K, Rasxod.Muas_K) AS Muas_K ;
	FROM Prixod, Rasxod, CurDates ;
	INTO CURSOR CurTempl NOFILTER
	
*-* (IGEL) Получаем полный список приходов и расходов по дням
SELECT ;
	Od_Tar				AS Datum, ;
	Muas_K				AS Muas_K, ;
	SUM(Mebleg_D)		AS Prixod, ;
	MAX(cnSumma)		AS Rasxod ;
	FROM Prixod ;
	GROUP BY  1 ,  2  ;
UNION ALL SELECT ;
	Yukl_Tar			AS Datum, ;
	Muas_K				AS Muas_K, ;
	MAX(cnSumma)		AS Prixod, ;
	SUM(Mebleg_D)		AS Rasxod ;
	FROM Rasxod ;
	GROUP BY  1 ,  2  ;
	INTO CURSOR CurOborot NOFILTER READWRITE
	
*-* (IGEL) Рассчитываем сальду по датам
SELECT ;
	CL.Datum, ;
	CL.Muas_K, ;
	NVL(SUM(CR.Prixod), cnSumma)								AS FullPrixod, ;
	NVL(SUM(CR.Rasxod), cnSumma)								AS FullRasxod, ;
	SUM(IIF(CR.Datum = CL.Datum, CR.Prixod, cnSumma))			AS Prixod, ;
	SUM(IIF(CR.Datum = CL.Datum, CR.Rasxod, cnSumma))			AS Rasxod, ;
	NVL(SUM(CR.Prixod), cnSumma) - NVL(SUM(CR.Rasxod), cnSumma)	AS Saldo ;
	FROM CurTempl CL ;
	LEFT OUTER JOIN CurOborot CR ON CR.Datum <= CL.Datum ;
								AND CR.Muas_K = CL.Muas_K ;
	GROUP BY  1 ,  2  ;
	ORDER BY  2 ,  1  ;
	INTO CURSOR CurSaldo NOFILTER READWRITE