Есть софтина (не моя) в ней кусок про создание формы и получения снимка с камеры.
Сама
PROCEDURE GetFrame
THIS.msg(WM_CAP_GRAB_FRAME, 0,0)
дает картинку по размеру окна.
Вопрос как её сохранить или же как сделать снимок заданного разрешения (320 на 400)



PARAMETERS idpers,typephoto
LOCAL oForm
IF typephoto=[p]
fpref="P"+RIGHT(ALLTRIM(idpers),10)
ELSE
fpref="S"+RIGHT(ALLTRIM(idpers),10)
ENDIF
loFSO = CREATEOBJECT('Scripting.FileSystemObject')
IF loFSO.FolderExists('PHOTO')= .F.
MKDIR PHOTO
ENDIF

fcapname=CURDIR()+"\PHOTO\"+fpref+".bmp"
fcapnameJ=CURDIR()+"\PHOTO\"+fpref+".jpg"
oForm = CREATEOBJECT("Tform")
oForm.Show(1)
* end of main

DEFINE CLASS Tform As Form
#DEFINE WM_CAP_START 0x0400
#DEFINE WM_CAP_DRIVER_CONNECT (WM_CAP_START+10)
#DEFINE WM_CAP_DRIVER_DISCONNECT (WM_CAP_START+11)
#DEFINE WM_CAP_DRIVER_GET_CAPS (WM_CAP_START+14)
#DEFINE WM_CAP_SET_PREVIEW (WM_CAP_START+50)
#DEFINE WM_CAP_SET_OVERLAY (WM_CAP_START+51)
#DEFINE WM_CAP_SET_PREVIEWRATE (WM_CAP_START+52)
#DEFINE WM_CAP_GET_STATUS (WM_CAP_START+54)
#DEFINE WM_CAP_GRAB_FRAME (WM_CAP_START+60)
#DEFINE WM_CAP_SAVEDIB (WM_CAP_START+25)

Width=320 && Ширина окна
Height=440 && Высота окна
Autocenter=.T.
Caption="Фотографирование"
MinButton=.F.
MaxButton=.F.
hWindow=0
hCapture=0
capWidth=0
capHeight=0
capOverlay=0

ADD OBJECT cmdSaveFrame As CommandButton WITH Default=.T.,;
Left=12, Top=410, Height=27, Width=100, Caption="Сделать снимок",;
Enabled=.F.

ADD OBJECT cmdPreview As CommandButton WITH Default=.T.,;
Left=130, Top=410, Height=27, Width=100, Caption="Предпросмотр",;
Enabled=.F.

ADD OBJECT cmdClose As CommandButton WITH Cancel=.T.,;
Left=250, Top=410, Height=27, Width=70, Caption="Закрыть"

PROCEDURE Activate
IF THIS.hWindow = 0
DECLARE INTEGER GetFocus IN user32
THIS.hWindow = GetFocus()
THIS.CreateCaptureWindow
THIS.DriverConnect
ENDIF

PROCEDURE Destroy
THIS.ReleaseCaptureWindow

PROCEDURE cmdClose.Click

DELETE FILE &fcapname
ThisForm.Release

PROCEDURE cmdSaveFrame.Click
ThisForm.SaveFrame

PROCEDURE cmdPreview.Click
ThisForm.StartPreview

PROCEDURE GetFrame
THIS.msg(WM_CAP_GRAB_FRAME, 0,0)


PROCEDURE SaveFrame
THIS.msg(WM_CAP_GRAB_FRAME, 0,0)
THIS.msg(WM_CAP_SAVEDIB, 0,fcapname,1)

LOCAL lcPath, loGP, llReturn
SET CLASSLIB TO vfpgdiplus additive

loGP = CREATEOBJECT("GdipImages")
loGP.LoadFromFile(fcapname)
*loGP.CopyFromClipboard()
loGP.SaveToFile('&fcapnameJ')
= MESSAGEBOX(IIF(llReturn,'OK','Сохранено '))

PROCEDURE CreateCaptureWindow
#DEFINE WS_CHILD 0x40000000
#DEFINE WS_VISIBLE 0x10000000

