BindEvent(oSrcGrd.Columns(i),'Resize',this,'eventHandler', 1 )
		BindEvent(oSrcGrd.Columns(i),'Moved',this,'eventHandler', 1 )
		BindEvent( oSrcGrd, 'Resize' , this, 'eventHandler', 1 )
		BindEvent( oSrcGrd, 'Moved' , this, 'eventHandler', 1 )
		BindEvent( oSrcGrd, 'AfterRowColChange' , this, 'eventHandler', 1 )
		BindEvent( oSrcGrd, 'LockColumns' , this, 'eventHandler', 1 )
		BindEvent( this, 'Scrolled',this,'eventHandler', 1 )

lparameters vParameter
local array aSrcObj[ 1 ]
local oObj, cEvt, cClass, i, nWorkArea,iARow,iACol, iRCol, iACol_1

AEvents(aSrcObj, 0 )
oObj = aSrcObj[ 1 ]
cEvt = Lower(aSrcObj[ 2 ])
cClass = Lower(oObj.BaseClass)
nWorkArea = Select(Alias())
this.Tag = 'evt'

Select(this.cRecordSourceCursor) 		&&to be sure that memvar evaluation doesn't conflict with other alias columns

do case
case cClass  = 'grid'
	do case
	case cEvt = 'resize'
		this.Width = oObj.Width
		this.Top = oObj.Top + oObj.Height
	case cEvt = 'moved'
		this.Top = oObj.Top + oObj.Height
		this.Left = oObj.Left
	case cEvt = 'afterrowcolchange'
		*the following never fires when LockColumns > 0
		if  not this.oSourceGrid.LeftColumn == This.LeftColumn  
			If this.oSourceGrid.LeftColumn > This.LeftColumn  
				*scroll to R
				i=0
				do while this.oSourceGrid.LeftColumn > This.LeftColumn  
					i = i + 1 
					This.DoScroll(5)
					if i >= this.ColumnCount 
						this.oSourceGrid.DoScroll(4)
					endif
				enddo
			else
				*scroll to L
				do while this.oSourceGrid.LeftColumn  < This.LeftColumn 
					This.DoScroll(4)
				enddo
			endif
		endif

		*try to solve LockColumn > 0 case
		if this.LockColumns > 0
			*the only way seems to be checking ActiveColumn/RelativeColumn
			iArow = this.oSourceGrid.ActiveRow
			iACol = this.oSourceGrid.ActiveColumn 
			iRCol = this.oSourceGrid.RelativeColumn
			
			*temporary unbind source grid ARCC, Scrolled
			Unbindevents(this.oSourceGrid,'AfterRowColChange',this,'eventHandler')
			Unbindevents(this,'Scrolled',this,'eventHandler')

			*this seems to be needed to avoid flickering
			thisform.LockScreen = .T.
			
			*column changed in locked portion, scroll both to left
			if iACol <= this.oSourceGrid.LockColumns
				this.oSourceGrid.Doscroll(6)
				for i=1 to 5	&&should be enough
					this.DoScroll(6)
				next
			else	
				this.SetFocus() 
				
				*very interesting next stuff, ActivateCell work relatively to locked columns
				*need to compare Column index for a given RelativeRow and scroll accordingly
				this.ActivateCell(1, iRCol)
				 
				iACol_1 = this.ActiveColumn 

				if not iACol_1 == iACol
					if iACol_1 > iACol
						for i=1 to iACol_1 - iACol
							this.DoScroll(4)
						next 
					else
						for i=1 to iACol - iACol_1
							this.DoScroll(5)
						next 
					endif
				endif 
				this.oSourceGrid.SetFocus()
				this.oSourceGrid.Visible = .T.
			endif 

			*bind ARCC back to this
			Bindevent(this.oSourceGrid,'AfterRowColChange',this,'eventHandler',1)
			BindEvent( this, 'Scrolled',this,'eventHandler',1)

			thisform.LockScreen = .F.

		endif 	
	case cEvt = 'scrolled'
		if  not this.oSourceGrid.LeftColumn == This.LeftColumn  
			If this.oSourceGrid.LeftColumn > This.LeftColumn  
				*scroll to L
				i=0
				do while this.oSourceGrid.LeftColumn > This.LeftColumn  
					This.oSourceGrid.DoScroll(4)
				enddo
			else
				*scroll to R
				i=0
				do while this.oSourceGrid.LeftColumn  < This.LeftColumn 
					i = i + 1 
					This.oSourceGrid.DoScroll(5)
					if i >= this.ColumnCount 
						this.DoScroll(4)
					endif
				enddo
			endif
		endif
		if this.oSourceGrid.LockColumns > 0
			this.oSourceGrid.DoScroll(vParameter)
		endif 
	case cEvt = 'lockcolumns'
		this.LockColumns = this.oSourceGrid.LockColumns
	endcase
case cClass = 'column'
	do case
	case cEvt = 'moved'
		for i=1 to this.ColumnCount
			if this.Columns(i).ColumnOrder <> this.oSourceGrid.Columns(i).ColumnOrder
				this.Columns(i).ColumnOrder = this.oSourceGrid.Columns(i).ColumnOrder
			endif
		next
	case cEvt = 'resize'
		for i=1 to this.ColumnCount
			if this.Columns(i).Width <> this.oSourceGrid.Columns(i).Width
				this.Columns(i).Width = this.oSourceGrid.Columns(i).Width
			endif
		next
	endcase

endcase

this.Tag = ''
select  (nWorkArea) 	&&switch back work area