#DEFINE cnMAXInteger	0x7FFFFFFF
CLEAR
CLOSE TABLES ALL
CREATE CURSOR CurTestData (Kod1 I, Kod2 I, Kod3 I, Name1 C( 10 ), Name2 C( 10 ), Name3 C( 10 ))
lnSeconds = SECONDS()
FOR m.i =  1  TO  10 
	FOR m.j =  1  TO  3000 
		INSERT INTO CurTestData VALUES (m.i, m.j, FLOOR(RAND() *  100 ), SYS( 2015 ), SYS( 2015 ), SYS( 2015 ))
	NEXT m.j
NEXT m.i
?"Создали набор данных: ", SECONDS() - lnSeconds

*-* (IGEL) Добавим итогов, добавление строк в Excel дольше работает.
lnSeconds = SECONDS()
SELECT ;
	Kod1, Kod2, Kod3, Name1, Name2, Name3 ;
	FROM CurTestData ;
UNION ALL SELECT ;
	Kod1, MAX(cnMAXInteger), SUM(Kod3), MAX(Name1), MAX(Name2), MAX(Name3) ;
	FROM CurTestData ;
	GROUP BY  1  ;
	ORDER BY  1 ,  2  ;
	INTO CURSOR CurData NOFILTER READWRITE
?"Добавили итогов к набору: ", SECONDS() - lnSeconds

loExcel = CREATEOBJECT("Excel.Application")
loExcel.WorkBooks.Add()
loSheet = loExcel.WorkSheets( 1 )

lnOffSetX =  1 
lnOffSetY =  3 
*-* (IGEL) Я обычно сбрасываю вот таким вот странным способом. Мне так больше нравится. На скорость влияет незначительно.
lnSeconds = SECONDS()
StoreCursor(loSheet, "CurData", "Kod1, Kod2, Kod3, Name1, Name2, Name3", lnOffSetX, lnOffSetY)
?"Выплюнули данные в Excel: ", SECONDS() - lnSeconds
*-* (IGEL) Итоги просто форматируем. В случае необходимости, можно отключить автопересчет перед этой операцией.
lnSeconds = SECONDS()
lnStartOffSet = lnOffSetY 
SELECT CurData
SCAN FOR Kod2 = cnMAXInteger
	lnY = lnOffSetY + RECNO() -  1 
	WITH loSheet.Cells[lnY, lnOffSetX]
		.EntireRow.Font.Bold = .T.
		.Cells[ 1 ,  2 ].Value = "ИТОГО"
		lcFormula = TEXTMERGE("=SUBTOTAL(9, R[-1]C:R<<lnStartOffSet>>C)")
		.Cells[ 1 ,  3 ].FormulaR1C1 = lcFormula
		lnStartOffSet = lnY
	ENDWITH
ENDSCAN

WITH loSheet.Cells[lnOffSetY + RECCOUNT("CurData"), lnOffSetX]
	.EntireRow.Font.Bold = .T.
	.Cells[ 1 ,  2 ].Value = "ИТОГО ВСЕГО"
	lcFormula = TEXTMERGE("=SUBTOTAL(9, R[-1]C:R<<lnOffSetY>>C)")
	.Cells[ 1 ,  3 ].FormulaR1C1 = lcFormula
	lnStartOffSet = lnY
ENDWITH
?"Все подытожили: ", SECONDS() - lnSeconds
*-* (IGEL) Готово.
loExcel.Visible = .T.

PROCEDURE StoreCursor
	LPARAMETERS toSheet, tcCursor, tcFieldList, tnOffSetX, tnOffSetY
	LOCAL luRetVal, lcField, lnCol
	PRIVATE laStoreVal( 1 )
	luRetVal = .T.
	
	FOR lnCol =  1  TO GETWORDCOUNT(tcFieldList, ",")
		lcField = RTRIM(GETWORDNUM(tcFieldList, lnCol, ","))
		SELECT &lcField FROM (tcCursor) INTO ARRAY laStoreVal && Здесь надо усложнить маленько выборку...
		lnRows = _TALLY
		IF !EMPTY(lnRows)
			toSheet.Cells[tnOffSetY, tnOffSetX + lnCol -  1 ].Resize[lnRows,  1 ] = RetArray("laStoreVal")
		ENDIF
	NEXT lnCntr
		
	RETURN luRetVal
ENDPROC

FUNCTION RetArray
	PARAMETERS tcArrayName
	RETURN @&tcArrayName
ENDFUNC