Public x
x=CreateObject('pgForm')
x.show()

Define Class pgForm as Form

	AutoCenter=.T.
	MinButton=.F.
	MaxButton=.F.
	
	BorderStyle= 0 
	TitleBar= 0 
	DeskTop=.T.
	
	BackColor=Rgb( 250 , 250 , 250 )
	
	Add Object PageFrame as PageFrame with ;
		PageCount= 2 ,;
		TabOrientation= 1 ,;
		TabStyle= 1 

	Procedure init
	With this
		.PageFrame.Width=.Width
		.PageFrame.Height=.Height
	
		DECLARE ReleaseCapture IN "user32"
		DECLARE LONG SendMessage IN "user32";
			LONG HWND, LONG wMsg, LONG wParam, LONG LPARAM
		
		DECLARE integer FindWindow in Win32api ;
			string lpClassName,;
			string lpWindowTitle 

		DECLARE INTEGER SetLayeredWindowAttributes IN win32api;
			INTEGER HWND,  INTEGER crKey, INTEGER bAlpha, INTEGER dwFlags

		*These functions get and set a window's attributes
		DECLARE INTEGER SetWindowLong IN user32.DLL ;
			INTEGER hWnd, INTEGER nIndex, INTEGER dwNewLong

		DECLARE INTEGER GetWindowLong IN user32.DLL ;
			INTEGER hWnd, INTEGER nIndex

		*Constants for SetLayeredWindowAttributs
		#DEFINE LWA_COLORKEY	1
		#DEFINE LWA_ALPHA		2

		*Constants for SetWindowLong and GetWindowLong
		#DEFINE GWL_EXSTYLE		-20
		#DEFINE WS_EX_LAYERED	0x00080000

		LOCAL lnFlags
		*The form's window must be set to Layered, so that it is drawn
		* in a separate layer.
		lnFlags = GetWindowLong(this.HWND, GWL_EXSTYLE)	&&Gets the existing flags from the window
		lnFlags	= BITOR(lnFlags, WS_EX_LAYERED)			&&Appends the Layered flag to the existing ones
		SetWindowLong(this.HWND, GWL_EXSTYLE, lnFlags)		&&Sets the new flags to the window
		SetLayeredWindowAttributes(this.HWND, this.BackColor,  0 ,  1 )
		
	EndWith

	Procedure MouseMove
	LPARAMETERS nButton, nShift, nXCoord, nYCoord
	IF nButton =  1 
		ReleaseCapture()
		SendMessage(THIS.HWND, 0x112, 0xF011, 0x0)
	ENDIF
		
	Procedure PageFrame.INit
	With this
		With .Page1
			.AddObject("Label","Label")
			.Label.FontSize= 16 
			.Label.FontBold=.T.
			.Label.Caption='Page 1'
			.Label.Visible=.T.
			.Label.AutoSize=.T.
		EndWith
		With .Page2
			.AddObject("Label","Label")
			.Label.FontSize= 16 
			.Label.FontBold=.T.
			.Label.Caption='Page 2'
			.Label.Visible=.T.
			.Label.AutoSize=.T.
		EndWith
	EndWith

	Procedure PageFrame.Page1.MouseMove(nButton, nShift, nXCoord, nYCoord)
	thisform.mousemove(nButton, nShift, nXCoord, nYCoord)

	Procedure PageFrame.Page2.MouseMove(nButton, nShift, nXCoord, nYCoord)
	thisform.mousemove(nButton, nShift, nXCoord, nYCoord)
	
EndDefine