DECLARE INTEGER capCreateCaptureWindow IN avicap32;
STRING lpszWindowName, LONG dwStyle,;
INTEGER x, INTEGER y,;
INTEGER nWidth, INTEGER nHeight,;
INTEGER hParent, INTEGER nID

THIS.hCapture = capCreateCaptureWindow("Фото",;
WS_CHILD+WS_VISIBLE,;
10,8,320,400, THIS.hWindow, 1)

PROCEDURE DriverConnect
THIS.msg(WM_CAP_DRIVER_CONNECT, 0,0)
IF THIS.IsCaptureConnected()
THIS.GetCaptureDimensions
STORE .T. TO THIS.cmdPreview.Enabled,THIS.cmdSaveFrame.Enabled
THIS.Caption = THIS.Caption + ": connected, " +;
LTRIM(STR(THIS.capWidth)) + "x" +;
LTRIM(STR(THIS.capHeight))
ELSE
THIS.Caption = THIS.Caption + ": failed to connect"
ENDIF

PROCEDURE DriverDisconnect
THIS.msg(WM_CAP_DRIVER_DISCONNECT, 0,0)

PROCEDURE ReleaseCaptureWindow
IF THIS.hCapture <> 0
THIS.DriverDisconnect
DECLARE INTEGER DestroyWindow IN user32 INTEGER hWnd
= DestroyWindow(THIS.hCapture)
THIS.hCapture = 0
ENDIF

PROCEDURE msg(msg, wParam, lParam, nMode)
IF THIS.hCapture = 0
RETURN
ENDIF

IF VARTYPE(nMode) <> "N" Or nMode=0
DECLARE INTEGER SendMessage IN user32;
INTEGER hWnd, INTEGER Msg,;
INTEGER wParam, INTEGER lParam
= SendMessage(THIS.hCapture, msg, wParam, lParam)
ELSE
DECLARE INTEGER SendMessage IN user32;
INTEGER hWnd, INTEGER Msg,;
INTEGER wParam, STRING @lParam
= SendMessage(THIS.hCapture, msg, wParam, @lParam)
ENDIF

FUNCTION IsCaptureConnected
* analyzing fCaptureInitialized member of the CAPDRIVERCAPS structure
#DEFINE CAPDRIVERCAPS_SIZE 44
LOCAL cBuffer, nResult
cBuffer = Repli(Chr(0),CAPDRIVERCAPS_SIZE)
THIS.msg(WM_CAP_DRIVER_GET_CAPS, Len(cBuffer), @cBuffer, 1)
THIS.capOverlay = buf2dword(SUBSTR(cBuffer,5,4))
nResult = Asc(SUBSTR(cBuffer, 21,1))
RETURN (nResult<>0)

PROCEDURE GetCaptureDimensions
* reading uiImageWidth and uiImageHeight members
* of the CAPSTATUS structure
#DEFINE CAPSTATUS_SIZE 76
LOCAL cBuffer
cBuffer = Repli(Chr(0), CAPSTATUS_SIZE)
THIS.msg(WM_CAP_GET_STATUS, Len(cBuffer), @cBuffer, 1)
THIS.capWidth = buf2dword(SUBSTR(cBuffer,1,4))
THIS.capHeight = buf2dword(SUBSTR(cBuffer,5,4))

PROCEDURE StartPreview
THIS.msg(WM_CAP_SET_PREVIEWRATE, 30,0)
THIS.msg(WM_CAP_SET_PREVIEW, 1,0)
IF THIS.capOverlay <> 0
THIS.msg(WM_CAP_SET_OVERLAY, 1,0)
ENDIF

PROCEDURE StopPreview
THIS.msg(WM_CAP_SET_PREVIEW, 0,0)
ENDDEFINE

FUNCTION buf2dword(lcBuffer)
RETURN Asc(SUBSTR(lcBuffer, 1,1)) + ;
BitLShift(Asc(SUBSTR(lcBuffer, 2,1)), 8) +;
BitLShift(Asc(SUBSTR(lcBuffer, 3,1)), 16) +;
BitLShift(Asc(SUBSTR(lcBuffer, 4,1)), 24)

