LOCAL lcFrom as String, lcTo as String, lcMask as String
lcMask=INPUTBOX('Введите маску для файлов','Маска файлов','*.*')
IF EMPTY(lcMask)
	RETURN
ENDIF  
lcFrom=GETDIR('C:\','Исходное местоположение','Выбор папки', 1 )
IF EMPTY(lcFrom)
	RETURN
ENDIF  
lcTo=GETDIR(lcFrom,'Новое местоположение','Выбор папки', 65 )
IF EMPTY(lcFrom)
	RETURN
ENDIF  
IF lcFrom==lcTo
	=MESSAGEBOX('Новое местоположение совпадает с исходным.', 48 )
	RETURN 
ENDIF 
IF !CopyFiles(lcFrom, lcTo, lcMask)
	=MESSAGEBOX('Копирование файлов было отменено или произошла ошибка.', 48 )
ENDIF 
***********************************************
FUNCTION CopyFiles
LPARAMETERS tcFrom as String,;
			tcTo as String,;
			tcMask as String

#define FO_COPY           0x0002
#define FOF_NOCONFIRMATION         0x0010  && Don't prompt the user.
#define FOF_FILESONLY              0x0080  && on *.*, do only files
#define FOF_NOERRORUI              0x0400  && don't put up error UI
#define FOF_NOCOPYSECURITYATTRIBS  0x0800  && dont copy NT file Security Attributes

LOCAL lcSHFO as String 
LOCAL lnHeap as Integer 
LOCAL lcpFrom as String, lcpTo as String 
LOCAL lnpFrom as Integer, lnpTo as Integer 
LOCAL lnFlags as Integer 
LOCAL i as Integer
LOCAL llReturn

DECLARE INTEGER SHFileOperation IN shell32.dll string @
DECLARE INTEGER GetProcessHeap IN WIN32API 
DECLARE INTEGER HeapAlloc IN WIN32API;
INTEGER hHeap, INTEGER dwFlags, INTEGER dwBytes
DECLARE INTEGER HeapFree IN WIN32API;
INTEGER hHeap, INTEGER dwFlags, INTEGER lpMem
DECLARE RtlMoveMemory IN WIN32API;
INTEGER nDestBuffer, STRING @pVoidSource, INTEGER nLength

lnHeap=GetProcessHeap()
lcSHFO=int2bin(_screen.hwnd)
lcSHFO=lcSHFO+int2bin(FO_COPY)
lcpFrom=ADDBS(tcFrom)+tcMask+CHR( 0 )+CHR( 0 )
lcpTo=+ALLTRIM(tcTo)+CHR( 0 )+CHR( 0 )
lnpFrom=HeapAlloc(lnHeap, 0 ,LEN(lcpFrom))
lnpTo=HeapAlloc(lnHeap, 0 ,LEN(lcpTo))
=RtlMoveMemory(lnpFrom,@lcpFrom,len(lcpFrom))
=RtlMoveMemory(lnpTo,@lcpTo,len(lcpTo))
lcSHFO=lcSHFO+int2bin(lnpFrom)+int2bin(lnpTo)
lnFlags=FOF_NOCONFIRMATION+FOF_FILESONLY+FOF_NOCOPYSECURITYATTRIBS
lcSHFO=lcSHFO+int2bin(lnFlags)+REPLICATE(CHR( 0 ), 12 )
llReturn=IIF(SHFileOperation(@lcSHFO)= 0 ,.T.,.F.)
= HeapFree(lnHeap, 0 ,lnpFrom)
= HeapFree(lnHeap, 0 ,lnpTo)
CLEAR DLLS 
RETURN llReturn
ENDFUNC 
***********************************************
FUNCTION int2bin
LPARAMETERS tnValue as Integer 
LOCAL lcReturn as String, lnValue as String, i as Integer  
lcReturn=''
FOR i= 3  TO  0  step - 1 
	lnValue=INT(tnValue/ 256 ^i)
	lcReturn=chr(lnValue)+lcReturn
	tnValue=tnValue-lnValue* 256 ^i
ENDFOR 
RETURN lcReturn
ENDFUNC