* Исходные данные
Create Cursor test (f1 i, f2 c(10))
insert into test (f1, f2) values (1, 'один')
insert into test (f1, f2) values (1, 'два')
insert into test (f1, f2) values (2, 'три')
insert into test (f1, f2) values (2, 'четыре')

* Результирующий курсор, в который пойдет запись
* Предполагаю, что общая длина "склеенной" строки не превышает 255 символов
* Если результат может превышать 254 символов, то следует использовать поле типа memo
Create cursor result (f1 i, f2 c(254))

* Предварительная выборка, чтобы упорядочить данные в нужной последовательности
select f1, f2 from test into cursor curSort order by f1,f2

local lif1prev, lcf2
lif1prev = 0    && Заведомо не существующее значение поля f1 для инициализации переменных
lcf2 = ""
select curSort
scan
    if lif1prev = curSort.f1 
        lcf2 = m.lcf2 + "; " + alltrim(curSort.f2)
    else
        if lif1prev <> 0
            * Записываю очередную группу в результирующую таблицу
            insert into result (f1, f2) values (m.lif1prev, m.lcf2)
        endif
        * Сброс переменных для очередной группы
        lif1prev = curSort.f1 
        lcF2 = alltrim(curSort.f2)
    endif
endscan

if lif1prev <> 0
    * Записываю последнюю группу в результирующую таблицу
    insert into result (f1, f2) values (m.lif1prev, m.lcf2)
endif

* Смотрим результат
select result
go top
browse nowait