PUBLIC o AS act_tbrEdit
o=NEWOBJECT( "act_tbrEdit" ) 
o.Show() 

*#INCLUDE "\vfplib\prg\def_inc.h"
#DEFINE VFP8_VERSION  VERSION( 5 )>= 800  
#DEFINE DEBUG_VERSION VERSION( 2 )# 0  

#DEFINE bc_toolBar  toolbar
#DEFINE bc_timer    timer
* #DEFINE cmdGraphics commandbutton 

**************************************************
* -- Class:        act_tbredit (\vfplib\cls\act_cls.vcx) 
* -- BaseClass:    bc_toolbar 
* -- Edit toolbar Extended 

DEFINE CLASS act_tbrEdit AS bc_toolbar

  Caption = "Edit"
  ControlBox = .T.
  DataSession =  1 
  cName = "act_tbredit"
  oactiveform = .NULL.
  Visible = .F. 

  cappobjectname = ("goApp")
  oappobject = .NULL.

  ADD OBJECT tmrrequest AS bc_timer WITH ; && baseobj.vcx 
        Enabled = .F. ;
      , Height =  20  ;
      , Interval =  500  ;
      , Left =  5  ;
      , Top =  3  ;
      , Width =  10 

  ADD OBJECT cmdundo AS cmdgraphics WITH ; && act_cls.vcx 
        Left =  15  ;
      , Picture = "..\bmp\undo.bmp" ;
      , TabIndex =  19  ;
      , ToolTipText = "Undo {Ctrl+Z}" ;
      , Top =  3  ;
      , ZOrderSet =  1 

  ADD OBJECT sep1 AS separator WITH ;
        Height =  0  ;
      , Left =  46  ;
      , Top =  3  ;
      , Width =  0 

  ADD OBJECT cmdcut AS cmdgraphics WITH ; && act_cls.vcx 
        Left =  46  ;
      , Picture = "..\bmp\cut.bmp" ;
      , TabIndex =  19  ;
      , ToolTipText = "Cut {Ctrl+X}" ;
      , Top =  3  ;
      , ZOrderSet =  3 

  ADD OBJECT cmdcopy AS cmdgraphics WITH ; && act_cls.vcx 
        Left =  70  ;
      , Picture = "..\bmp\copy.bmp" ;
      , TabIndex =  20  ;
      , ToolTipText = "Copy {Ctrl+C}" ;
      , Top =  3  ;
      , ZOrderSet =  4 

  ADD OBJECT cmdpaste AS cmdgraphics WITH ; && act_cls.vcx 
        Left =  94  ;
      , Picture = "..\bmp\paste.bmp" ;
      , TabIndex =  21  ;
      , ToolTipText = "Paste {Ctrl+V}" ;
      , Top =  3  ;
      , ZOrderSet =  5 

 PROCEDURE cmdundo.Click
    = SYS( 1500 , "_MED_UNDO", "_MEDIT")
  ENDPROC
  PROCEDURE cmdcut.Click
    = SYS( 1500 , "_MED_CUT", "_MEDIT")
  ENDPROC
  PROCEDURE cmdcopy.Click
    = SYS( 1500 , "_MED_COPY", "_MEDIT")  
  ENDPROC
  PROCEDURE cmdpaste.Click
    = SYS( 1500 , "_MED_PASTE", "_MEDIT")
  ENDPROC
  
  PROCEDURE buttonsstatus
    LOCAL lcOnError, luRet 
    LOCAL lnCmd 

    WITH This
    
       luRet =  0 
       lcOnError = ON( "ERROR" )
       ON ERROR =ERROR()
           lnCmd = _MED_UNDO
           luRet = SKPBAR("_MEDIT", lnCmd )
       ON ERROR &lcOnError                     && Restores ON ERROR 
          
       IF TYPE( "luRet" ) = "L"
         lnCmd = _MED_UNDO
         .cmdUndo.Enabled  = NOT SKPBAR("_MEDIT", lnCmd )
         
         lnCmd = _MED_CUT
         .cmdCut.Enabled   = NOT SKPBAR("_MEDIT", lnCmd )
         lnCmd = _MED_COPY
         .cmdCopy.Enabled  = NOT SKPBAR("_MEDIT", lnCmd )     
         lnCmd = _MED_PASTE
         .cmdPaste.Enabled = NOT SKPBAR("_MEDIT", lnCmd )     
         
       ELSE
          STORE (TYPE( "_SCREEN.ActiveForm.ActiveControl.Value" ) # 'U' ) ;
                  TO  .cmdUndo.Enabled, .cmdCut.Enabled ;
                    , .cmdCopy.Enabled, .cmdPaste.Enabled 
       ENDIF  
    
    ENDWITH
  ENDPROC
  
  PROCEDURE Destroy
    WITH This
         IF TYPE( '.tmrRequest.Name' ) = 'C'
            This.tmrRequest.Enabled = .F.  
         ENDIF 
         IF .Visible      
            .Hide() 
         ENDIF
         IF TYPE( "_SCREEN."+ This.cName +".Name" ) = "C"
            LOCAL lcObj
            lcObj = "_SCREEN." + This.cName 
            &lcObj = .F.
         ENDIF
    ENDWITH
  ENDPROC
  
  PROCEDURE Hide
    IF This.Visible 
       This.SaveWindowPosition()
    ENDIF
    This.Visible = .F. 
    This.Release() 
  ENDPROC
  
  PROCEDURE Init
    WITH This
         SET ASSERTS ON 
         
         IF TYPE( This.cAppObjectName ) = 'O'        && application object 
            This.oAppObject = EVALUATE( This.cAppObjectName )  
         ENDIF 
         
         ASSERT SET( "DATASESSION" ) ==  1  
         IF VFP8_VERSION                             && VFP  8  version or highest 
            LOCAL lObj 
            FOR EACH lObj IN .Controls 
               IF UPPER( lObj.BaseClass ) = "COMMANDBUTTON"
                  lObj.SpecialEffect =  2              && Hot tracking efect 
               ENDIF   
            ENDFOR
         ENDIF 
    
         IF DEBUG_VERSION
            IF TYPE( "_SCREEN."+ This.cName +".Name" ) = "C"
               lcMeth = "_SCREEN."+ This.cName +".Release()"
               &lcMeth
            ENDIF
            _SCREEN.AddProperty( This.cName, This )
         ENDIF
    
         .Dock(  0  )
         .ButtonsStatus()
         ASSERT ! .Visible 
    ENDWITH
  ENDPROC
  
  PROCEDURE Show(  nStyle ) 
    This.Visible = .T. 
  ENDPROC

  
  PROCEDURE MouseMove(  nButton, nShift, nXCoord, nYCoord ) 
    This.ButtonsStatus()
  ENDPROC
  
  PROCEDURE cmdundo.MouseMove(  nButton, nShift, nXCoord, nYCoord ) 
    This.Parent.ButtonsStatus()
  ENDPROC
  PROCEDURE cmdcut.MouseMove(  nButton, nShift, nXCoord, nYCoord ) 
    This.Parent.ButtonsStatus()
  ENDPROC
  PROCEDURE cmdcopy.MouseMove(  nButton, nShift, nXCoord, nYCoord ) 
    This.Parent.ButtonsStatus()
  ENDPROC
  PROCEDURE cmdpaste.MouseMove(  nButton, nShift, nXCoord, nYCoord ) 
    This.Parent.ButtonsStatus()
  ENDPROC

  PROCEDURE restorewindowposition
    = TYPE( "This.oAppObject" ) = 'O' ;
      AND This.oAppObject.RestoreTBarPos( This )
  ENDPROC
  
  PROCEDURE savewindowposition
      = TYPE( "This.oAppObject" ) = 'O' ;
        AND This.oAppObject.SaveTBarPos( This )
  ENDPROC
  
  PROCEDURE tmrrequest.Timer
    IF DEBUG_VERSION ;
       AND ( WEXIST( "Trace" )  OR WEXIST( 'View' )  OR WEXIST( "Command" ) )
             && on Debug with Trace window 
             
      IF TYPE( "nOldInterval" ) # "N"
           This.AddProperty( "nOldInterval", This.Interval )
      ENDIF
      IF This.Interval = This.nOldInterval 
         IF  1000  <  10  * This.nOldInterval 
            IF This.nOldInterval > 2E4          &&  10  min./ 10  
               This.nOldInterval = 2E4
            ENDIF
            This.Interval =  10  * This.nOldInterval
                                                && increasing interval 
         ELSE
            This.Interval =  1000                 &&  1  second
         ENDIF
      ENDIF   
    ELSE
      IF TYPE( "nOldInterval" ) = "N" AND This.Interval # This.nOldInterval 
         This.Interval = This.nOldInterval      && Restores interval
      ENDIF  
    ENDIF
    This.Parent.ButtonsStatus()                 && buttons status
  ENDPROC
  
ENDDEFINE

DEFINE CLASS cmdGraphics AS commandbutton 
   Caption = "" 
   Width  =  24 
   Height =  24  
ENDDEFINE