Не уверен, что понял правильно :)
Если такое не потянет, ай-да в ФоксКлуб:
|>

_Screen.Visible=.F.
oStartForm = Createobject("StartTopForm")
oStartForm.Show()
Read Events

Clear All
_Screen.Visible=.T.
Cancel

Define Class StartTopForm As Form
Caption = " TopLevel форма #1"
AutoCenter = .T.
ShowWindow = 2
Height = 500
Width = 700

Add Object CloseForm As CommandButton With;
CAPTION = "Выход",;
HEIGHT = 40,;
TOP = 40,;
LEFT = 500

Add Object Form2 As CommandButton With;
CAPTION = "Модальная",;
HEIGHT = 40,;
TOP = 40,;
LEFT = 250

Procedure Form2.Click()
Public oForm2
oForm2 = Createobject("ModalForm")
oForm2.Left = 50
oForm2.Show()

Procedure CloseForm.Click()
Clear Events

Procedure Destroy()
Clear Events

Procedure Load()
Public m.Menu_Name, m.Form_Name
m.Form_name=This.Name
m.Menu_name="m_"+This.Name

Define Menu (m.Menu_name) Bar In Window (m.Form_Name)
*****************************************************
Define Pad p1 Of (m.Menu_name) Prompt "Операции "
Define Pad p2 Of (m.Menu_name) Prompt "Товары "
Define Pad p_quit Of (m.Menu_name) Prompt "Выход "
On Pad p1 Of (m.Menu_name) Activate Popup OPE
On Pad p2 Of (m.Menu_name) Activate Popup TOV
On Sele Pad p_quit Of (m.Menu_name) Do to_quit

Local m.i, m.POP
m.i=0
m.POP="OPE"
Define Popup (m.POP) SHORT Relative
m.i=m.i+1
Define Bar m.i Of (m.POP) Prompt "Создать операцию"
m.i=m.i+1
Define Bar m.i Of (m.POP) Prompt "Удалить операцию"

m.i=0
m.POP="TOV"
Define Popup (m.POP) SHORT Relative
m.i=m.i+1
Define Bar m.i Of (m.POP) Prompt "Купить товар"
m.i=m.i+1
Define Bar m.i Of (m.POP) Prompt "Продать товар"

Activate Menu (m.Menu_name) Nowait
**********************************

Enddefine


Define Class ModalForm As Form

Caption = " Модальная дочерняя форма #2"
WindowType = 1
ShowWindow = 1
Height = 400
Width = 600

Add Object Form3 As CommandButton With;
CAPTION = "Немодальная",;
HEIGHT = 40,;
TOP = 40,;
LEFT = 50

Procedure Form3.Click()
Public oForm3
oForm3 = Createobject("ModellessForm")
oForm3.Left = 100
oForm3.Show()

Procedure Load()
Define Pad (This.Name) Of (m.Menu_name) Prompt "Активна форма #2" Before P_QUIT

Procedure Unload()
Release Pad (This.Name) Of (m.Menu_Name)

Procedure Activate()
If Type("OFORM3")="O" && Если форма #3 существует - убиваем
Release OFORM3
Endif

Enddefine


Define Class ModellessForm As Form

Caption = " Немодальная дочерняя TopLevel форма #3"
AutoCenter = .T.
WindowType = 0
ShowWindow = 2
Height = 300
Width = 400

Procedure Load()
Define Pad (This.Name) Of (m.Menu_name) Prompt "Активна форма #3" Before P_QUIT

Procedure Unload()
Release Pad (This.Name) Of (m.Menu_Name)

Enddefine


Procedure to_QUIT
** грубо конечно
Clear Wind
Clear Events

ps - если Ваши формы создаются визуально, то Public ссылки на формы
можно получить в методах формы (например в Init) так:

Public Form_Handle
Form_Handle=This

Хотел вставить URL - www.foxclub.ru/ph/ получилась лабуда, извините

Игорь:
автор писал:Мне с менюхой надо работать как с объектом ...
Как я Вас понимаю ... объектные меню и репорт - "но не в этой жизни", хотя некоторые мастерят свои классы, конечно :)
imho в Вашем случае одного имени для меню не достаточно без ссылки на форму, если не так - покажите пример :)
автор писал:Мне надо что б на клике мыши вне формы 3, но на форме 1 или 2
или 4... их там много может быть...
А вызывается он из модальной формы, у которой свойство AlwaysOnTop = .T.
Вот на Activate этих многих и предлагается гасить форму 3, а AlwaysOnTop зачем - только раздражать пользователей при загрузке Worda-Excelя :)
с/у Равиль :)

автор писал:На одной из форм есть оле-компонент...
Когда я его гашу... то клика на нем не происходит...
Соответственно актив форм пролетает...
:) Вы хотите сказать, что не происходит актив формы при активации оле-компонента, или наоборот оле-компонент находится на "гасимой" форме - не совсем понятен вопрос ... а что за компонент ?