DEFINE CLASS Steck AS Custom
	Stack_Rec =  0 
	DIMENSION Stack[ 1 ]

PROCEDURE Init
	DIMENSION THIS.Stack[ 1 ]
	THIS.Stack_Rec =  0 
ENDPROC

PROCEDURE getnumrecord
	RETURN THIS.Stack_Rec
ENDPROC

PROCEDURE push
	LPARAMETERS lnID
	*-- Помещение на верхушку стэка
	THIS.Stack_Rec = THIS.Stack_Rec +  1 
	DIMENSION THIS.Stack[THIS.Stack_Rec]
	THIS.Stack[THIS.Stack_Rec] = m.lnID
ENDPROC

PROCEDURE pop
	*-- Снимаем с верхушки стэка значение с удалением его из стэка и дикрементом указателя
	LOCAL lRet
	IF THIS.Stack_Rec =  0 
		RETURN  0 
	ENDIF
	m.lRet = THIS.Stack[THIS.Stack_Rec]
	THIS.Stack_Rec = THIS.Stack_Rec -  1 
	RETURN (m.lRet)
ENDPROC
ENDDEFINE

*-- Таблица TreeTabl имеет, как минимум, поля ParentID , KeyID
*--ЗАДАЧА: Найти все KeyID, который подчиняются lnKeyID и записать их
*-- в курсор Result
USE IN SELECT("Result")
CREATE CURSOR Result (KeyID I)
loSteck = CREATEOBJECT("Steck")
loSteck.Push(m.lnKeyID)
*-- Главнй цикл
DO WHILE loSteck.GetNumRecord() >  0 
	*-- Снимает с верхушки стэка
	m.lnKeyID = loSteck.Pop()
	SELECT Temp 
	LOCATE FOR KeyID = m.lnKeyID 
	IF FOUND()
		SELECT Result 
		INSERT INTO Result (KeyID) VALUES (m.lnKeyID)
	ENDIF
	*-- Находим все подразделения для m.lnKeyID 
	SELECT KeyID FROM TreeTabl  INTO CURSOR temp NOFILTER ;
		WHERE ParentID = m.lnKeyID 
	*-- Переписываем их в стэк
	SELECT temp
	GOTO TOP
	SCAN
		loSteck.Push(temp.KeyID)
	ENDSCAN
	USE IN SELECT("temp")
ENDDO
RELEASE loSteck
SELECT Result
GOTO TOP

LOCAL lnLevel

CREATE CURSOR  Result (KeyID I, Lev I)
m.lnLevel  =  0 
INSERT INTO Result (KeyID, Lev) ;
SELECT KeyID, m.lnLevel FROM TreeTabl WHERE KeyID = m.lnKeyID
DO WHILE _TALLY >  0 
	m.lnLevel = m.lnLevel +  1 
	INSERT INTO Result (KeyID, Lev) ;
	SELECT TreeTabl.KeyID, m.lnLevel FROM TreeTabl  ;
		INNER JOIN Result ON TreeTabl.ParentID = Result.KeyID AND Result.Lev = m.lnLevel -  1 

ENDDO