PUBLIC oForm  
  oForm = CREATEOBJECT('searchingrid')  
  oForm.show( 1 )  
    
  DEFINE CLASS searchingrid AS form  
  	Caption = "Form1"  
  	Name = "Form1"  
    
  	ADD OBJECT grids1 AS grids WITH ;  
  		Height =  229 , ;  
  		Left =  12 , ;  
  		Top =  12 , ;  
  		Width =  349 , ;  
  		Name = "Grids1"  
    
    
  	PROCEDURE Load  
  		LOCAL i  
  		IF !USED('test')  
  			CREATE CURSOR test (Id i, Texts c( 30 ))  
  			FOR i =  1  TO  1000   
  				INSERT INTO test (Id, texts) VALUES (i, TRANSFORM(i))  
  			ENDFOR   
  		ENDIF
  		GO TOP IN test
  		   
  	ENDPROC  
    
    
  	PROCEDURE Init  
  		WITH this.grids1  
  			.ColumnCount =  2   
  			DODEFAULT()   
  			.RecordSource = 'test'  
  			.Column1.ControlSource = "Test.Id"  
  			.Column1.readonly = .t.  
  			.Column2.ControlSource = "Test.Texts"  
  			.Column2.readonly = .t.  
  		ENDWITH   
  	ENDPROC  
    
    
  ENDDEFINE  
    
    
 **************************************************  
  DEFINE CLASS textboxs AS textbox  
  	Height =  23   
  	SelectOnEntry = .T.  
  	Width =  287   
  	NullDisplay = "'Нет'"  
  	Name = "textboxs"  
    
  	PROCEDURE KeyPress  
  		LPARAMETERS nKeyCode, nShiftAltCtrl  
    
 		* Проверяем на ReadOnly  
  		if this.ReadOnly and (IsAlpha(chr(nKeyCode)) or IsDigit(chr(nKeyCode)) )  
  			do case  
  				case allt(upper(this.parent.baseClass)) = 'COLUMN'  
 				* родитель колонка  
  					if !empty(this.controlSource)  
  						KEYBOARD chr(lastkey()) PLAIN CLEAR  
    
 						* источник данных не пустой  
 							* Cсоздаем обьект QuickSearchGrid и перадаем ссылку на родительский Grid  
  							if type('this.parent.parent.Quick') = 'O' and !isnull(this.parent.parent.Quick)  
  							else  
  								this.parent.parent.Quick = createobject('QuickSearchGrid',this)   
 								* Определяем тип выражения  
  								do case  
  									case type('this.value') $ 'C M'  
  										this.parent.parent.Quick.txt1.value = ''  
  									case type('this.value') $ 'N Y'  
  										this.parent.parent.Quick.txt1.value = val(chr(nKeyCode))  
  									case type('this.value') $ 'D'  
  										this.parent.parent.Quick.txt1.value = ctod(chr(nKeyCode))  
  									case type('this.value') $ 'T'  
  										this.parent.parent.Quick.txt1.value = ctoT(chr(nKeyCode))  
  								endcase  
  							endif  
  							this.parent.parent.Quick.show( 2 )  
    
  							this.parent.parent.Quick.txt1.setfocus()  
  							this.parent.parent.Quick.txt1.refresh()  
    
  							this.parent.parent.Quick.top =  thisform.top + mrow(thisform.name)*FONTMETRIC( 1 )  
  							this.parent.parent.Quick.left = thisform.left + mcol(thisform.name)*FONTMETRIC( 6 )  
    
  						endif  
  				endcase  
  			endif  
  	ENDPROC  
    
    
  ENDDEFINE  
    
 **************************************************  
  DEFINE CLASS grids AS grid  
    
  	DeleteMark = .F.  
  	Height =  200   
  	RecordMark = .F.  
  	SplitBar = .F.  
  	Width =  320   
  	GridLineColor = RGB( 192 , 192 , 192 )  
  	Name = "grids"  
    
 	*-- Свойство для привязки быстрого поиска  
  	quick = .F.  
  	PROCEDURE Init  
  		local i, lens  
  		lens =  0 . 9  * this.width/this.columnCount  
  		lens = iif(lens <  70 , 70 ,lens)  
 		* заменяем поля ввода на свои  
  		for i =  1  to this.columnCount  
 		* установка св - в колонок  
    
  			this.columns(i).width = lens  
  			if this.columns(i).currentcontrol $ 'Text1'  
  				this.columns(i).removeobject('text1')  
  				this.columns(i).addobject('textboxs1','textboxs')  
  				this.columns(i).currentcontrol = 'textboxs1'  
  				this.columns(i).bound = .t.  
  				this.columns(i).alignment =  3   
  				this.columns(i).selectonentry = .t.  
  				with this.columns(i).textboxs1  
  					.visible = .t.  
  					.borderstyle =  0   
  					.margin =  0   
  				endwith  
  				this.columns(i).Header1.alignment =  2   
  			endif  
  		endfor  
  	ENDPROC  
    
  ENDDEFINE  
    
  DEFINE CLASS quicksearchgrid AS toolbar  
    
  	Caption = "Быстрый Поиск"  
  	Height =  29   
  	Left =  0   
  	Top =  0   
  	Width =  203   
  	ShowWindow =  1   
  	Name = "quicksearchgrid"  
    
 	*-- Ссылка на Grid который вызвал поиск  
  	parentgrid = .F.  
    
    
  	ADD OBJECT txt1 AS txt WITH ;  
  		Alignment =  1 , ;  
  		Height =  23 , ;  
  		Left =  5 , ;  
  		SelectOnEntry = .F., ;  
  		StatusBarText = "Быстрый поиск", ;  
  		ToolTipText = "Быстрый поиск", ;  
  		Top =  3 , ;  
  		Width =  193 , ;  
  		Name = "TXT1"  
    
    
  	PROCEDURE Init  
  		Lparameters ParentGrid  
 		* Ссылка на TextBox в Grid который вызвал поиск  
  		if parameters() =  1   
  			This.ParentGrid = ParentGrid  
  		endif  
  	ENDPROC  
  ENDDEFINE  
    
    
  DEFINE CLASS txt AS TextBoxs  
  	Height =  23   
  	SelectOnEntry = .T.  
  	Width =  287   
  	NullDisplay = "'Нет'"  
  	Name = "txt"  
    
  	PROCEDURE KeyPress  
  		LPARAMETERS nKeyCode, nShiftAltCtrl  
  		do case  
  			case nKeyCode =  13   
 			* нажали ввод. Ищем запись удовлетв. условию.  
  				set exact off  
 		*set step on  
  		LOCAL cc  
  				do case  
  					case type('this.value') = 'C' or type('this.value') = 'M'  
 					* для поиска в символьных данных  
  						cc = [locate for LIKEC(UPPER('*] + upper(allt(this.value )) + [*'),UPPER(] + allt(this.parent.parentGrid.controlSource) + [))]  
  						&cc  
 		*				locate for upper(left(allt(eval(this.parent.parentGrid.controlSource)),len(allt(this.value)) )) = upper(allt(this.value ))  
  					case type('this.value') = 'N' or type('this.value') = 'Y'  
 					* для поиска в числовых данных  
  						cc = 'locate for ' + allt(this.parent.parentGrid.controlSource) + ' = ' + allt(str(this.value, 15 , 5 ))  
  						&cc  
  					case type('this.value') = 'T'  
 					* для поиска в данных ДатаТайм  
  						cc = 'locate for ' + allt(this.parent.parentGrid.controlSource) + ' = ' + '{' + allt(ttoc(this.value)) + '}'  
  						&cc  
  					case type('this.value') = 'D'  
 					* для поиска в данных Дата  
  						cc = 'locate for ' + allt(this.parent.parentGrid.controlSource) + ' = ' + '{' + allt(dtoc(this.value)) + '}'  
  						&cc  
  					otherwise  
  						locate for eval(this.parent.parentGrid.controlSource) = this.value   
  				endcase  
  				if found()  
  					this.parent.parentGrid.parent.parent.afterrowcolchange()  
  				endif  
  				this.parent.parentGrid.parent.parent.Quick = null  
  				set exact on  
  			CASE nKeyCode =  27  and nShiftAltCtrl =  0   
 			* нажали esc  
  				this.parent.parentGrid.parent.parent.Quick = null  
    
  		endcase  
    
  		this.parent.parentGrid.setfocus()  
  	ENDPROC  
    
    
  	PROCEDURE LostFocus  
  		this.keypress( 13 , 0 )  
  	ENDPROC  
    
    
  ENDDEFINE  
    

this.parent.parent.Quick.top =  thisform.top + mrow(thisform.name)*FONTMETRIC( 1 )  +  20 
this.parent.parent.Quick.left = thisform.left + mcol(thisform.name)*FONTMETRIC( 6 )  +  20