|
Да ладно, че вы все такие важные, даже пошутить нельзя,
понимаешь...
Про Try дак можно хелп почитать, а если не судьба, то на
тебе перевод
(специально сам переводил чтоб грехи замалить перед вами :-)))
TRY...CATCH...FINALLY Command fox.orient-time.ru
Команда TRY...CATCH...FINALLY
См. Также
Commands | Exception Class | UserValue Property | VARTYPE( ) Function | ErrorNo Property | ERROR( ) Function | MESSAGE( ) Function | AERROR( ) Function | SYS(2018) - Error Message Parameter
Структура для обработки ошибок и исключений, которые могут произойти при выполнении блока кода. Подробности о структурной обработке ошибок приведены в документе Structured Error Handling.
TRY
[ tryCommands ]
[ CATCH [ TO VarName ] [ WHEN lExpression ]
[ catchCommands ] ]
[ THROW [ eUserExpression ] ]
[ EXIT ]
[ FINALLY
[ finallyCommands ] ]
ENDTRY
Параметры
TRY
Указывает начало структуры TRY...CATCH...FINALLY.
tryCommands
Расположение инструкций, в которых, на взгляд разработчика, могла бы произойти ошибка. При происхождении ошибки, Visual FoxPro сохраняет ссылку на объект Exception в переменной VarName в предложении TO VarName. Выполнение программы переходит к инструкциям CATCH. Если ошибка не происходит, выполнение программы переходит к блоку FINALLY.
CATCH
Указывает начало блока CATCH, который обрабатывает соответствующую ошибку. Вы можете использовать инструкцию CATCH без параметров. В этом случае инструкция будет оценена как соответствующая Истине, и будет выполнен код, размещенный в этой конструкции.
В случае, если ошибка произойдет в методе объекта, в коде, обрамленном блоком TRY, и выполнение кода вызовет исключение, будет вызвана соответствующая инструкция CATCH. Если метод, вызванный из блока TRY, вызывает ошибку, она будет обработана методом Error этого метода. Это поведение обусловлено тем, что другой метод, который был вызван непосредственно, может и не содержать структуру TRY...CATCH...FINALLY. Следующий пример иллюстрирует это поведение:
x=NEWOBJECT("myClass")
x.myMethod()
DEFINE CLASS myClass AS Session OLEPUBLIC
PROCEDURE myMethod
myMethod3() && обрабатывает ошибку метод Error.
TRY
THIS.myMethod2()
myMethod3() && обрабатывает ошибку конструкция CATCH.
CATCH TO oErr
? "Catch:",oErr.ErrorNo
FINALLY
ENDTRY
ENDPROC
PROCEDURE myMethod2
x=y && Переменной y не существует. Заработает метод Error. ENDPROC
PROCEDURE Error(nError, cMethod, nLine)
? "Error:",nError
ENDPROC
ENDDEFINE
PROCEDURE myMethod3
x = y
ENDPROC
TO VarName
Определяет содержимое дополнительной переменной памяти, в которой сохраняется ссылка на объект Exception, который создается автоматически при происхождении ошибки в блоке TRY. VarName должна быть простой переменной. Она не может быть объектной ссылкой или свойством.
Вы можете явно присвоить переменной VarName любое значение в структуре TRY...CATCH...FINALLY. Значение не изменится, пока не заработает другая инструкция CATCH, которая присвоит VarName значение NULL.
VarName может иметь локальную (local), глобальную (public), или частную (private) область видимости. Это зависит от того, как предварительно была объявлена переменная. Если VarName не была предварительно объявлена, она имеет частную область видимости. Созданный объект Exception имеет ту же самую область, что и переменная VarName. Когда переменная VarName выйдет из области видимости, объект Exception также будет освобожден из памяти.
Когда выполняется предложение CATCH TO VarName, Visual FoxPro передает ссылке VarName указатель на новый объект Exception, независимо от его предыдущей установки, хотя VarName сохраняет его область видимости. Содержание VarName всегда записывается поверх, независимо от того, на что ранее ссылалось предварительное значение переменной.
Если существует предложение WHEN, и оно равно .F., Visual FoxPro освобождает объект Exception из памяти и присваивает переменной VarName значение NULL. Вы можете проверять установки переменной VarName , используя функцию VARTYPE ().
WHEN lExpression
Определяет дополнительное выражение, которое будет обработано в случае, если программа сталкивается с инструкцией CATCH. Для дальнейшей работы, для перехода к catchCommands, выражение должно быть равно Истине (.T)..
Параметр lExpression может содержать ссылку на VarName объекта Exception. Соответственно, с ее помощью, Вы можете запросить данные об ошибке для ее соответствующей обработки.
catchCommands
Здесь помещается код инструкции CATCH.
THROW [ eUserExpression ]
Создает новый объект Exception, который будет передан инструкции CATCH. Параметр eUserExpression определяет выражение любого типа и определяет значение свойства UserValue объекта Exception. Обычно, предложение THROW в блоке CATCH,используется для передачи ошибки или исключения в вышестоящий обработчик ошибки. Вы можете передавать объект любого типа, так как свойство UserValue объекта Exception может хранить только объектную ссылку.
Когда Вы используете предложение THROW с eUserExpression, Visual FoxPro присваивает свойству ErrorNo объекта Exception значение 2071, которое соответствует ошибке «User Thrown Error (Ошибка 2071)». Если Вы опускаете eUserExpression, Visual FoxPro ищет ранее определенный объект Exception, если он существует, иначе, Visual FoxPro передает новый объект Exception со значением свойства ErrorNo равным 2071.
Примечание Вы должны стараться использовать параметр eUserExpression, который будет определять значение свойства UserValue объекта Exception, так как он позволит Вам использовать цепь объектов Exception. Для получения дополнительной информации о последовательных объектах Exception, см. раздел Example.
Если Вы не включаете eUserExpression, и предложение THROW передает объект Exception внешнему блоку TRY...CATCH, внешним блоком TRY...CATCH будет захвачен тот же самый объект Exception. Значения, возвращаемые функциями ERROR(), MESSAGE( ), и AERROR () не всегда могут быть достоверными, при использовании их в структурном обработчике исключений. Вместо них, Вы должны использовать объект Exception.
Вы можете вызвать THROW из любого блока кода в структуре TRY...CATCH...FINALLY. Вы не можете вызвать THROW от окна Command. Вы можете использовать THROW только в том коде, в котором существует обработчик ошибки для захвата исключения.
Предупреждение Вызов команды THROW вне структуры TRY...CATCH...FINALLY и без соответствующего обработчика ошибки заставит среду прервать выполнение вашей программы.
Если при вызове THROW из блока CATCH или FINALLY присутствует внешняя инструкция TRY...CATCH, Visual FoxPro передает переменной VarName, находящейся в предложении CATCH TO, объектную ссылку на объект Exception (который был сгенерирован переброшенным исключением). Если внешней инструкции TRY...CATCH нет, Visual FoxPro передает исключение в обработчик, назначенный ON ERROR или в метод ERROR, если они существуют; иначе, Visual FoxPro вызывает системный обработчик ошибки.
Замечание Передача инструкции THROW во внешнюю структуру TRY...CATCH...FINALLY, в выполняющемся приложении (Runtime applications), должна быть соответствующим образом выполнена (обернута).
Если Вы желаете повторно передать первоначальное (оригинальное) исключение, которое было захвачено предложением CATCH TO VarName, Вы можете вызвать THROW VarName.
Обратите внимание. Передачу первоначального исключения производит другой новый объект Exception, во внешней инструкции CATCH (которая имеет свойство UserValue, содержащее объектную ссылку на первоначальное исключение).
Visual FoxPro игнорирует любые инструкции THROW, появляющиеся в предложении CATCH WHEN eExpression.
Если THROW сталкивается с ошибкой при оценке выражения, Visual FoxPro передает ошибку обычным способом.
EXIT
Используется в TRY, CATCH, FINALLY для немедленного выхода из блока кода.
Если EXIT стоит в блоке TRY или CATCH, управление переходит к инструкции FINALLY, если она существует. Если EXIT стоит в блоке FINALLY или если FINALLY не существует, управление переходит к инструкции, следующей за ENDTRY.
FINALLY
Указывает начало блока FINALLY, который обычно используется для очистки любых ресурсов, задействованных блоком TRY, и который всегда будет выполнен кроме случаев использования команд CANCEL и QUIT.
Для получения дополнительной информации о командах, которые могут быть использованы в структуре TRY...CATCH...FINALLY, см. Structured Error Handling.
finallyCommands
Расположение инструкций кода в блоке FINALLY, которые будет выполнены, после того, как в блоке TRY не будет обнаружено никаких ошибок или будут выполнены инструкции в блоке CATCH.
ENDTRY
Указывает конец структуры TRY...CATCH...FINALLY. Каждая структура TRY...CATCH...FINALLY должна закончиться ключевым словом ENDTRY. Как и в других управляющих инструкциях Visual FoxPro, Вы можете использовать комментарии, предваренные двойным амперсандом (&&) после слова ENDTRY.
Если Вы забудете включить инструкцию ENDTRY в конец структуры TRY...CATCH...FINALLY, Visual FoxPro сгенерирует ошибку при компиляции вашего кода и этот блок не сможет работать в дальнейшем.
Замечания
Исключения, которые происходят в обработчиках исключений TRY...CATCH...FINALLY, устанавливают команду SET CONSOLE в значение ON. Для получения дополнительной информации, см. SET CONSOLE Command.
Вы не можете явно передавать выполнение программы конструкциям CATCH или FINALLY.
Visual FoxPro устанавливает область видимости переменных как в процедурах. То есть переменные, объявленные в блоке TRY, видимы в блоке FINALLY в пределах той же самой структуры TRY...CATCH...FINALLY. Однако, переменные во вложенной структуре, которые объявлены в блоках TRY, CATCH, или FINALLY, имеют локальную область видимости (local).
Вы не должны инициализировать переменные или использовать критически важный код в блоке TRY, потому что этот код может не заработать. Если ошибка происходит в специфической строке программы в блоке TRY, все последующие строки в блоке TRY не будут выполнены.
Любые ошибки, которые происходят в объекте при возникновении события Error, должны быть обработаны объектом, и не должны передаваться в подпрограмму ON ERROR или обработчику TRY...CATCH...FINALLY. Однако, для перехвата ошибки при возникновении события Error, Вы можете использовать структуру TRY...CATCH...FINALLY. Для получения дополнительной информации, см. Error Event.
Использование функции COMRETURNERROR () в блоке CATCH заканчивает всю дальнейшую обработку ошибок, и управление возвращается непосредственно клиенту Component Object Model (COM). Так что блок FINALLY не будет выполнен. Для получения дополнительной информации, см. COMRETURNERROR( ) Function.
Избегайте использовать команду SET TEXTMERGE TO MEMVAR в структуре TRY...CATCH...FINALLY, потому что, если в этой инструкции произойдет ошибка, переменная памяти будет потеряна.
Вы можете использовать SYS (2410), функцию Error Handler в вашем коде TRY...CATCH...FINALLY, чтобы определить направление действий, например, используя структуру DO CASE, в зависимости от типа обработчика, который обрабатывает исключение. Для получения дополнительной информации, см. SYS(2410) - Error Handler.
Вы можете использовать TRY...CATCH...FINALLY для обработки тех ошибок, которые происходят в меню и событиях таймера и в командах типа ON KEY LABEL, если структура должным образом обернута. Следующий пример иллюстрирует, как команда READ EVENTS сохраняет управление программой в пределах структуры TRY...CATCH...FINALLY для захвата события меню. Захват ошибки управляется позицией TRY...CATCH...FINALLY в стеке вызовов.
TRY
DO myMenu.mpr
DO FORM myForm
myForm.AddObject("tm1","mytimer")
READ EVENTS
CATCH TO oException
IF oException.ErrorNo = 1
ENDIF
FINALLY
CLEAR EVENTS
ENDTRY
Для получения дополнительной информации, см. READ EVENTS Command и ON KEY LABEL Command.
Visual FoxPro поддерживает функцию отладки Set Next Statement только в пределах отдельного блока кода. Например, при выполнении кода в блоке TRY, Вы можете использовать Set Next Statement только применительно к другой строке в пределах блока TRY. Вы не можете перейти к другой строке программы в блоке CATCH или FINALLY. Для получения дополнительной информации, см.Debugger Keyboard Shortcuts and Menus.
Visual FoxPro генерирует соответствующие сообщения при следующих условиях:
Несоответствие или внутренняя ошибка структуры TRY...CATCH...FINALLY.
Возникает не обрабатывающееся исключение.
В блоке TRY, CATCH, или FINALLY появляется недопустимая команда. Для получения дополнительной информации, см. Structured Error Handling.
Если пользователь передал ошибку.
Пример
Следующий пример иллюстрирует, как вложить инструкции TRY...CATCH, использовать предложение THROW, и обработать объект Exception.
LOCAL x AS Integer, y AS Integer, result AS Integer
LOCAL oErr AS Exception, oErr1 AS Exception
TRY
x = 1
TRY
USE nothing
GO TOP
y = nothing.col1
CATCH TO oErr
oErr.UserValue = "Сообщение вложенного CATCH: Не могу обработать"
?[: Вложенный Catch! (Не могу обработать передачу объекта oErr наверх)]
?[ Внутренний Объект Исключения: ]
?[ Error: ] + STR(oErr.ErrorNo)
?[ LineNo: ] + STR(oErr.LineNo)
?[ Message: ] + oErr.Message
?[ Procedure: ] + oErr.Procedure
?[ Details: ] + oErr.Details
?[ StackLevel: ] + STR(oErr.StackLevel)
?[ LineContents: ] + oErr.LineContents
?[ UserValue: ] + oErr.UserValue
THROW oErr
FINALLY
?[: Выполняется вложенный FINALLY]
IF USED("nothing")
USE IN nothing
ENDIF
ENDTRY
result = x-y
CATCH TO oErr1
?[: Внешний CATCH! ]
?[ Внешний объект Exception: ]
?[ Error: ] + STR(oErr1.ErrorNo)
?[ LineNo: ] + STR(oErr1.LineNo)
?[ Message: ] + oErr1.Message
?[ Procedure: ] + oErr1.Procedure
?[ Details: ] + oErr1.Details
?[ StackLevel: ] + STR(oErr1.StackLevel)
?[ LineContents: ] + oErr1.LineContents
?[ ->UserValue становится внутренним исключением THROWn во вложенном TRY/CATCH ]
?[ Error: ] + STR(oErr1.UserValue.ErrorNo)
?[ Message: ] + oErr1.UserValue.Message
?[ Procedure: ] + oErr1.UserValue.Procedure
?[ Details: ] + oErr1.UserValue.Details
?[ StackLevel: ] + STR(oErr1.UserValue.StackLevel)
?[ LineContents: ] + oErr1.UserValue.LineContents
?[ UserValue: ] + oErr1.UserValue.UserValue
result = 0
FINALLY
?[: Инструкция FINALLY выполнилась ]
ENDTRY
RETURN result
Следующий пример показывает, как Вы могли бы работать с цепочкой объектов Exception:
TRY
TRY
x=y && Переменная Y не существует и потому вызывает ошибку.
CATCH TO oException2
THROW CREATEOBJECT("myException")
ENDTRY
CATCH TO oException1
ENDTRY
? 2, oException2.ErrorNo, oException2.UserValue
? 1, oException1.ErrorNo, oException1.UserValue.UserValue
DEFINE CLASS myException AS Exception
UserValue = "Мой персональный обработчик ошибки"
PROCEDURE Init
STRTOFILE("Ошибка произошла в: " + TRANSFORM(DATETIME());
+ CHR(13),"c:\errs.log",.T.)
ENDPROC
ENDDEFINE
См. Также
Commands | Exception Class | UserValue Property | VARTYPE( ) Function | ErrorNo Property | ERROR( ) Function | MESSAGE( ) Function | AERROR( ) Function | SYS(2018) - Error Message Parameter
--------------------------------------------------------------------------------
Send feedback on this topic to Microsoft
For technical support and product issues, see the "Microsoft Visual FoxPro Technical Support" topic..
© 1992 - 2003 Microsoft Corporation. All rights reserved.
fox.orient-time.ru
|
