Отчеты FoxPro всегда строятся как результат сканирования одной (главной) таблицы. Поэтому, в общем случае, сначала необходимо эту самую таблицу создать. Любым способом.

В данном случае, использование Select-SQL допустимо, но как вспомогательный механизм. Проще создать пустую временную таблицу и при помощи рекурсии ее заполнить.

Создавать курсор необходимо, чтобы выстроить записи в нужном порядке. При помощи индекса это решить очень сложно.

* Создаем курсор со структурой, повторяющей структуру исходной таблицы
* Плюс дополнительное поле, отображающее уровень вложенности
* относительно искомого узла
CREATE CURSOR curReport (IDprod I, IDParent I, ProdName C(50), IsProd L, Opisanie M, nLevel I)

* Код записи, для которой ищем все дочернии узлы
LOCAL lnBaseID
lnBaseID = 0

SELECT MyTab
LOCATE FOR IDprod = m.lnBaseID
IF FOUND() = .T.

	* Если необходимо, записываю информацию по искомому узлу
	INSERT INTO curReport (IDprod, IDParent, ProdName, IsProd, Opisanie, nLevel) ;
	VALUES ;
	(MyTab.IDprod, MyTab.IDParent, MyTab.ProdName, MyTab.IsProd, MyTab.Opisanie, 0)

	* Запуск рекурсии
	DO LoadNode WITH MyTab.IDprod, 0

ENDIF


* Рекурсивная функция
PROCEDURE LoadNode
LPARAMETERS tnParentID, tnLevel

* Увеличиваю уровень вложенности
tnLevel = m.tnLevel+1

LOCAL lnRecno
SELECT MyTab
SCAN FOR IDParent = m.tnParentID

	* Записываю информацию по найденному узлу
	INSERT INTO curReport (IDprod, IDParent, ProdName, IsProd, Opisanie, nLevel) ;
	VALUES ;
	(MyTab.IDprod, MyTab.IDParent, MyTab.ProdName, MyTab.IsProd, MyTab.Opisanie, m.tnLevel)

	* Сохранаяю текущий код записи до входа в рекурсию
	lnRecno = Recno()
	* Продолжение рекурсии
	DO LoadNode WITH MyTab.IDprod, m.tnLevel
	* Восстановление текущего положения указателя записи
	GO m.lnRecno

ENDSCAN

RETURN
 

В результате, должна получится временная таблица (курсор) с именем curReport, которая повторяет стркутуру исходной таблицы и содержит все дочернии узлы для записи с указанным кодом. Однако в отличии от основной таблицы здесь записи упорядочены (выстроены) в том порядке как они должны отображаться, если бы дерево было бы полностью раскрыто.

Плюс имеем поле nLevel, содержащее уровень вложенности (отступа) каждого узла от базового узла. Это поле понадобится для формирования древовидной структуры в отчете.

Теперь, можно строить отчет, взяв в качестве источника данных полученный курсор. По значению поля nLevel можно делать красивое оформление отчета, если это необходимо.