ComboBox.Style= 2  && разумеется!
******* ComboBox.GotFocus *******
THIS.SelStart =  0 
THIS.SelLength = LEN(ALLTRIM(THIS.Value))
THIS.TAG=""
********ComboBox.KeyPress *******
LPARAMETERS nKeyCode, nShiftAltCtrl
newSym=CHR(nKeyCode)
DelKey=(nKeyCode= 7  OR nKeyCode= 127 )
IF (ISALPHA(newSym) OR ISDIGIT(newSym) OR DelKey ) AND nShiftAltCtrl< 2  ;
  AND This.ListCount> 0  AND !EMPTY(THIS.DisplayValue)
  txtLen=LEN(THIS.DisplayValue)
	IF !DelKey
	 This.Tag=ALLT( LEFT(THIS.DisplayValue,THIS.SelStart)+newSym+ ;
	 RIGHT(THIS.DisplayValue,txtLen-THIS.SelStart-THIS.SelLength) )
	ELSE
		IF THIS.SelLength+THIS.SelStart=txtLen
	 		This.Tag=""
		ELSE
			IF nKeyCode= 7 
		 		This.Tag=ALLT( LEFT(THIS.DisplayValue,THIS.SelStart)+ ;
		 			RIGHT(THIS.DisplayValue,txtLen-THIS.SelStart-IIF(THIS.SelLength= 0 , 1 ,THIS.SelLength)) )
			ELSE
		 		This.Tag=ALLT( LEFT(THIS.DisplayValue,IIF(THIS.SelLength= 0 ,THIS.SelStart- 1 ,THIS.SelStart) )+ ;
		 			RIGHT(THIS.DisplayValue,txtLen-THIS.SelStart-THIS.SelLength) )
			ENDIF
		ENDIF
	ENDIF
ENDIF
******** ComboBox.InteractiveChange *******
IF This.ListCount> 0  AND !EMPTY(This.Tag)
	input_Text=This.Tag
	nLenText=LEN(input_Text)
	cntList=This.ListCount
	FOR ij= 1  TO cntList
		IF UPPER(input_Text)==UPPER(LEFT(This.List[ij],nLenText))
			THIS.DisplayValue=allt(This.List[ij])
			THIS.SelStart=nLenText
			THIS.SelLength=LEN(allt(This.List[ij]))-nLenText
			THIS.TAG=""
			EXIT
		ENDIF
	ENDFOR
ENDIF