Hi Ilhom_uz!

http://www.geocities.com/rremus/multithreaded_vfp.htm

Это по потокам. А процессы разные он и так может создавать - по !/RUN,
ShellExecute, CreateProcess и т.п. И общаться с ними через NamedPipes
например... Хотя многоПРОЦЕССНЫХ приложения я не встречал, вот
многопоточных - тех хватает.

Posted via ActualForum NNTP Server 1.1

Hi Ilhom_uz!

Не ломает описывать - почитай MSDN там много всего есть интересного и полезного.
А вот пример (код т.е.) наоборот имеется:

=========Beginning of the Pipe Server.prg==============
#DEFINE STANDARD_RIGHTS_REQUIRED 0xF0000
#DEFINE PIPE_ACCESS_OUTBOUND 0x00000002
#DEFINE FILE_FLAG_OVERLAPPED 0x40000000
#DEFINE PIPE_TYPE_BYTE 0x00000000
#DEFINE ERROR_PIPE_CONNECTED 535

DECLARE INTEGER GetLastError IN kernel32

DECLARE INTEGER CreateNamedPipe IN kernel32;
STRING lpName, INTEGER dwOpenMode, INTEGER dwPipeMode,;
INTEGER nMaxInstances, INTEGER nOutBufferSize, INTEGER nInBufferSize,;
INTEGER nDefaultTimeOut, INTEGER

DECLARE INTEGER ConnectNamedPipe IN kernel32;
INTEGER hNamedPipe, INTEGER lpOverlapped

DECLARE INTEGER CloseHandle IN kernel32 INTEGER hObject

DECLARE INTEGER WriteFile IN kernel32 INTEGER hFile,;
STRING lpBuffer, INTEGER nBt2Write, INTEGER @ lpBtWritten, INTEGER lpOverlapped
pipehnd = CreateNamedPipe("\\.\pipe\PPing", PIPE_ACCESS_OUTBOUND, PIPE_TYPE_BYTE, 1, 0, 0, 0, 0)
If pipehnd = 0
= CloseHandle(pipehnd)
MESSAGEBOX("Error1")
CLEAR DLLS
RETURN
ENDIF
m.res = ConnectNamedPipe(pipehnd, 0)
If m.res <> 0 .Or. (res = 0 And GetLastError() = ERROR_PIPE_CONNECTED)
m.buffer = ALLTRIM(STR(100)) && на будущее
m.lenbuf = LEN(m.buffer)
m.written = 0
m.res = WriteFile(pipehnd, m.buffer, m.lenbuf, @m.written, 0)
? m.written
Else
= CloseHandle(pipehnd)
MESSAGEBOX("Error2")
CLEAR DLLS
RETURN
ENDIF
MESSAGEBOX("Ok!")
= CloseHandle(pipehnd)
CLEAR DLLS
=========The end of the Pipe Server.prg================

=========Beginning of the Pipe Client.prg==============
DECLARE INTEGER CreateFile IN WIN32API ;
STRING, INTEGER, INTEGER, INTEGER, ;
INTEGER, INTEGER, INTEGER

DECLARE INTEGER ReadFile IN WIN32API ;
INTEGER, STRING @, INTEGER, INTEGER @, INTEGER

DECLARE INTEGER CloseHandle IN WIN32API INTEGER

#DEFINE GENERIC_READ 0x80000000
#DEFINE OPEN_EXISTING 3

lnHandle = CreateFile("\\.\pipe\PPing", GENERIC_READ, 0, 0, OPEN_EXISTING, 0, 0)
IF m.lnhandle = 0
MESSAGEBOX("Can't open pipe")
RETURN .F.
ENDIF
lcBuf = SPACE(255)
lnRead = 0
IF ReadFile(m.lnHandle, @m.lcBuf, LEN(m.lcBuf), @m.lnRead, 0) = 0
MESSAGEBOX("No data in pipe")
CloseHandle(m.lnHandle)
RETURN .F.
ENDIF
MESSAGEBOX(TRANSFORM(m.lnRead) + " bytes read from the pipe" + CHR(13) + ;
"Read data follows:" + LEFT(m.lcBuf, m.lnRead))

CloseHandle(m.lnHandle)
RETURN .T.
=========The end of the Pipe Client.prg================

Posted via ActualForum NNTP Server 1.1

Hi Ilhom_uz!

> Один вопрос: После перезагрузки компа, pipe исчезнет?

Pipe это временный ресурс - он не только при перезагрузке исчезнет, он заметно раньше исчезнет :)

> А в фоксе это(открыть поток) можно проделать?

См. первое сообщение и инфу по линку.

Posted via ActualForum NNTP Server 1.1