* Массив для экспорта должен иметь область видимости Private
* поскольку передается в процедуру parserArray
Dimension testArray(2,5)

testArray[1,1] = 1
testArray[1,2] = 'Один'
testArray[1,3] = 1.01
testArray[1,4] = Date()
testArray[1,5] = .f.

testArray[2,1] = 2
testArray[2,2] = 'Два'
testArray[2,3] = 2.02
testArray[2,4] = Date() + 10
testArray[2,5] = .t.

oExcel = CREATEOBJECT("Excel.Application")  
oBook = oExcel.workbooks.add  
oExcel.visible = .T.  

* Для исследования вопроса о том, как будет происходить экспорт/импорт
* в случае если в Excel есть объединенные ячейки
*!*	oBook.Sheets(1).Range("C1:D1").merge()
*!*	oBook.Sheets(1).Range("C2:D2").merge()

*!*	oBook.Sheets(1).Range("A1:A2").merge()

********************************
* Запись массива в Excel
* Только через процедуру и никак иначе (!)
********************************
oBook.Sheets(1).Range("A1:E2").value = parserArray("testArray")


********************************
* Чтение из Excel в Массив
* Область видимости массива с полученными данными может быть любой
* размерность массива будет автоматически изменена после чтения из Excel
********************************
Local laArray(1)	

laArray = oBook.Sheets(1).Range("A1:E2").value 
* Смотрим, что прочитали
For lnI = 1 to Alen(laArray, 1)
	?'строка '+ Transform(m.lnI) + ': '
	For lnJ = 1 to Alen(laArray,2)
		??' '
		??laArray[m.lnI,m.lnJ]
	EndFor
EndFor



********************************
* Обязательно должна быть оформлена отдельная процедура
* Для "распарсивания" массива при экспорте в Excel
PROCEDURE parserArray
LPARAMETERS taarrayname  
RETURN @&taarrayname