PUBLIC goFrmMain  
  goFrmMain = CREATEOBJECT("frmMain")  
  m.goFrmMain.Show()  
    
  DEFINE CLASS frmMain AS Form  
  DataSession =  2   
  Caption = "Main"  
  Height =  450   
  Width =  300   
  oChild = .F.  
  AlwaysOnTop  = .t.
  
  ADD OBJECT grd1 AS Grid WITH ;  
   RecordSource = "tmp1", Height =  400 , Width =  300   
  ADD OBJECT cmdCall AS Commandbutton WITH ;  
   Caption = "Child", Top =  410 , Height =  30 , ;  
   Left =  50 , Width =  200   
    
  PROCEDURE Load  
   CREATE CURSOR tmp1 (nID I)  
   LOCAL ln1  
   FOR ln1 =  1  TO  10   
    INSERT INTO tmp1 (nID) VALUES (m.ln1)  
   ENDFOR  
   GO TOP IN tmp1  
  ENDPROC  
  PROCEDURE grd1.AfterRowColChange  
   LPARAMETERS tnColIndex  
   IF TYPE("ThisForm.oChild.Name") = "C"  
    ThisForm.oChild.Refresh()  
   ENDIF  
  ENDPROC  
  PROCEDURE cmdCall.Click  
   IF TYPE("ThisForm.oChild.Name") # "C"  
    ThisForm.oChild = CREATEOBJECT("frmChild")  
   ENDIF  
   ThisForm.oChild.Show()  
  ENDPROC  
  ENDDEFINE  
    
  DEFINE CLASS frmChild AS Form  
  DataSession =  1   
  Caption = "Child"  
  Width =  100   
  Height =  90   
  Top =  100   
  Left =  320   

  ADD OBJECT txt1 AS Textbox WITH ;  
  ControlSource = "tmp1.nID", Width =  80 , Height =  20 , ;  
   Top =  10 , Left =  10   
  ADD OBJECT cmdClose AS Commandbutton WITH ;  
   Caption = "Close", Top =  50 , Height =  30 , ;  
   Left =  10 , Width =  80   
    
  PROCEDURE cmdClose.Click  
   ThisForm.Release()  
  ENDPROC  
  ENDDEFINE