Lparameters   tcAlias         ; && курсор
			, tcFldCaptions   ; && перечень полей с заголовками в виде  fldName1,Заголовок;fldName2,Заголовок; ....
			, tnDivHeight       && высота скроллинга

external array taFldCaptions

Local lcResult, lnFldNum
If !Empty(tcAlias) And Used(tcAlias) and varType(tcFldCaptions)="C"
	Local taFldCaptions[ 1 ], lnFontSize, lcFontDefault, lcColorFont, lcStyle
	If Reccount(tcAlias)>= 1  and ALines(taFldCaptions,tcFldCaptions, 8 ,",",";")> 0 
		lnFontSize =  10 
		lcFontDefault = "Arial"
		lcColorFont = "black"
		Text to lcStyle NOSHOW TEXTMERGE PRETEXT  15 
			font-family: '<<lcFontDefault>>',sans-serif; 
			font-size:<<lnFontSize>>pt; 
			color:<<lcColorFont>>
		EndText
		If !Empty(tnDivHeight)
			Text to lcResult NOSHOW TEXTMERGE PRETEXT  7 
				<div style="height:<<(tnDivHeight)>>px;overflow:auto">
			EndText
		Else
			lcResult = ""		
		endif
		Text to lcResult ADDITIVE NOSHOW TEXTMERGE PRETEXT  7 
			<TABLE BORDER= 1  STYLE="<<lcStyle>>" frame="border"><COLGROUP span="<<ALEN(taFldCaptions,1)>>" width="0*">
		EndText	
		*заголовки таблицы
		Text to lcResult ADDITIVE NOSHOW TEXTMERGE PRETEXT  7 
			<TR>
		EndText 
		For lnFldNum =  2  To Alen(taFldCaptions, 1 ) step  2 
			Text to lcResult ADDITIVE NOSHOW TEXTMERGE PRETEXT  7 
				<TH NOWRAP><<taFldCaptions[lnFldNum]>></TH>
			EndText	
		Endfor
		Text to lcResult ADDITIVE NOSHOW TEXTMERGE PRETEXT  7 
			</TR>
		EndText
		*записи таблицы
		Select (tcAlias)
		Scan
			Text to lcResult ADDITIVE NOSHOW TEXTMERGE PRETEXT  7 
				<TR>
			EndText
			For lnFldNum =  1  To Alen(taFldCaptions, 1 ) step  2 
				luFieldValue = Evaluate(taFldCaptions[lnFldNum])
				lcTypeValue  = Vartype(luFieldValue)
				If InList( lcTypeValue, "N", "Y")
					luFieldValue = Iif( lcTypeValue="Y", Transform(luFieldValue,"999 999 999 999 999 999 999.99"), luFieldValue)
					Text to lcResult ADDITIVE NOSHOW TEXTMERGE PRETEXT  7 
						<TD NOWRAP ALIGN=RIGHT><<luFieldValue>></TD>
					EndText
				Else
					Text to lcResult ADDITIVE NOSHOW TEXTMERGE PRETEXT  7 
						<TD NOWRAP><<luFieldValue>></TD>
					EndText
				Endif
			EndFor
			Text to lcResult ADDITIVE NOSHOW TEXTMERGE PRETEXT  7 
				</TR>
			EndText
		EndScan
		Text to lcResult ADDITIVE NOSHOW TEXTMERGE PRETEXT  7 
			</COLGROUP></TABLE>
		EndText
		If !Empty(tnDivHeight)
			Text to lcResult ADDITIVE NOSHOW TEXTMERGE PRETEXT  7 
				</div>
			EndText
		EndIf 
		If !Empty(lcResult)
			#if .f.
			Local lnPartSize, lnStartPos
			lnPartSize =  1000 
			For lnStartPos= 1  to len(lcResult) step lnPartSize
				this.insert(Substr(lcResult,lnStartPos,lnPartSize))
			EndFor
			#EndIf 
			this.insert(lcResult)
		EndIf
	Endif
Endif