Привет всем.
У меня в Outlook Express есть две учетных записи.
Кто нибудь знает как отправить из фокса сообщение через Outlook Express от учетной записи, которая не установлена по умолчанию

Привет Игорь.
Это конечно странно, я в начале тоже думал что это должно сработать (я про Username). Но у меня все время отсылается от той учетной записи, которая установлена по умолчанию(независимо от того, что присвоено Username).

привет Игорь!
я имею в виду то, что называется в русском OE учетной записью

код примерно такой, см. ниже
Если в программе вместо .send(.f.) сделать .send(.t.) , то я вручную смогу выбрать ту учетную запись какую я хочу. Но хотелось чтобы это можно сделать автоматом. (Можно tcProfile сделать пустышкой, все равно запись отправляется от accounta, установленого по умолчанию)


tcProfile="Sender2@mail.com"
txtTo="Receiver@mail.com"
txtSubject="theme"
txtFile="c:\MyAttach.txt"
txtCC=""

DO vfpmail WITH tcProfile, txtTo, txtCC, "", txtSubject, txtNote, txtFile, "", ""

PROCEDURE vfpmail

LPARAMETERS tcProfile, tcTO, tcCC,tcBCC,tcSubject,tcNoteText,tcFiles,tcMessType,tcMailFlag
#DEFINE CRLF CHR(13) + CHR(10)

LOCAL laToList,laCCList,laBCCList,laFileList
LOCAL loDummyForm,loSession,loMessages,llSendFiles,lnForCounter

DIMENSION laToList(1),laCCList(1),laBCCList(1),laFileList(1)



IF TYPE('m.tcTo') # "C" OR EMPTY(m.tcTo)
RETURN .F.
ENDIF
tcCC =IIF(TYPE('m.tcCC')#"C","",m.tcCC)
tcBCC =IIF(TYPE('m.tcBCC')#"C","",m.tcBCC)
tcSubject =IIF(TYPE('m.tcSubject')#"C","",m.tcSubject)
tcNoteText =IIF(TYPE('m.tcNoteText')#"C","",m.tcNoteText)
tcFiles =IIF(TYPE('m.tcFiles')#"C","",m.tcFiles)
tcMessType =IIF(TYPE('m.tcMessType')#"C" OR EMPTY(m.tcMessType),"",m.tcMessType)
tcMailFlag =IIF(TYPE('m.tcMailFlag')#"C","",m.tcMailFlag)

laFileList=""
llSendfiles=TYPE('m.tcFiles')="C" AND !EMPTY(m.tcFiles)

DO CharToArray WITH laToList, (m.tcTo)
DO CharToArray WITH laCCList, (m.tcCC)
DO CharToArray WITH laBCCList, (m.tcBCC)

IF m.llSendFiles
DO CharToArray WITH laFileList, (m.tcFiles)
ENDIF
loDummyForm=createobject("Form")
loDummyForm.Addobject("oleSession","MAPISession")

WITH loDummyForm.oleSession
.DownloadMail = "FORCE DOWNLOAD" $ m.tcMailFlag
.NewSession = !"NO NEW SESSION" $ m.tcMailFlag
.LogonUI = !"NO LOGON" $ tcMailFlag
.UserName = tcProfile
.signon()
IF .sessionid<=0
RETURN .F.
ENDIF
ENDWITH


loDummyForm.Addobject ("oleMessages","MAPIMessages")


WITH loDummyForm.oleMessages
.SessionID=loDummyForm.oleSession.SessionID
.compose()
.MsgType=m.tcMessType
.MsgReceiptRequested="RETURN RECEIPT" $ m.tcMailFlag
.MsgNoteText=IIF(m.llSendFiles,SPACE(ALEN(laFileList,1))+CRLF,"")+m.tcNoteText
.MsgSubject=m.tcSubject


FOR lnForCounter=1 TO ALEN(laToList,1)
IF EMPTY(laToList(lnForCounter))
LOOP
ENDIF
.RecipIndex=.RecipCount
.RecipDisplayName=laToList(m.lnForCounter)
.RecipType=1
.ResolveName()
ENDFOR

FOR lnForCounter=1 TO ALEN(laCCList,1)
IF EMPTY(laCCList(lnForCounter))
LOOP
ENDIF
.RecipIndex=.RecipCount
.RecipDisplayName=laCCList(m.lnForCounter)
.RecipType=2
.ResolveName()
ENDFOR

FOR lnForCounter=1 TO ALEN(laBCCList,1)
IF EMPTY(laBCCList(lnForCounter))
LOOP
ENDIF
.RecipIndex=.RecipCount
.RecipDisplayName=laBCCList(m.lnForCounter)
.RecipType=3
.ResolveName()
ENDFOR


IF llSendFiles
FOR lnForCounter=1 TO ALEN(laFileList,1)
.AttachmentIndex=.AttachmentCount
.AttachmentPosition=m.lnForCounter -1
.AttachmentPathName=laFileList(m.lnForCounter)
DO CASE
CASE "OLE FILES" $ tcMailFlag
.AttachmentType=1
CASE "OLE STATIC FILES" $ tcMailFlag
.AttachmentType=2+1
OTHERWISE
.AttachmentType=0
ENDCASE
ENDFOR
ENDIF


* .send("DIALOG" $ m.tcMailFlag)

.send(.f.)

ENDWITH



loDummyForm.oleSession.Signoff()

loDummyForm.release

***************** CharToArray ****************************
PROCEDURE CharToArray

LPARAMETERS taList,tcList,tcDelimit
LOCAL lnCount,lcList



IF TYPE("m.tcList")#"C" OR EMPTY(m.tcList)
DIMENSION taList(1)
taList[1]=""
RETURN .F.
ENDIF

lcList=ALLTRIM(m.tcList)
tcDelimit=IIF(TYPE("m.tcDelimit")#"C" OR EMPTY(m.tcDelimit),";",LEFT(m.tcDelimit,1))
lcList=m.lcList+IIF(RIGHT(m.lcList,1)<> m.tcDelimit,m.tcDelimit,"")

lnCount=1
DO WHILE AT(m.tcDelimit,m.lcList)#0
DIMENSION taList[m.lnCount]
taList[m.lnCount]=ALLTRIM(LEFT(m.lcList,AT(m.tcDelimit,m.lcList)-1))
lcList=IIF(LEN(m.lcList)#LEN(taList(m.lnCount))+LEN(m.tcDelimit);
,SUBSTR(m.lcList,LEN(taList(m.lnCount))+2),"")
lnCount=lnCount+1
ENDDO

RETURN
************************************************************** DEFINE class MAPISession AS OleControl
OLEClass="MSMAPI.MAPISession"
OLETypeAllowed=-2
ENDDEFINE
************************************************************** DEFINE CLASS MAPIMessages AS OleControl
OLEClass="MSMAPI.MAPIMessages"
OLETypeAllowed=-2
PROCEDURE init
WITH this
.AddressCaption="Visual FoxPro E-Mail"
.AddressEditFieldCount=1
.AddressLabel="Enter Names:"
.AddressModifiable=.T.
.AddressResolveUI=.T.
.FetchUnreadOnly=.T.
ENDWITH
ENDDEFINE
**************************************************************

спасибо за совет Игорь!