local loReportCad 
loReportCad  =  createobject('_cursoradapter',	;
		              '#tt',	;	&& таблица на сервере
			 'Id',	;	&& ключь-линк в таблице
			 'TT,NOTE', 	;	&& обновляемые поля в таблице
			 .f.,		;	&& схема - преобразов-е типов
			 '1=2' )				&& условие в запросе

DEFINE CLASS _cursoradapter AS cursoradapter


	Height =  22 
	Width =  23 
	BufferModeOverride =  5 
	DataSourceType = "ODBC"
	FetchSize = - 1 
	WhereType =  1 
	MapVarchar = .T.
	UseTransactions = .F.
	nconnection = .F.
	Name = "_cursoradapter"


	PROCEDURE setproperties
		lparameters tcSql_updateTableName, tcCADkeyFieldList, tcCADupdatableFieldList, tcCADcursorSchema, tcWhere
		with this
			if !.CheckConnection()
				return .f.
			endif
			.DataSource         = .nConnection
			text to .SelectCmd noshow textmerge pretext  15 
				select <<tcCADkeyFieldList>>, <<tcCADupdatableFieldList>>
					from <<tcSql_updateTableName>> 
					<<iif(!empty(tcWhere), 'WHERE '+tcWhere, '')>>
			endtext
			.Tables             = tcSql_updateTableName
			.keyFieldList		= tcCADkeyFieldList
			.UpdatableFieldList = tcCADupdatableFieldList && строка в виде 'Fld1, Fld2'
			if !empty(tcCADcursorSchema)
				.cursorsChema 	= tcCADcursorSchema   && строка в виде 'Fld c(16)'
			endif
			local laFieldsArr( 1 ), lnField, lcField 
			* формируем строку
			.updateNameList 	=  tcCADkeyFieldList + ' ' + .Tables+'.'+tcCADkeyFieldList
			for lnField= 1  to alines(laFieldsArr,.UpdatableFieldList,',')
				lcField = alltrim(laFieldsArr(lnField))
				if !empty(lcField)
					.updateNameList = .updateNameList +iif(!empty(.updateNameList),', ','') + lcField + ' ' + .Tables+'.'+lcField
				endif
			endfor
			.UseCursorSchema = !empty(.cursorschema)
		endwith
	ENDPROC


	HIDDEN PROCEDURE checkconnection
		* сейчас создаем доп.коннект
		* но затем нужно забуферить коннект
		* на постоянный
		with this
			if empty(.nConnection)
				.nConnection = sqlstringconnect(бубен.sql_sqlgetprop('ConnectString'))
				if .nConnection> 0 
					sqlsetprop(.nConnection,"Asynchronous",.f.)
					sqlsetprop(.nConnection,"BatchMode",.t.)
				else 
					return .f.
				endif 
			endif
		endwith
		return .t.
	ENDPROC


	PROCEDURE savecursor
		with this
			if !empty(getNextModified( 0 ,.Alias))
				msg('Ждите ... Происходит обновление данных на сервере ...')
				* в курсоре что-то потрогали
				sqlsetprop(.nConnection, 'Transactions',  2 )
				if !tableupdate(.t.,.t.,.Alias)
					* ошибка, не смогли сохранить изменения на сервер
					sqlrollback(.nConnection)
					msg()
					local laErrors( 1 ), lcErrMessage
					=aerror(laErrors)
					text to lcErrMessage noshow pretext  7 
						КАД. Ошибка сохранения изменений в таблице <<.Tables>>.
						<<iif(alen(laErrors)>= 2 ,laErrors[ 2 ],'Ошибка не идентифицирована.')>>
					endtext
					messagebox(lcErrMessage, 16 ,'Класс КА')
					return .f.
				else &&!tableupdate(.t.,.t.,.Alias)
					* все хорошо, сохранились
					sqlcommit(.nConnection)
				endif
			else
				* в курсоре ничего не трогали - нечего обновлять на сервере
				return .f.
			endif 
		endwith 
		msg('Данные на сервере обновлены успешно.')
		return .t.
	ENDPROC


	PROCEDURE Destroy
		with this
			if !empty(.Alias)
				use in select(.Alias)
			endif
			if !empty(.nConnection)
				* убиваем соединение, созданное для КАДа
				sqldisconnect(.nConnection)
			endif 
		endwith
	ENDPROC


	PROCEDURE Init
		lparameters tcSql_updateTableName, tcCADkeyFieldList, tcCADupdatableFieldList, tcCADcursorSchema, tcWhere
		with this
			.Alias = 'Cad'+Sys( 2015 )
			if  !empty(tcSql_updateTableName) and !empty(tcCADkeyFieldList) and !empty(tcCADupdatableFieldList)
				if .SetProperties(tcSql_updateTableName, tcCADkeyFieldList, tcCADupdatableFieldList, tcCADcursorSchema, tcWhere)
					if !.CursorFill(!empty(.CursorSchema))
						messagebox('Ошибка загрузки КА!', 16 ,'Класс КА')
						return .f.
					endif
				endif
			endif
		endwith
		return .t.
	ENDPROC


ENDDEFINE

if vartype(loReportCad)='O'
     if !loReportCad.SaveCursor()
        return - 1 
     endif
endif