Если ВЫ не против, то небольшое дополнение:

Довольно часто с этим сталкиваюсь. Для работы с макросом Word необходим файл заголовка данного приложения.

А в принципе: записал макрос, изменил синтаксис (достаточно большое количество различий, но разобраться не очень трудно), вставил в Fox.

Если нужен простенький листинг для примера, то всегда пожалуйста.

Простенький пример:

Есть таблица с 3-мя текстовыми полями (Фамилия-FAM, Имя-NAM, Отчество-OT4 )

Далее листинг:

USE my_table
kl_recc1 = RECCOUNT()

*!* #include Word.h && Все необходимые перененные уже определеы
&& если нужны другие возможности Word
&& необходимо использовать файл заголовка
#Define true .T.
#Define false .F.
#Define wdAlignParagraphCenter 1
#Define wdToggle 9999998
#Define wdAlignParagraphLeft 0
#Define wdOrientLandscape 1
#Define wdPrinterDefaultBin 0
#Define wdSectionNewPage 2
#Define wdAlignVerticalTop 0
#Define wdCellAlignVerticalTop 0
#Define wdStory 6
#Define wdLine 5
#Define wdCharacter 1

***************

old=On('error')
On Error oExcel=.Null.
oExcel=Getobject(,'word.application')
On Error &old
If Isnull(oExcel)
oExcel=Createobject('word.application')
Endi
oExcel.Visible = .t.

With oExcel

.documents.Add('Normal',false)

With .ActiveDocument.PageSetup
.Orientation = wdOrientLandscape
.TopMargin=30
.BottomMargin = 30
.LeftMargin = 115
.RightMargin = 30
Endwith

With .Selection
.Font.Size = 14
.Font.Bold = wdToggle
.TypeText('Какой-то текст')
.ParagraphFormat.Alignment = wdAlignParagraphCenter
.TypeParagraph
.TypeText('Еще что-нибудь в этом роде,')
.ParagraphFormat.Alignment = wdAlignParagraphCenter
.TypeParagraph
.TypeText('ну и еще какая-нибудь информация')
.TypeParagraph
.TypeParagraph
.TypeParagraph
.Font.Size = 12
.Font.Bold = wdToggle
Endwith

.ActiveDocument.Tables.Add (.Selection.Range, kl_recc1,4)
.ActiveDocument.Tables(1).Columns(1).SetWidth(43,0)
.ActiveDocument.Tables(1).Columns(2).SetWidth(73.4,0)
.ActiveDocument.Tables(1).Columns(3).SetWidth(134.65, 0)
.ActiveDocument.Tables(1).Columns(4).SetWidth(190.9, 0)
.ActiveDocument.Tables(1).Select

.Selection.Cells.VerticalAlignment = 1
.Selection.ParagraphFormat.Alignment = wdAlignParagraphLeft
.Selection.MoveUp(wdLine,1)

For i = 1 To 4
.Selection.MoveRight(wdCharacter,1)
.Selection.Font.Bold = wdToggle
.Selection.ParagraphFormat.Alignment = wdAlignParagraphCenter
Endfor

iotable = .ActiveDocument.Tables(1)

Declare data_sub[kl_recc1,4]
data_sub[1,1] = '№ п/п'
data_sub[1,2] = 'Фамилия'
data_sub[1,3] = 'Имя'
data_sub[1,4] = 'Отчество'


GO TOP
cur_recc = 0

For i = 2 To kl_recc1
cur_recc = cur_recc+1
data_sub[i,1] = cur_recc
data_sub[i,2] = ALLTRIM(fam)
data_sub[i,3] = ALLTRIM(nam)
data_sub[i,4] = ALLTRIM(ot4)
Skip
Endfor

With iotable
For lnrow = 1 To Alen(data_sub,1)
For lncolumn = 1 To Alen(data_sub,2)
.cell(lnrow,lncolumn).Range.insertAfter(data_sub[lnrow,lncolumn])
Endfor
Endfor
Endwith

.Selection.EndKey (wdStory)

With .Selection
.Font.Size = 14
.Font.Bold = wdToggle
.TypeParagraph
.TypeParagraph
.TypeText('Директор Фамилия')
.ParagraphFormat.Alignment = wdAlignParagraphLeft
.TypeParagraph
.TypeParagraph
.TypeText('Начальник Фамилия')
.ParagraphFormat.Alignment = wdAlignParagraphLeft
.TypeParagraph
.Font.Size = 12
.Font.Bold = wdToggle
ENDWITH
ENDWITH


Буду очень рад любым замечаниям и коментариям.