* Сохранение некоторых настроек
LOCAL llDispWarning, lnDispLogin
llDispWarning=SQLGetProp( 0 ,'DispWarning')
lnDispLogin=SQLGetProp( 0 ,'DispLogin')

* Установка этих настроек в значения, препятствующие выдаче системных сообщений об ошибке
SQLSetProp( 0 ,'DispWarning',.F.)
SQLSetProp( 0 ,'DispLogin', 3 )

* Формирование строки коннекта
LOCAL lcStringConnect
lcStringConnect='DRIVER=SQL Server'+;
';SERVER=MyServer'+;
';UID=UserName;PWD=PassWord'+;
';DataBase=MyDataBase'+;
';Trusted_Connection=Yes'

* Попытка установить связь
LOCAL lnNewConnection, laError( 1 )
lnNewConnection=sqlstringconnect(m.lcStringConnect)
IF m.lnNewConnection<= 0 
	=AERROR(laError)
	MessageBox('Произошла ошибка № '+LTRIM(STR(laError[ 1 , 5 ]))+chr( 13 )+;
	RTRIM(SubStr(laError[ 1 , 3 ],RAT("]",laError[ 1 , 3 ])+ 1 ))+chr( 13 )+;
	'Обратитесь к администратору сервера или разработчику программы.')
ENDIF

* Восстановление исходных настроек
SQLSetProp( 0 ,'DispWarning',m.llDispWarning)
SQLSetProp( 0 ,'DispLogin',m.lnDispLogin)