DECLARE PrintWindow IN WIN32API Long hwnd, Long hdcBlt, Long nFlags      
    DECLARE Long GdipGetImageGraphicsContext IN Gdiplus.dll Long nativeImage, Long @ graphics    
    DECLARE Long GdipGetDC IN Gdiplus.dll Long nativeImage, Long @ hdc    
    DECLARE Long GdipCreateBitmapFromScan0 IN Gdiplus.dll Long, Long, Long, Long, Long, Long @    
    DECLARE GdipDisposeImage IN Gdiplus.dll Long    
    DECLARE GdipDeleteGraphics IN Gdiplus.dll Long    
    DECLARE GdipReleaseDC IN Gdiplus.dll Long nativeGraphics, Long hdc    
    DECLARE Long GdipSaveImageToFile IN Gdiplus.dll Long, String, String, String    
        
    lqClsidEncoderBMP = 0h00F47C55041AD3119A730000F81EF32E    
    lnBitmap =  0     
    lnGraphics =  0     
    hdc =  0     
    lnStatus =  0     
    lnWidth = oOleObject.Width 
    lnHeight = oOleObject.Height    
        
    lnStatus = GdipCreateBitmapFromScan0(lnWidth, lnHeight,  0 , 0x000E200B,  0 , @lnBitmap)    
    IF lnStatus =  0     
    	lnStatus = GdipGetImageGraphicsContext(lnBitMap, @lnGraphics)    
    ENDIF 	    
    IF lnStatus =  0     
    	lnStatus = GdipGetDC(lnGraphics, @hdc)    
    	PrintWindow(oOleObject.HWnd, hdc,  0 )    
    ENDIF     
        
    = GdipReleaseDC(lnGraphics, hdc)    
    = GdipDeleteGraphics(lnGraphics)    
        
    lnStatus = GdipSaveImageToFile(lnBitMap, STRCONV("mytest.bmp" + CHR( 0 ),  5 ), lqClsidEncoderBMP, NULL)    
        
    = GdipDisposeImage(lnBitMap)    
        
    IF lnStatus >  0     
    	= MESSAGEBOX("Ошибка GDI+" + STR(lnStatus))    
    ENDIF