x=CREATEOBJECT('form1')
READ EVENTS 

DEFINE CLASS form1 AS form
	Top =  0 
	Left =  0 
	Height =  438 
	Width =  607 
	DoCreate = .T.
	Caption =  "Form1" 
	Name =  "Form1" 
	ADD OBJECT grid1 AS grid WITH ;
		Height =  348 , ;
		Left =  24 , ;
		RecordSource =  "table2" , ;
		Top =  12 , ;
		Width =  564 , ;
		Name =  "Grid1" 
	ADD OBJECT command1 AS commandbutton WITH ;
		Top =  384 , ;
		Left =  312 , ;
		Height =  25 , ;
		Width =  85 , ;
		Caption =  "Add" , ;
		Name =  "Command1" 
	ADD OBJECT command2 AS commandbutton WITH ;
		Top =  384 , ;
		Left =  408 , ;
		Height =  25 , ;
		Width =  85 , ;
		Caption =  "Append" , ;
		Name =  "Command2" 
	ADD OBJECT command3 AS commandbutton WITH ;
		Top =  384 , ;
		Left =  504 , ;
		Height =  25 , ;
		Width =  97 , ;
		Caption =  "Browse" , ;
		Name =  "Command3" 
	PROCEDURE Unload
		CLOSE ALL 
		CLEAR EVENTS 
	ENDPROC
	PROCEDURE Load
		USE ? ALIAS table1
		IF !EMPTY(ALIAS())
			=AFIELDS(lArray)
			CREATE CURSOR table2 FROM ARRAY lArray
		ENDIF 
	ENDPROC
	PROCEDURE Init
		IF EMPTY(ALIAS())
			RETURN .F.
		ENDIF 
		this.Visible= .T. 
	ENDPROC
	PROCEDURE command1.Click
		APPEND BLANK IN table2
	ENDPROC
	PROCEDURE command2.Click
		SELECT table1
		APPEND FROM DBF('table2')
		SELECT table2
		LOCAL lcSafety
		lcSafety=SET( "Safety" )
		SET SAFETY OFF 
		ZAP
		SET SAFETY &lcSafety
		thisform.grid1.SetFocus()
	ENDPROC
	PROCEDURE command3.Click
		SELECT table1
		BROWSE
		SELECT table2
	ENDPROC
ENDDEFINE