Тут по идее надо как-то забрать его с формы. Сам снимок выдергивается по THIS.msg(WM_CAP_GRAB_FRAME, 0,0), ну точнее кадр. А вот как его мона забрать с формы ? Он ведь на форму лепится или как-то так. Понять не могу вообщем =(
Не хотелось бы лезть в дебри, меняя в корне все прям.

авторСергей П.Ст., "забрать его с формы" ? - Это ты о чём?
Если программа по кнопке "Сделать снимок" помещает снимок в PHOTO\P1.bmp, то зачем этот снимок "брать с формы"? Это непостижимо!!!

THIS.msg(WM_CAP_GRAB_FRAME, 0,0) как раз по моему на форме его размещает.. нет разве ?... у меня в этом примере отображается на форме снимок.

авторто дальше без порчи качества ты можешь эту картинку только обрезать каким-нибудь граф=редактором по размеру 320x400.
А так как форма как раз нужного размера (320 на 400) точнее capCreateCaptureWindow нужного размера, то подумалось мне, что проще забрать как-то его оттуда. Он как раз получается обрезан как надо.

авторно из твоей программы подключение даёт 640x480
А тут вообще на сколько я понял ограничение при использовании avicap будет в 640 на 480. Но сие не важно. Снижение на 320х240 это вообще не вариант.. потеря качество же просто будет. Тут нужно вырезать нужный фрагмент.

З.Ы. перевод в джпег и сжатие это уже не вопрос.. с этим как раз и справляется vfpgdiplus.

Блин, неужели никто не знает как получить картинку только размера
THIS.hCapture = capCreateCaptureWindow("Фото",;
WS_CHILD+WS_VISIBLE,;
10,8,320,400, THIS.hWindow, 1) ?????????

авторто ты поймёшь заодно, что операция показа картинки на экране через окно отсечения никак не связана с операцией сохранения картинки в файл на диске

Интересно было бы увидеть сие утверждение от меня. Но чувствую не тот случай. То что сейчас там стоит сохранение, означает только лишь то, что я всего лишь сохраняю кадр. Вопрос был про область захвата, которое отображено на форме.

авторПравильный вопрос, наверно, такой. Как получить доступ к графическому контексту для клиентской области фоксовской формы и как создать из этой области графический файл?

Вы...вы... вы молодец просто. Я даже близко не подошел к этой формулировке. Даже намека не было.


авторточнее capCreateCaptureWindow нужного размера, то подумалось мне, что проще забрать как-то его оттуда. Он как раз получается обрезан как надо. А на это не обращайте внимание.

авторPROCEDURE GetFrame
THIS.msg(WM_CAP_GRAB_FRAME, 0,0)
дает картинку по размеру окна.
Вопрос как её сохранить или ...
И на это то же.

авторИ чтоб сделать вырезку из изображения, загруженного из файла
Хреновая идея. Резать изображение автоматом придется, а резать то, что за ранее не известно и тупо в заданной области - хреновая идея. Суть обрезки и выдергивании окна захвата, как раз в том, что оператор ВИДИТ что он фотографирует и именно эта область и сохранится.

авторСтоило ли тебе ломиться в открытую дверь?
И птицы устремились к вершине Фудзиямы.

авторСергей должен сказать "спасибо", а не блажить про "Фудзияму".

Приношу извинения, действительно Спасибо.

Но вот только еще поправка. Форма то у меня 320 на 440 (ибо на ней кнопки сделать фото), а надо строго 320 на 400. Как быть ?
У самого THIS.hCapture = capCreateCaptureWindow нет возможности так же обратиться к высоте и ширине же ? А форму уменьшить низя... оператор должон кнопку видеть =(

А первые два это случайно не позиция начала точки выделения ?

Спасибо. Кстати есть еще вопрос почти в ту же область. Может кто знает, в vfpgdiplus можно как-то при сохранении, сделать картинку в 256 градации серого ?

А все.. вопрос закрыт. Сделано. Долго правда конвертит.. сек 15, но потерпеть можно =)

Следом еще вопрос. avicap который мы юзаем в этом примере имеет одно очень нехорошее ограничение, а именно 640 на 480 точек. Можно как-нить обойти сие ? (((