Если файл открылся в VFP, то это значит, что физическое количество записей перестало соответствовать количеству записей указанному в заголовке таблицы (байты с 4 по 7).
Это очень распространенная ошибка. Обычно возникает при сбое питания в момент добавления записи (счетчик записей увеличился, но физически запись еще не вставилась)
В принципе, это можно исправить
1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
11.
12.
13.
14.
15.
16.
17.
18.
19.
20.
21.
22.
23.
24.
25.
26.
27.
28.
29.
30.
31.
32.
33.
34.
35.
36.
37.
38.
39.
40.
41.
42.
43.
44.
45.
46.
47.
48.
49.
50.
51.
52.
53.
54.
55.
56.
57.
58.
59.
60.
61.
62.
63.
64.
* В качестве параметра передается дескриптор открытого файла
* по FOPEN( "MyTable.DBF" , 2 )
LPARAMETERS tnFD
* Определяю количество записей записанное в заголовке файла
* байты с 4 по 7
LOCAL lnReccount
=FSEEK(m.tnFD, 4 )
lnReccount=ASC(FREAD(m.tnFD, 1 ))+;
256 *ASC(FREAD(m.tnFD, 1 ))+;
256 * 256 *ASC(FREAD(m.tnFD, 1 ))+;
256 * 256 * 256 *ASC(FREAD(m.tnFD, 1 ))
* Определяю позицию, с которой начинается собственно данные (первая запись)
* байты с 8 по 9
LOCAL lnDataStart
lnDataStart=ASC(FREAD(m.tnFD, 1 ))+ 256 *ASC(FREAD(m.tnFD, 1 ))
* Определяю количество символов в одной записи, включая метку на удаление
* байты с 10 по 11
LOCAL lnRecLength
lnRecLength=ASC(FREAD(m.tnFD, 1 ))+ 256 *ASC(FREAD(m.tnFD, 1 ))
* Определяю общий размер файла
LOCAL lnFileSize
=FSEEK(m.tnFD, 0 , 0 )
lnFileSize=FSEEK(m.tnFD, 0 , 2 )
* Определяю значение самого последнего байта файла
LOCAL lnEndByte
=FSEEK(m.tnFD,- 1 , 1 )
lnEndByte=ASC(FREAD(m.tnFD, 1 ))
* И реальное количество записей в файле
LOCAL lnFaktCount
DO CASE
CASE m.lnFileSize=m.lnDataStart
* Т.е. в таблице вообще нет информации
lnFaktCount= 0
CASE m.lnEndByte= 26
* Если последний байт файла имеет ASCII код 26 (0x1A),
* то общее число информационных байтов надо уменьшить на 1
lnFaktCount=(m.lnFileSize-m.lnDataStart- 1 )/m.lnRecLength
OTHERWISE
lnFaktCount=(m.lnFileSize-m.lnDataStart)/m.lnRecLength
ENDCASE
LOCAL lnResult
* Анализ полученных результатов
DO CASE
CASE INT(m.lnFaktCount)<>m.lnFaktCount
lnResult=- 1
* Есть дробная часть. Т.е. выделить целое количество записей невозможно
* повреждения более существенные, чем разница в количестве записей
* лучше ничего не трогать
CASE m.lnFaktCount<>m.lnReccount
* Записанное и фактическое количество записей отличаются
* корректирую записанное количество записей
=FSEEK(m.tnFD, 4 , 0 )
FOR lnI= 1 TO 4
=FWRITE(m.tnFD,CHR(MOD(INT(m.lnFaktCount/ 256 **(m.lnI- 1 )), 256 )))
ENDFOR
lnResult= 1
OTHERWISE
* Ошибки в определении количества записей не обнаружено
lnResult= 0
ENDCASE
RETURN m.lnResult
Это код для VFP, но он корректен и для FPD, надо только заменить все LOCAL на PRIVATE и проследить, чтобы имена переменных были не более 10 символов.
Но можешь ремонтировать и через открытие таких таблиц в VFP с последующим копированием
COPY TO NewTab TYPE FOX2X AS 866
