DEFINE CLASS clsini AS custom


	Height =  101 
	Width =  199 
	Name = "clsini"

	*-- Файл с параметрами
	PROTECTED cinifile


	*-- Установка имени ini-файла
	PROCEDURE setinifile
		lpara tcIniFile
		this.cIniFile = fullpath(tcIniFile)
	ENDPROC


	*-- Установка значения параметра
	PROCEDURE set
		lpara tuValue, tcKey, tcSection
		local lcS, lcCentury
		if empty(tcSection)
			tcSection = 'Common'
		endif

		if vartype(tuValue) = 'C'
			lcS = ''
		else
			lcS = '[' + vartype(tuValue) + '] '
		endif
		lcCentury = set('century')
		set century on
		do case
			case vartype(tuValue) = 'C'
				lcS = lcS + tuValue
			case vartype(tuValue) = 'D'
				lcS = lcS + dtoc(tuValue)
			case vartype(tuValue) = 'T'
				lcS = lcS + ttoc(tuValue)
			case vartype(tuValue) = 'L'
				lcS = lcS + iif(tuValue, 'TRUE', 'FALSE')
			case vartype(tuValue) = 'N'
				lcS = lcS + alltrim(str(tuValue, 20 , 9 ))
				do while .t.
					lcK = right(lcS, 1 )
					if lcK = Set('point') or lcK = '0'
						lcS = left(lcS, len(lcS) -  1 )
						if lcK = Set('point')
							exit
						endif
					else
						exit
					endif
				enddo
		endcase
		set century &lcCentury

		WritePrivateProfileString(tcSection, tcKey, lcS, this.cIniFile)
	ENDPROC


	*-- Получение значения параметра
	PROCEDURE get
		lpara tcKey, tcSection, tuDefault
		local lcVal, lnLen, lcType, luRet

		if parameters() <  3 
			tuDefault = ''
		endif
		if empty(tcSection)
			tcSection = 'Common'
		endif

		lcVal = space( 2000 )
		lnLen = GetPrivateProfileString(tcSection, tcKey, '', @lcVal,  2000 , fullpath(this.cIniFile))
		lcVal = left(lcVal, lnLen)

		if left(lcVal,  1 ) == '[' and substr(lcVal,  3 ,  2 ) == '] '
			lcType = substr(lcVal,  2 ,  1 )
			lcVal = substr(lcVal,  5 )
		else
			lcType = '*'
		endif
		do case
			case lcType == 'C'
				luRet = lcVal
			case lcType == 'D'
				luRet = ctod(lcVal)
			case lcType == 'T'
				luRet = ctot(lcVal)
			case lcType == 'N'
				luRet = ValWithPoint(lcVal)
			case lcType == 'L'
				luRet = (lcVal = 'TRUE')
			otherwise
				if empty(lcVal) and (vartype(tuDefault) != 'C' or !empty(tuDefault))
					luRet = tuDefault
					this.Set(luRet, tcKey, tcSection)
				else
					luRet = lcVal
				endif
		endcase
		return luRet
	ENDPROC


	PROCEDURE Init
		if type('glDeclareIniDll') = 'U'
			public glDeclareIniDll
			DECLARE INTEGER GetPrivateProfileString IN Win32API AS GetPrivateProfileString;
				String cSection,String cKey,String cDefault,String @cBuffer,;
				Integer nBufferSize, String cINIFile
			DECLARE INTEGER WritePrivateProfileString IN Win32API AS WritePrivateProfileString;
				String cSection,String cKey,String cValue,String cINIFile
		endif
		this.cIniFile = 'param.ini'
	ENDPROC


ENDDEFINE