PRIVATE ConnectString

ConnectString = ;
	"driver={SQL Server};" ;
	+ "server=mydbserver;" ;
	+ "uid=mylogin;" ;
	+ "pwd=mypassword;" ;
	+ "database=mydb"

TRY
	PRIVATE hConn, s, aErrors, i
	hConn = SQLSTRINGCONNECT(ConnectString)
	IF hConn <=  0 
		DIMENSION aErrors[ 1 ]
		s = "Ошибка подключения:" + CHR( 13 ) + CHR( 13 ) ;
			+ ConnectString + CHR( 13 )
		FOR i =  1  TO AERROR(aErrors)
			s = s + CHR( 13 ) + "SQL State: " + NVL(aErrors[i,  4 ], "Not available") ;
				+ IIF(ISNULL(aErrors[i,  5 ]), "", CHR( 13 ) + "#" + LTRIM(STR(aErrors[i,  5 ])) + " " + TRIM(aErrors[i,  3 ])) ;
				+ CHR( 13 )
		ENDFOR
		MESSAGEBOX(s,  16 , "Ошибка подключения: " + STR(NVL(aErrors[ 1 , 5 ],  0 ))
	ELSE
		PRIVATE cur, x, y, res
		cur = SYS( 2015 )
		x =  123 
		y = "asd"

		SQLString = ;
			"select * " ;
				+ "from " ;
					+ "mytable " ;
				+ "where " ;
					+ "mytable.mynumericfield = ?x " ;
					+ "and mytable.mycharacterfield like ?y "

		res = SQLEXEC(hConn, SQLString, cur)
		DO CASE
			CASE res <  0 
				DIMENSION aErrors[ 1 ]
				s = "Ошибка выполнения SQL-запроса:" + CHR( 13 ) + CHR( 13 ) ;
					+ SQLString + CHR( 13 )
				FOR i =  1  TO AERROR(aErrors)
					s = s + CHR( 13 ) + "SQL State: " + NVL(aErrors[i,  4 ], "Not available") ;
						+ IIF(ISNULL(aErrors[i,  5 ]), "", CHR( 13 ) + "#" + LTRIM(STR(aErrors[i,  5 ])) + " " + TRIM(aErrors[i,  3 ])) ;
						+ CHR( 13 )
				ENDFOR
				MESSAGEBOX(s,  16 , "Ошибка исполнения: " + STR(NVL(aErrors[ 1 , 5 ],  0 ))
			CASE res =  0 
				MESSAGEBOX("Запрос все еще асинхронно выполняется...")
			OTHERWISE
				MESSAGEBOX("Запрос выполнился успешно")
				IF USED(cur)
					SELECT (cur)
					BROWSE NORMAL IN WINDOW (thisform.Name) TITLE (SQLString)
					USE IN (cur)
				ELSE
					MESSAGEBOX("Сервер не вернул ни одного набора данных")
				ENDIF
		ENDCASE
	ENDIF
CATCH
	MESSAGEBOX(NVL(MESSAGE(), "Неопознанная летающая ошибка"),  16 , "Ошибка")
FINALLY
	TRY
		SQLDISCONNECT(hConn)
	CATCH
	ENDTRY
ENDTRY