DEFINE CLASS state AS control


	Width =  76 
	Height =  21 
	BackStyle =  0 
	BorderWidth =  0 
	Style =  3 
	nwidth =  0 
	nheight =  0 
	nrow =  0 
	ncol =  0 
	Name = "state"
	ogrid = .F.
	nrowheightold = .F.
	calias = .F.
	cpopup = .F.
	llockbar1 = .F.
	llockbar2 = .F.
	llockbar3 = .F.
	llockbar4 = .F.


	ADD OBJECT lbl AS label WITH ;
		BackStyle =  0 , ;
		Caption = "", ;
		Height =  17 , ;
		Left =  5 , ;
		Top =  3 , ;
		Width =  66 , ;
		Name = "lbl"


	ADD OBJECT lbl_lock AS label WITH ;
		FontName = "Courier New", ;
		FontSize =  7 , ;
		BackStyle =  0 , ;
		Caption = "заблокирован", ;
		Height =  13 , ;
		Left =  1 , ;
		Top = - 2 , ;
		Visible = .F., ;
		Width =  74 , ;
		Name = "Lbl_lock"


	ADD OBJECT cmd AS commandbutton WITH ;
		Top =  1 , ;
		Left =  59 , ;
		Height =  20 , ;
		Width =  18 , ;
		FontName = "Webdings", ;
		Caption = "6", ;
		SpecialEffect =  1 , ;
		Themes = .F., ;
		Name = "cmd"


	PROCEDURE nheight_assign
		LPARAMETERS tnNewVal
		store tnNewVal to this.nHeight, this.Height
		return .t.
	ENDPROC


	PROCEDURE nwidth_assign
		LPARAMETERS tnNewVal
		store tnNewVal to this.nWidth, this.Width
		return .t.
	ENDPROC


	PROCEDURE eventgridmousedown
		lparameters nButton, nShift, nXCoord, nYCoord
		if nButton= 1  and vartype(this.oGrid)="O"
			this.nRowHeightOld=this.oGrid.RowHeight
		endif
	ENDPROC


	PROCEDURE eventgridmouseup
		LPARAMETERS nButton, nShift, nXCoord, nYCoord
		with this 
			IF vartype(this.oGrid)="O" and .nRowHeightOld<>.oGrid.RowHeight
				.resize()
			endif
		endwith
	ENDPROC


	PROCEDURE definepopup
		local lcPopup
		with this
			if empty(this.cPopup)
				store "PopObjState"+sys( 2015 ) to lcPopup, .cPopup
			else
				store .cPopup to lcPopup
			endif
			DEFINE popup (lcPopup) SHORTCUT RELATIVE FROM MROW(),MCOL()
			Define BAR  1  OF (lcPopup) prompt iif(.lLockBar1,"\", "") + "1"  
			Define BAR  2  OF (lcPopup) prompt iif(.lLockBar2,"\","\") + "2"
			Define BAR  3  OF (lcPopup) prompt iif(.lLockBar3,"\", "\") + "3"  
			Define BAR  4  OF (lcPopup) prompt iif(.lLockBar3,"\", "") + "4"  
			Define BAR  5  OF (lcPopup) prompt iif(.lLockBar4,"\", "") + "5" 
			on selection popup (lcPopup) deactivate popup (lcPopup)
		endwith
	ENDPROC


	PROCEDURE activatepopup
		mouse at objtoclient(this, 1 )+objtoclient(this, 4 ),objtoclient(this, 2 )+objtoclient(this, 3 ) pixels window (thisform.name)
		doevents
		local lcPopup, lnActiveBar
		lcPopup = this.cPopup
		this.nRow = mrow("SCREEN")-wlrow()- 2 
		this.nCol = mcol("SCREEN")-wlcol()- 1 
		select (thisform.alias)
		if lower(alltrim(AN_SNAME))== lower(alltrim(thisform.cAnalitConfirmed))
			lnActiveBar =  4 
		else
			lnActiveBar = icase(obr= 0 ,  1 , obr= 1 ,  2 , obr= 2 ,  3 ,  1 ) 
		endif
		activate popup (lcPopup) at this.nRow, this.nCol bar lnActiveBar
		return iif(lastkey()= 13 ,bar(), 0 )
	ENDPROC


	PROCEDURE Init
		With This
			If Vartype(.Parent)='O'
				store .parent.parent.backcolor to .cmd.backcolor
				local loColumn
				loColumn = This.Parent
				.oGrid = loColumn.Parent
				.cAlias = .oGrid.recordSource
				.definePopup()
				bindevent(loColumn,'Resize',this,'Resize', 1 )
				bindevent(.oGrid,'MouseDown',this,'EventGridMouseDown', 1 )
				bindevent(.oGrid,'MouseUp',this,'EventGridMouseUp', 1 )
				.Resize(loColumn)
			Endif
		Endwith
	ENDPROC


	PROCEDURE Resize
		Lparameters toColumn
		With This
			If Vartype(toColumn)<>'O'
				store .Parent to toColumn
			endif 
			If .nWidth<>toColumn.Width or .nHeight<>toColumn.Parent.RowHeight
				.nWidth  		= toColumn.Width
				store toColumn.Parent.RowHeight to .nRowHeightOld, .nHeight
				.cmd.Height 	= .nHeight- 2 
				.cmd.Left   	= .nWidth - .cmd.Width
				.lbl.Width 		= .nWidth
				.lbl.Top   		= (.nHeight - .lbl.Height)/ 2 
				toColumn.refresh()
			Endif
		Endwith
	ENDPROC


	PROCEDURE Destroy
		with this
			.oGrid = .f.
			if !empty(.cPopup)
				release popups (.cPopup)
			endif
		endwith
	ENDPROC


	PROCEDURE DblClick
		with this.cmd
			if .enabled
				.click()
			endif
		endwith
	ENDPROC


	PROCEDURE lbl.DblClick
		this.Parent.DblClick()
	ENDPROC


	PROCEDURE cmd.Click
	ENDPROC


ENDDEFINE