local loArray1
clear 
loArray1 = create_array()
? "после создания"
for lnItem =  1  to loArray1.count
	? loArray1.item[m.lnItem]
endfor

loArray1 = modify_array(loArray1)
? "после модификации"
for lnItem =  1  to loArray1.count
	? loArray1.item[m.lnItem]
endfor
return

function create_array
	local lovector
	lovector = createobject('vector')
	lovector.add( 220 )
	lovector.add( 120 )
	lovector.add( 10 )
	return m.lovector
endfunc
function modify_array
	lparameters lovector
	lovector.remove( 1 )
	return m.lovector
endfunc

define class vector as custom

	*--	число элементов
	count =  0 
	*--	емкость 
	capacity =  0 
	*-- элементы
	dimension item[ 1 ]

	*--	инициализировать вектор размеров tncount и со значением по умолчанию tudefaultvalue
	function init
		lparameters tncount, tudefaultvalue
		if type('m.tncount') == 'N'
			local loldCompatible
			loldCompatible = set('compatible')
			set compatible off
			with this
				store m.tncount to .count, .capacity				
				dimension .item[.capacity]
				.item = m.tudefaultvalue
			endwith
			set compatible &loldCompatible.
		endif
	endfunc
	
	*--	очистить, без освобождения памяти
	procedure clear
		with this
			.count =  0 
		endwith
	endproc

	*--	добавить элемент в конец массива
	procedure add
		lparameters tuElement
		local loldCompatible
		loldCompatible = set('compatible')
		set compatible off
		with this
			if .count >= .capacity
				.capacity =  2  * iif(empty(.capacity),  8 , .capacity)
				dimension .item[.capacity]
			endif
			.item(.count +  1 ) = m.tuElement
			.count = .count +  1 
		endwith
		set compatible &loldCompatible.
	endproc

	*-- удалить элемент
	procedure remove
		lparameters tnindex
		with this
			if between(m.tnindex,  1 , .count)
				adel(.item, m.tnindex)
				.count = .count -  1  
			endif
		endwith
	endproc
enddefine