LOCAL x, y
x = CREATEOBJECT("testform")
y = CREATEOBJECT("testform", x)
x.Show()
y.Show()
READ EVENTS

DEFINE CLASS testform AS form

	DataSession =  2 
	Name = "testform"

	ADD OBJECT grid1 AS grid WITH ;
		Height =  217 , ;
		Left =  12 , ;
		Top =  12 , ;
		Width =  349 , ;
		Name = "Grid1"

	PROCEDURE Init
		LPARAMETERS oForm
		IF VARTYPE(oForm)="O" AND !ISNULL(oForm)
			LOCAL ARRAY laData[ 1 ]
			LOCAL ARRAY laFields[ 1 ]
			LOCAL lnDS
			lnDS = this.DataSessionId
			SET DATASESSION TO oForm.DataSessionId
			=AFIELDS(laFields, "test")
			SELECT * FROM test INTO ARRAY laData
			SET DATASESSION TO lnDS
			CREATE CURSOR extern FROM ARRAY laFields
			APPEND FROM ARRAY laData
			SELECT a.id, a.test as own, b.test as extern ;
			FROM test a INNER JOIN extern b ON a.id = b.id ;
			INTO CURSOR new
			USE IN extern
			USE IN test
			WITH this.Grid1
				.ColumnCount =  3 
				.RecordSource = "new"
				WITH .Column3.Header1
					.Caption = "Extern"
					.Alignment =  2 
				ENDWITH 
			ENDWITH 
			this.AutoCenter = .T. 
		ELSE
			this.Grid1.RecordSource = "test"
		ENDIF 
		this.Caption = "DataSessionID: " + STR(this.DataSessionId)
	ENDPROC

	PROCEDURE Load
		CREATE CURSOR test (id i, test c( 10 ))
		FOR i =  1  TO  10 
			INSERT INTO test VALUES (i, SYS( 2015 ))
		ENDFOR 
		GO TOP 
	ENDPROC
ENDDEFINE

*!* Метод формы-источника
PROCEDURE Export
LPARAMETERS taFields, taData
	=AFIELDS(taFields, "test")
	SELECT * FROM test INTO ARRAY taData
ENDPROC

*!* Метод формы-получателя
PROCEDURE Import
LPARAMETERS oForm
IF VARTYPE(oForm)="O" AND !ISNULL(oForm)
	LOCAL ARRAY laData[ 1 ]
	LOCAL ARRAY laFields[ 1 ]
	oForm.Export(@laFields, @laData)
	CREATE CURSOR extern FROM ARRAY laFields
	APPEND FROM ARRAY laData
ENDIF 
ENDPROC

*!* Пример вызова
PROCEDURE Command1.Click
	thisform.Import(x)
	ACTIVATE SCREEN 
	SELECT a.id, a.name as own, b.name as extern ; 
 	FROM test a INNER JOIN extern b ON a.id = b.id 
ENDPROC