Если на таблицу установлен любой режим буферизации, то любые модификации производятся не сразу с таблицей, а записываются в некий "буфер".
Т.е. ты выполняешь все обычные команды по модификации (INSERT-SQL, REPLACE, UPDATE-SQL), но они модифицируют не непосредственно исходную таблицу, а ее буфер.
В режиме строковой буферизации (2 или 3) сброс буфера происходит:
-) По команде TableUpdate()
-) При переходе на другую запись
-) При закрытии таблицы
В режиме табличной буферизации (4 или 5) сброс буфера происходит
-) Только по команде TableUpdate() и никак иначе
Откат внесенных в буфер изменений и очистка буфера происходит по команде TableRevert()
Это значит, что при установленном режиме буферизации ты работаешь с таблицами как обычно. Однако чтобы внесенные изменения попали в исходную таблицу необходимо сбросить буфер этой таблицы.
Проверить факт модификации данных при табличной буферизации можно по команде GetNextModified(), а в пределах одной записи по GetFldState().
При работе в режиме табличной буферизации следует иметь в виду, что сброс буфера осуществляется по одной строке за раз. Это значит, что если в процессе сброса буфера произойдет ошибка, то хотя выполнение команды TableUpdate() будет прервано, но тем не менее все ранее сброшенные данные (сброшенные ДО возникновения ошибки) попадут в итоговую таблицу.
Как следствие, если предполагается сброс более одной записи, то команду TableUpdate() следует окружать транзакцией.
Если в процессе сброса буфера по команде TableUpdate() произошла ошибка, то никакого сообщения об ошибке не появится. Просто команда TableUpdate() вернет .F. Анализ причины ошибки следует выполнить при помощи функции AERROR().
Итого, примерный код кнопки "Сохранить" в режиме оптимистической табличной буферизации (5)
1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
11.
12.
13.
14.
15.
16.
17.
18.
19.
20.
21.
22.
23.
24.
25.
26.
27.
28.
29.
30.
31.
32.
LOCAL llSuccess, lcMessageText, laError( 1 ), llOverWrite, llExit
llOverWrite = .F.
llExit = .F.
DO WHILE llExit = .F.
* Предполагаю что будет только один шаг цикла
llExit = .T.
BEGIN TRANSACTION
llSuccess = TableUpdate(.T.,m.llOverWrite,"MyTable")
IF llSuccess=.T.
END TRANSACTION
ELSE
* Немедленный откат изменений
ROLLBACK
* Анализ причины ошибки ПОСЛЕ отката
=AERROR(laError)
IF laError[ 1 , 1 ]= 1585
lcMessageText = "Пока Вы вносили изменения другим пользователем "+;
"были изменены те же самые данные. Писать поверх внесенных изменений?"
IF MessageBox(m.lcMessageBox,'Конфликт обновления', 4 + 32 + 256 )= 6
* Ответили "Да". Повторяю цикл сохранения, но уже с перезаписью
llExit = .F.
llOverWrite = .T.
CONTINUE
ELSE
* Ответили "Нет". Действия по обновлению данных
ENDIF
ELSE
lcMessageText = "В процессе сохранения произошла ошибка № "+;
LTRIM(STR(laError[ 1 , 1 ]))+chr( 13 )+laError[ 1 , 2 ]
MessageBox(m.lcMessageText,'Ошибка при сохранении', 0 + 48 )
ENDIF
ENDIF
ENDDO
