#define HANDLE INTEGER
#define BOOLEAN LONG

PROCEDURE PrintTextFile
 LPARAMETERS cFileName as String

 LOCAL hPrinter as Integer
 LOCAL cPrinter as String
 LOCAL cString as String
 LOCAL nWritten as Long
 LOCAL oPB as Object
 LOCAL hFile as Integer
 LOCAL nAll as Long
 LOCAL nCur as Long

 IF .NOT.FILE(m.cFileName) THEN
  MESSAGEBOX("Файл "+m.cFileName+" не найден!", 16 ,"Печать файла")
  RETURN .F.
 ENDIF

 DECLARE BOOLEAN OpenPrinterA IN WINSPOOL.DRV AS OpenPrinter ;
  STRING pPrinterName, ;
  HANDLE @phPrinter, ;
  LONG pDefault

 DECLARE LONG StartDocPrinterA IN WINSPOOL.DRV AS StartDocPrinter ;
  HANDLE hPrinter, ;
  LONG Level, ;
  STRING pDocInfo

 DECLARE BOOLEAN EndDocPrinter IN WINSPOOL.DRV AS EndDocPrinter ;
  HANDLE hPrinter

 DECLARE BOOLEAN WritePrinter IN WINSPOOL.DRV AS WritePrinter ;
  HANDLE hPrinter, ;
  STRING pBuf, ;
  LONG cbBuf, ;
  LONG @pcWritten

 DECLARE BOOLEAN ClosePrinter IN WINSPOOL.DRV AS ClosePrinter ;
  HANDLE hPrinter

 DECLARE LONG GetLastError IN WIN32API as GetLastError

 m.cPrinter=GETPRINTER()
 IF ISBLANK(m.cPrinter) THEN
  RETURN .F.
 ENDIF

 m.hFile=FOPEN(m.cFileName)
 IF m.hFile< 0  THEN
  MESSAGEBOX("Hе удалось открыть файл "+m.cFileName+"!", 16 ,"Печать файла")
  RETURN .F.
 ENDIF

 IF OpenPrinter(m.cPrinter,@m.hPrinter, 0 )= 0  THEN
  FCLOSE(m.hFile)
  m.nWritten=GetLastError()
  MESSAGEBOX("Произошла ошибка при печати! Код ошибки "+ALLTRIM(STR(m.nWritten, 10 , 0 )), 48 ,"Печать файла")
  RETURN .F.
 ENDIF

 IF StartDocPrinter(m.hPrinter, 1 ,REPLICATE(CHR( 0 ), 12 ))= 0  THEN
  FCLOSE(m.hFile)
  m.nWritten=GetLastError()
  MESSAGEBOX("Произошла ошибка при печати! Код ошибки
"+ALLTRIM(STR(m.nWritten, 10 , 0 )), 48 ,"Печать файла")
  ClosePrinter(m.hPrinter)
  RETURN .F.
 ENDIF

 DO WHILE .NOT.FEOF(m.hFile)
  m.cString=FREAD(m.hFile, 1024 )
  IF WritePrinter(m.hPrinter,m.cString,LEN(m.cString),@m.nWritten)= 0  THEN
   m.nWritten=GetLastError()
   MESSAGEBOX("Произошла ошибка при печати! Код ошибки "+ALLTRIM(STR(m.nWritten, 10 , 0 )), 48 ,"Печать файла")
   EXIT
  ENDIF
 ENDDO

 FCLOSE(m.hFile)

 EndDocPrinter(m.hPrinter)

 ClosePrinter(m.hPrinter)

ENDPROC