DECLARE INTEGER CreateProcess IN Win32API ;
		INTEGER lpApplicationName, ;
		STRING lpCommandLine, ;
        INTEGER lpProcessAttributes, ;
        INTEGER lpThreadAttributes, ;
        INTEGER bInheritHandles, ;
        INTEGER dwCreationFlags, ;
        INTEGER lpEnvironment, ;
        INTEGER lpCurrentDirectory, ;
        STRING @lpStartupInfo, ;
        STRING @lpProcessInformation
DECLARE INTEGER WaitForSingleObject IN Win32API ;
        INTEGER hHandle, ;
        INTEGER dwMilliseconds
DECLARE INTEGER CloseHandle IN Win32API ;
        INTEGER hObject


=API_RunAndWait('myprog.exe','',.f.)
return

***************************************************************
FUNCTION API_RunAndWait()
*!*	Запускает внешний процесс (приложение) и ждет конца
*!*	его выполнения.
*!*	Параметры :
*!*	tcCommandLine - командная строка для выполнения.
*!*	                Например - "c:\my\prog.exe file1.txt file2.txt"
*!*	tcCallBackMacro - подпрограмма (необязательна) для выполнения в 
*!*	                  цикле работы запущенного процесса.
*!*	                  Можно оставить пустым.
*!*	tlInvisible - признак видимости окна процесса 
*!*                   (.t. - окна не видно, .f. - видно).
*!*	Возвращает .t., если процесс успешно запущен.
*!*	НЕ возвращает кодов завершения запущенного приложения.
***************************************************************
paramETERS tcCommandLine, tcCallBackMacro, tlInvisible
#DEFINE NORMAL_PRIORITY_CLASS         32 
#DEFINE IDLE_PRIORITY_CLASS           64 
#DEFINE HIGH_PRIORITY_CLASS           128 
#DEFINE REALTIME_PRIORITY_CLASS       1600 
#DEFINE WAIT_TIMEOUT                 0x00000102
#DEFINE WAIT_INTERVAL                 500 
#DEFINE CREATE_NO_WINDOW   134217728 

LOCAL lcStart, lcProcessInfo, lnReturn, lnHProcess, lnCreationFlags
IF VARTYPE(tcCommandLine) # "C" OR EMPTY(tcCommandLine)
	RETURN .f.
ENDIF
IF VARTYPE(tcCallBackMacro) # "C"
    tcCallBackMacro = ""
ENDIF
IF VARTYPE(tlInvisible) # "L"
    tlInvisible = .f.
ENDIF 
tcCallBackMacro = ALLTRIM(tcCallBackMacro)
tcCommandLine = ALLTRIM(tcCommandLine)
IF RIGHT(tcCommandLine,  1 ) # CHR( 0 )
    tcCommandLine = tcCommandLine + CHR( 0 )
ENDIF 
lnCreationFlags = IIF(tlInvisible = .t., CREATE_NO_WINDOW,  0 )  + NORMAL_PRIORITY_CLASS
lcStart = BINTOC( 68 , "4RS") + REPLICATE(CHR( 0 ),  64 )
lcProcessInfo = REPLICATE(CHR( 0 ),  16 )
lnReturnCode = CreateProcess( 0 , tcCommandLine,  0 ,  0 ,  1 , ;
lnCreationFlags,  0 ,  0 , @lcStart, @lcProcessInfo)
&& Если не можем запустить, то выходим немедленно.
IF lnReturnCode =  0 
    RETURN .f.
ENDIF
lnHProcess = CTOBIN(SUBSTR(lcProcessInfo,  1 ,  4 ), "4RS")
DO WHILE .t.
IF WaitForSingleObject(lnHProcess, WAIT_INTERVAL) <> WAIT_TIMEOUT
    EXIT
ELSE
    DOEVENTS
    IF !EMPTY(tcCallBackMacro)
        EXECSCRIPT(tcCallBackMacro)
        DOEVENTS
    ENDIF
ENDIF
ENDDO
lnReturnCode = CloseHandle(lnHProcess)
RETURN .t.
ENDFUNC