*!* заменить строку запроса и строку соединения на свою
#define CSQLSTRING "select top 100 * from test"
#define CCONNECTTRING "driver=sql server; server=(local); database=test"
CLEAR ALL 
PUBLIC x
x = CREATEOBJECT("form1")
x.Show()
=SQLDISCONNECT( 0 )
=SYS( 1500 , '_MWI_VIEW', '_MWINDOW')

DEFINE CLASS form1 AS form

	DataSession =  2 
	Name = "form1"

	PROCEDURE Load
		LOCAL oWrapper1, oWrapper2
		*!* Курсор откроется в Private DataSession объекта
		*!* и будет закрыт при его удалении (при выходе из Form.Load)
		oWrapper1 = CREATEOBJECT("wrapper1")
		oWrapper1.SQLEXEC(CSQLSTRING, "test1")
		*!* Курсор откроется в Private DataSession формы
		oWrapper2 = CREATEOBJECT("wrapper2")
		oWrapper2.SQLEXEC(CSQLSTRING, "test2")
		*!* Курсор откроется в Default DataSession
		oWrapper3 = CREATEOBJECT("wrapper3")
		oWrapper3.SQLEXEC(CSQLSTRING, "test3")
	ENDPROC
ENDDEFINE

DEFINE CLASS wrapper1 AS session
	DataSession =  2 
	Name = "wrapper1"
	CH = SQLSTRINGCONNECT(CCONNECTTRING)

	PROCEDURE SQLEXEC
	LPARAMETERS pcSQL, pcCurName
		lnRetVal = SQLEXEC(This.CH, pcSQL, pcCurName)
		RETURN IIF(lnRetVal >  0 , .T., .F.) 
	ENDPROC
ENDDEFINE

DEFINE CLASS wrapper2 AS wrapper1
	DataSession =  1 
	Name = "wrapper2"
ENDDEFINE

DEFINE CLASS wrapper3 AS wrapper1
	Name = "wrapper3"
	PROCEDURE Init
		this.DatasessionId =  1 
	ENDPROC
ENDDEFINE