* Исходная таблица
create cursor curTree (nLevel i, ItemId c(7), ItemIdFrom c(7))
insert into curTree (nLevel, ItemId, ItemIdFrom) values (1, '1001000', '1001100')
insert into curTree (nLevel, ItemId, ItemIdFrom) values (1, '1001000', '1001200')
insert into curTree (nLevel, ItemId, ItemIdFrom) values (1, '1001000', '1001300')
insert into curTree (nLevel, ItemId, ItemIdFrom) values (2, '1001200', '1001210')
insert into curTree (nLevel, ItemId, ItemIdFrom) values (2, '1001200', '1001220')
insert into curTree (nLevel, ItemId, ItemIdFrom) values (2, '1001300', '1001310')
insert into curTree (nLevel, ItemId, ItemIdFrom) values (2, '1001300', '1001320')
insert into curTree (nLevel, ItemId, ItemIdFrom) values (3, '1001310', '1001311')

* Вход в рекурсию
* Результирующая таблица
create cursor curShow (nLevel i, ItemId c(7), ItemIdFrom c(7))

* Список элементов первого уровня
select * into cursor cur1 from curTree where nLevel = 1 order by ItemId
select cur1
scan
    insert into curShow (nLevel, ItemId, ItemIdFrom) values (cur1.nLevel, cur1.ItemId, cur1.ItemIdFrom)
    * вызов рекурсии
    do createLevel with cur1.nLevel, cur1.ItemIdFrom, ','+cur1.ItemId+','
endscan
use in cur1

*************************************
****************** рекурсивная процедура
*************************************
procedure createLevel
parameters tnLevel, tcItemId, tcParent

local lcCursorName
lcCursorName = SYS(2015)

select * into cursor &lcCursorName from curTree where nLevel = m.tnLevel + 1 and ItemId = m.tcItemId order by ItemId
select (m.lcCursorName)
scan
    * Проверка на "зацикливание"
    * Надо "подняться" в таблице curShow по родителям и проверить, 
    * что ItemId ни разу не встречался в текущей ветке
    if at(','+&lcCursorName..ItemId+',', tcParent) > 0
        * Зацикливание. Пропускаем текущий узел
        loop
    endif

    insert into curShow (nLevel, ItemId, ItemIdFrom) values (&lcCursorName..nLevel, &lcCursorName..ItemId, &lcCursorName..ItemIdFrom)
    * вызов рекурсии
    do createLevel with &lcCursorName..nLevel, &lcCursorName..ItemIdFrom, tcParent + &lcCursorName..ItemId+','
endscan
use in (m.lcCursorName)
return