oleDragOver
lparameters data, effect, button, shift, x, y, state

if type('Row_id')<>'C' or SIGN<> 7 
   return 
endif

local llSuccess
try
	* Подсвечиваю элемент, находящийся под указателем мыши
	this.DropHighlight = this.HitTest(x*thisform.nPTRatioX, y*thisform.nPTRatioY)
	llSuccess = .t.
catch
endtry
if !llSuccess
	return
endif

if !pemstatus(_screen,'oDragRelation', 5 )
   _screen.AddProperty('oDragRelation')
endif
* запоминаю Row_id записи, которую тащу
if vartype(_screen.oDragRelation)<>'O'
	scatter fields row_id,name name _screen.oDragRelation
endif

oleDragDrop 
LPARAMETERS data, effect, button, shift, x, y

* натащили сюда и отпустили кнопку мыши
local loDrop, llSuccess
try
	loDrop = this.DropHighlight
	llSuccess = .t.
catch
endtry
if llSuccess and !isnull(loDrop) and pemstatus(_screen,'oDragRelation', 5 ) and ;
   vartype(_screen.oDragRelation)='O' and !empty(nvl(_screen.oDragRelation.Row_id,''))
	* прыг на нужную запись
	this.nodeClick(loDrop)
	if type('Row_id')<>'C' or SIGN<> 7 
		* если это не документы прошлого года - ушли взад
		store null to this.DropHighlight, _screen.oDragRelation
		return
	endif
	local loDocTo
	scatter fields row_id,name name loDocTo
	if !empty(nvl(loDocTo.Row_id,'')) and SIGN= 7   && смотрим, чтобы он был документом прошлого года
		if loDocTo.Row_id=_screen.oDragRelation.Row_id
			store null to this.DropHighlight, _screen.oDragRelation
			messagebox('Укажите документ правильно!', 16 ,pcNameApp)
			return 
		endif
		if messagebox('Привязать ' + chr( 13 ) + ;
					  'документ: ' + alltrim(_screen.oDragRelation.name) + chr( 13 ) + ;
					  'к док-ту: ' + alltrim(loDocTo.name)+ ' ?', 33 ,pcNameApp) =  1 
			* привязываем документ
			public pnResult
			pnResult =  0 
			text to lcSelectCmd textmerge noshow pretext  7 
			     {?@pnResult = CALL dbo.SELECT_DOC_BD_LY_RELATION_EDIT('<<_screen.oDragRelation.Row_id>>','<<loDocTo.Row_id>>')}
			endtext
			if L_SQLEXEC (m.Handle,lcSelectCmd)> 0  and pnResult> 0 
				* успешно привязали
				* переначитываем дерево 
				Thisform.DATA_REFRESH( 0 ,.f.)
		   	endif
		 endif
	 else
		messagebox('Возможна привязка только документов прошлого года!', 16 ,pcNameApp)
	 endif
endif
store null to this.DropHighlight, _screen.oDragRelation