Можно сделать очень многое, и очень разными способами.

PUBLIC goFrm
goFrm = CREATEOBJECT("frmTest")
m.goFrm.Show()

DEFINE CLASS frmTest AS Form
ADD OBJECT cmb AS Combobox
ADD OBJECT cmb2 AS Combobox WITH Top = 30
ADD OBJECT txt AS Textbox WITH Left = 120, Width = 50
ADD OBJECT txt2 AS Textbox WITH Left = 120, Top = 30, Width = 50

PROCEDURE Load
CREATE CURSOR table1 (kei I, naim C(20))
FOR ln1 = 1 TO 20
INSERT INTO table1 (kei, naim) VALUES (m.ln1, "Caienu " +
TRANSFORM(m.ln1))
ENDFOR
ENDPROC

PROCEDURE cmb.Init
This.RowSourceType = 0
This.Style = 2
SELECT table1
SCAN ALL
This.AddItem(table1.naim)
This.AddListItem(STR(table1.kei), This.NewItemId, 2)
ENDSCAN
This.BoundColumn = 2
This.Value = 0
This.BoundTo = .T.
This.ListIndex = 1
ENDPROC

PROCEDURE cmb.InteractiveChange
ThisForm.txt.Refresh()
ENDPROC

PROCEDURE cmb2.Init
This.AddProperty("aRows(1, 2)")
SELECT table1.naim, table1.kei + 100 ;
FROM table1 ;
INTO ARRAY This.aRows
This.RowSourceType = 5
This.RowSource = "This.aRows"
This.Style= 2
This.BoundColumn = 2
This.Value = 0
This.BoundTo = .T.
This.ListIndex = 1
ENDPROC

PROCEDURE cmb2.InteractiveChange
ThisForm.txt2.Refresh()
ENDPROC

PROCEDURE Init
USE IN SELECT("table1")
This.txt.ControlSource = "ThisForm.cmb.Value"
This.txt2.ControlSource = "ThisForm.cmb2.Value"
ENDPROC
ENDDEFINE

Только чем тебе не угодил курсор?

Posted via ActualForum NNTP Server 1.0