************************************************************************************
* Функция:		OOoCreateDocument
* Назначение:	Создать чистый документ OO и вернуть объект для общения с ним
* Возврат:		{OBJECT} - оле объект, содержащий открытый документ OpenOffice
* Параметры:	Тип документа:  1  - calc,  2  - write,  3  - draw,  4  - math,  5  - impress
* Автор:		Кручинин П.Н. ( 2005 - 09 - 28 )
************************************************************************************
FUNCTION OOoCreateDocument
	LPARAMETERS uType
	
	DO CASE 
		CASE VARTYPE(uType)="N" AND uType= 1 
			cName = "scalc"
		CASE VARTYPE(uType)="N" AND uType= 2 
			cName = "swriter"
		CASE VARTYPE(uType)="N" AND uType= 3 
			cName = "sdraw"
		CASE VARTYPE(uType)="N" AND uType= 4 
			cName = "smath"
		CASE VARTYPE(uType)="N" AND uType= 5 
			cName = "simpress"
		CASE VARTYPE(uType)="C" AND LOWER(uType)="calc"
			cName = "scalc"
		CASE VARTYPE(uType)="C" AND LOWER(uType)="write"
			cName = "swriter"
		CASE VARTYPE(uType)="C" AND LOWER(uType)="draw"
			cName = "sdraw"
		CASE VARTYPE(uType)="C" AND LOWER(uType)="math"
			cName = "smath"
		CASE VARTYPE(uType)="C" AND LOWER(uType)="impress"
			cName = "simpress"			
		OTHERWISE
			RETURN NULL
	ENDCASE

	LOCAL loOfcMgr, loDesktop, loDocument, args( 1 ), ;
	loCoreReflection, loPropertyValue

	* Create the Service Manager and Desktop
	loOfcMgr = CreateObject("com.sun.star.ServiceManager")
	loDesktop = loOfcMgr.createInstance("com.sun.star.frame.Desktop")

	loPropertyValue = loOfcMgr.Bridge_GetStruct( "com.sun.star.beans.PropertyValue" ) 
    loPropertyValue.Name = "Hidden"  
  	loPropertyValue.Value = .F. 

	args[ 1 ] = loPropertyValue 

	* Tell VFP to pass arrays to the loDesktop object as zero-based, by reference
	COMARRAY(loDesktop, 10 )
	* Open a new empty writer document
	loDocument = loDesktop.loadComponentFromURL("private:factory/" + cName,"_blank",  0 , @args)
	RETURN loDocument
ENDFUNC